[文件操作] [已解决]批处理如何批量重命名文件？

 
@echo off&set cd=%cd%
for /f "delims=" %%i in ('dir/b/s *.jpg') do (
    if exist "%%i" (
        if exist "%%~dpixbs.jpg" (
            cd/d %%~dpi
            set /a n=0
            for /f "delims=" %%j in ('dir/b *.jpg') do (
                set var=%%~nxj&set /a n+=1
                setlocal enabledelayedexpansion
                if not "!var!"=="xbs.jpg" (
                   ren "!var!" "xbs!n!.jpg"
                ) else (set /a n-=1)
                for %%k in (!n!) do endlocal&set n=%%k
            )
            cd/d %cd%
           ) else (ren "%%i" "xbs.jpg")
     ) 
)
pause
复制代码

@echo off&setlocal ENABLEDELAYEDEXPANSION
for /r %%i in (*.jpg) do call :x %%~fsi&set a=
pause&exit
:x
ren %1 xbs!a!.jpg 2>nul||(set /a a+=1&goto :x)
复制代码

@echo off
SetLocal
set "prefix=xbs"
set "_cd=%cd%"
for /f "usebackq delims=" %%a in ("a.txt") do (
    set path_now=%%~dpa
    SetLocal EnableDelayedExpansion
    if /i "!path_now!" neq "!path_last!" (
        EndLocal
        set path_last=%%~dpa
        set n=
        cd /d %%~dpa
        if exist "%prefix%*.jpg" ren "%prefix%*.jpg" "*.*.jpg"
        for /f "delims=" %%i in (' dir /b "*.jpg" ') do (
            set file=%%i
            SetLocal EnableDelayedExpansion
            ren "!file!" "!prefix!!n!.jpg"
            EndLocal
            set /a n += 1
        )
    ) else EndLocal
)
cd /d "%_cd%"
复制代码

@echo off
SetLocal EnableDelayedExpansion
for /r %%a in (*.jpg) do (
    set /a n += 1
    echo "%%~nxa" → "!n!.jpg"
    ren "%%a" "!n!.jpg"
)
pause
复制代码

@echo off&set cd=%cd%
::关闭回显，并将cd变量设置为固定值
for /f "delims=" %%i in ('dir/b/s *.jpg') do (
rem 获取“鸡屁股”文件列表
    if exist "%%i" (
    rem 如果存在该文件则
        if exist "%%~dpixbs.jpg" (
        rem 如果同路径下存在xbs.鸡屁股文件，则
            cd/d %%~dpi
            rem 切换到其目录下（建议改成pushd和popd，可以简化操作）
            set /a n=0
            rem 设置变量n为0，小建议，不使用/a开关效率更高
            for /f "delims=" %%j in ('dir/b *.jpg') do (
            rem 获取所切换的目录下的jpg文件列表
                set var=%%~nxj&set /a n+=1
                rem 设置变量var值为所获取的文件名，并将n加1
                setlocal enabledelayedexpansion
                rem 打开变量延迟（一看就是老手）
                if not "!var!"=="xbs.jpg" (
                rem 如果该文件不叫作xbs.jpg
                   ren "!var!" "xbs!n!.jpg"
                   rem 则将该文件改名为xbs%n%.jpg，此时n位于语块之内，所以要使用有变量延迟效果的!n!
                ) else (set /a n-=1)
                rem 否则让n减1
                for %%k in (!n!) do endlocal&set n=%%k
                rem 与setlocal对应，关闭回显，并将会在退出堆栈的过程中丢失的变量n保留
            )
         cd/d %cd%
         rem 回到原始位置
         ) else (ren "%%i" "xbs.jpg")
         rem 否则（对应第二层的if）将文件改名为xbs.jpg
    )
)
pause
复制代码

@echo off
for /f "delims=" %%i in ('dir/b/s *.jpg') do (
    set str=%%~dpi&set str2=%%~nxi
    setlocal enabledelayedexpansion
    if not "!str!"=="!num!" (set n=) else set /a n+=1
    ren "!str!!str2!" "xbs!n!.jpg"
    for %%a in (!n!) do endlocal&set n=%%a
    set "num=%%~dpi"
)
pause
复制代码

@echo off
for /f "delims=" %%i in ('dir/b/s *.jpg') do (
    set str=%%~dpi&set str2=%%~nxi
    setlocal enabledelayedexpansion
    if not "!str!"=="!num!" (
        set "n="
        ren "!str!*.jpg" "*.*.jpg"
    ) else set /a n+=1
    ren "!str!!str2!.jpg" "xbs!n!.jpg"
    for %%a in (!n!) do endlocal&set n=%%a
    set "num=%%~dpi"
)
pause
复制代码