[文本处理] [已解决] 批处理如何合并两个文本？

(for /f "delims=" %%a in ('findstr  .* A.txt') do (
  set "a=%%a"
  setlocal enabledelayedexpansion
  set /p b=
  echo !a!:!b!
  endlocal
))<B.txt>C.txt
pause>nul&exit
复制代码

findstr /n .* B.txt>tmp1
find /n /v "" <A.txt>tmp2
(for /f "tokens=2*delims=]:" %%a in ('fc /lb1000 /n tmp1 tmp2^|sort') do (
   if not defined . (
      set /p=%%b<nul
      set .=.
   ) else (
      set .=
      echo;:%%b
   )
))>C.txt
del /q tmp?
pause
复制代码

@echo off
(for /f "delims=" %%a in (A.txt) do (
  set /p b=
  call echo %%a:%%b%%
))<B.txt>C.txt
pause>nul
复制代码

@echo off&SetLocal EnableDelayedExpansion
For /f "delims=: tokens=1*" %%i in ('findstr /n ".*" a.txt') do set _%%i=%%j
(For /f "delims=: tokens=1*" %%i in ('findstr /n ".*" b.txt') do (
	Set n=%%i
	Call echo %%_!n!%%:%%j
	))>c.txt
start c.txt
pause&exit
复制代码

@echo off&setlocal enabledelayedexpansion
set txt=a.txt&call :sta
set txt=b.txt&call :sta
pause
:sta
set /a n+=1
set m=0
for /f "delims=" %%i in (!txt!) do (
set /a m+=1
set  "_!n!!m!=%%i" 
if !n! equ 2 call echo %%_1!m!%%:%%_2!m!%%
)
goto :eof
复制代码

paste -d ":" a.txt b.txt >c.txt
复制代码

@echo off
setlocal enabledelayedexpansion
set n1=0
for /f "delims=" %%a in (1.txt) do (
set /a n1=n1+1
set n2=0
for /f "delims=" %%b in (2.txt) do (
set /a n2=n2+1
if !n1! equ !n2! (
echo %%a:%%b>>c.txt
)
)
)
pause
复制代码