[文件操作] 批处理删除某目录下三天前创建的文件。

@echo off
SET/p TT=输入天数:
SET/p PH=输入路径:
for /f "tokens=1-3 delims=-/\:. " %%i in ("%date%") do set /a p1=%%i,p2=100%%j%%100,p3=100%%k%%100
    if %p3% gtr %TT%  goto ppp
:nxt
set/a p2-=1
   if %p2% equ 0 set/a p1-=1&set p2=12
   set/a PN2="!(p1%%4)&!(!(p1%%100))|!(p1%%400)",PN2=28+PN2
   for /f "tokens=%p2%" %%i in ("31 %pN2% 31 30 31 30 31 31 30 31 30 31") do set/a p3+=%%i
   if %p3% leq %tt% goto nxt
:ppp
set/a p3-=tt
setlocal enabledelayedexpansion
   for %%i in (p2 p3) do if !%%i! lss 10 set %%i=0!%%i!
for /r "%ph%" %%i in (*) do set t=%%~ti&call :loop "%%i"
pause
goto :eof
:loop
if %p1%-%p2%-%p3% gtr %t:~,10% del %1
复制代码

@echo off
SET/p TT=输入天数:
SET/p PH=输入路径:
if "%tt%"=="" set tt=0
for /f "tokens=1-3 delims=-/\:. " %%i in ("%date%") do set /a p1=%%i,p2=100%%j%%100,p3=100%%k%%100
    if %p3% gtr %TT%  goto ppp
:nxt
set/a p2-=1
   if %p2% equ 0 set/a p1-=1,p2=12
   set/a PN2="!(p1%%4)&!(!(p1%%100))|!(p1%%400)",PN2=28+PN2
   for /f "tokens=%p2%" %%i in ("31 %pN2% 31 30 31 30 31 31 30 31 30 31") do set/a p3+=%%i
   if %p3% leq %tt% goto nxt
:ppp
set/a p3-=tt
setlocal enabledelayedexpansion
   for %%i in (p2 p3) do if !%%i! lss 10 set %%i=0!%%i!
     for /f "skip=5 tokens=1,3*" %%i in ('dir /tc /a-d "%ph%\*.*" 2^>nul^|findstr /v "字节"') do (
         if %p1%-%p2%-%p3% geq %%i del "%ph%\%%k"
)
pause&exit
复制代码

@echo off
regedit /e "%temp%\bak.reg" "HKEY_CURRENT_USER\Control Panel\International"
::::备份系统原时间日期格式
>aDate.reg echo REGEDIT4
>>aDate.reg echo.
>>aDate.reg echo [HKEY_CURRENT_USER\Control Panel\International]
>>aDate.reg echo "sShortDate"="yyyy-MM-dd"
>>aDate.reg echo "sDate"="-"
>>aDate.reg echo "sTimeFormat"="HH:mm:ss"
regedit /s aDate.reg&del aDate.reg
::::统一格式化系统日期格式（无需reg.exe兼容Win2000）

>tmp.vbs echo Wscript.echo FormatDateTime (DateAdd("d", -3 ,Date),2)
for /f "delims=" %%i in ('cscript.exe //nologo tmp.vbs') do set aDate=%%i& del tmp.vbs
::::用VBS计算当前日期减 3 天，如果要当前之后的 3 天请将 ↑上面 2 行的 -3 改成 +3

echo %aDate%
set 年=%aDate:~0,4%
set 月=%aDate:~5,2%
set 日=%aDate:~8,2%
set 3天前=%年%%月%%日%
setlocal enabledelayedexpansion
Wmic Datafile Where "Drive='D:' and path='\\111\\' and CreationDate<'!3天前!000000.000000+***'" call delete /NOINTERACTIVE
regedit /s "%temp%\bak.reg"&del "%temp%\bak.reg"
::::还原系统原时间日期格式
pause
复制代码