返回列表发帖

missll

一级士官

Rank: 2

帖子: 85
积分: 129
技术: 2
捐助: 0
注册时间: 2011-4-15

1楼 跳转到 » 倒序看帖

打印

字体大小: tT

发表于 2012-11-16 16:09 | 只看该作者

[注册表类] [已处理]获取word打开历史的批处理为什么执行第一次错误第2次正确呢？

本帖最后由 missll 于 2012-11-16 17:23 编辑

我想在用户权限下获取Microsoft Office版本
是读取注册表键值 HKEY_CURRENT_USER\Software\Microsoft\Office\12.0 位置, 12是office 007
代码一下 :

@echo off
set office=HKEY_CURRENT_USER\Software\Microsoft\Office
(reg query %office% | find "11.0" || reg query %office% | find "12.0" || reg query %office% | find "14.0")>%TEMP%\6c70ef5709acfbb79de47c27863d64eb
for /f %%a in ('type %TEMP%\6c70ef5709acfbb79de47c27863d64eb') do (
set ofver=%%a
echo %ofver:~-4%)
复制代码

执行结果:

Microsoft Windows [版本 5.2.3790]
(C) 版权所有 1985-2003 Microsoft Corp.
C:\Documents and Settings\Administrator>e:\1.bat
~-4
C:\Documents and Settings\Administrator>e:\1.bat
12.0
C:\Documents and Settings\Administrator>
复制代码

从以上结果可以看出  第一次执行的时候  %ofver:~-4% 获取值是错误的,第2次执行显示了正确的键值  但是我不明白这是为什么？

测试环境  win2k3 r2
我感觉写的很罗嗦  或者谁能给出更简单的代码呢？

花开不问月,不语笑红尘.

missll

一级士官

Rank: 2

帖子: 85
积分: 129
技术: 2
捐助: 0
注册时间: 2011-4-15

2楼

发表于 2012-11-16 17:06 | 只看该作者

更新了代码找出问题出在%ofver:~-4%上但是不知道原因。求解。。。

花开不问月,不语笑红尘.

TOP

BAT-VBS

少将

Rank: 8 Rank: 8

帖子: 888
积分: 6682
技术: 88
捐助: 0
注册时间: 2012-10-27

3楼

发表于 2012-11-16 17:07 | 只看该作者

@echo off
setlocal enabledelayedexpansion
del %TEMP%\6c70ef5709acfbb79de47c27863d64eb
set office=HKEY_CURRENT_USER\Software\Microsoft\Office
reg query %office% | findstr  "1[124].0" >%TEMP%\6c70ef5709acfbb79de47c27863d64eb
for /f %%a in ('type %TEMP%\6c70ef5709acfbb79de47c27863d64eb') do (
    set ofver=%%a
    echo --------------Microsoft Office Word--------------------
    reg query "%office%\!ofver:~-4!\Word\File MRU"
    echo --------------Microsoft Office Excel-------------------
    reg query "%office%\!ofver:~-4!\Excel\File MRU"
    echo --------------Microsoft Office PowerPoint--------------
    reg query "%office%\!ofver:~-4!\PowerPoint\File MRU"
)
复制代码

TOP

BAT-VBS

少将

Rank: 8 Rank: 8

帖子: 888
积分: 6682
技术: 88
捐助: 0
注册时间: 2012-10-27

4楼

发表于 2012-11-16 17:08 | 只看该作者

@echo off
setlocal enabledelayedexpansion
set office=HKEY_CURRENT_USER\Software\Microsoft\Office
for /f %%a in ('reg query %office% ^| findstr  "1[124].0"') do (
    set ofver=%%a
    echo --------------Microsoft Office Word--------------------
    reg query "%office%\!ofver:~-4!\Word\File MRU"
    echo --------------Microsoft Office Excel-------------------
    reg query "%office%\!ofver:~-4!\Excel\File MRU"
    echo --------------Microsoft Office PowerPoint--------------
    reg query "%office%\!ofver:~-4!\PowerPoint\File MRU"
)
复制代码

TOP

tmplinshi

版主

Rank: 7 Rank: 7 Rank: 7

帖子: 1023
积分: 3120
技术: 230
捐助: 160
注册时间: 2010-12-22

5楼

发表于 2012-11-16 17:08 | 只看该作者

for /f %%a in ('type %TEMP%\6c70ef5709acfbb79de47c27863d64eb') do (
set ofver=%%a
echo --------------Microsoft Office Word--------------------
reg query "%office%\%ofver:~-4%\Word\File MRU" 2>nul
echo --------------Microsoft Office Excel-------------------
reg query "%office%\%ofver:~-4%\Excel\File MRU" 2>nul
echo --------------Microsoft Office PowerPoint--------------
reg query "%office%\%ofver:~-4%\PowerPoint\File MRU" 2>nul)

因为每条命令在执行之前，变量就会被展开。以上几行都是属于一个 for 命令里的，也就是一条 for 命令。

在这条 for 命令之前并没有设置 ofver 变量，所以查不到结果。而当你第二次运行批处理时，因为第一次运行的 ofver 变量没有被清除，所以能够得到结果。

改成：

@echo off
setlocal enabledelayedexpansion
del %TEMP%\6c70ef5709acfbb79de47c27863d64eb >nul 2>nul
set office=HKEY_CURRENT_USER\Software\Microsoft\Office
(reg query %office% | find "11.0" || reg query %office% | find "12.0" || reg query %office% | find "14.0")>>%TEMP%\6c70ef5709acfbb79de47c27863d64eb
for /f %%a in ('type %TEMP%\6c70ef5709acfbb79de47c27863d64eb') do (
set ofver=%%a
echo --------------Microsoft Office Word--------------------
reg query "%office%\!ofver:~-4!\Word\File MRU" 2>nul
echo --------------Microsoft Office Excel-------------------
reg query "%office%\!ofver:~-4!\Excel\File MRU" 2>nul
echo --------------Microsoft Office PowerPoint--------------
reg query "%office%\!ofver:~-4!\PowerPoint\File MRU" 2>nul)

或者：

@echo off
set office=HKEY_CURRENT_USER\Software\Microsoft\Office

for /f "tokens=*" %%a in (' reg query %office% ^| findstr "1[124]\.0" ') do (
    
    echo --------------Microsoft Office Word--------------------
    reg query "%office%\%%~nxa\Word\File MRU"
    
    echo --------------Microsoft Office Excel-------------------
    reg query "%office%\%%~nxa\Excel\File MRU"
    
    echo --------------Microsoft Office PowerPoint--------------
    reg query "%office%\%%~nxa\PowerPoint\File MRU"
    
) 2>nul

pause
复制代码

TOP

missll

一级士官

Rank: 2

帖子: 85
积分: 129
技术: 2
捐助: 0
注册时间: 2011-4-15

6楼

发表于 2012-11-16 17:23 | 只看该作者

本帖最后由 missll 于 2012-11-16 17:26 编辑

感谢大家回复我对变量延迟不太了解我也找过文章看过但没消化。。

我自己修改了一下：

@echo off
(reg query HKEY_CURRENT_USER\Software\Microsoft\Office | find "11.0" || reg query HKEY_CURRENT_USER\Software\Microsoft\Office | find "12.0" || reg query HKEY_CURRENT_USER\Software\Microsoft\Office | find "14.0")>%TEMP%\6c70ef5709acfbb79de47c27863d64eb
for /f "tokens=1* delims=" %%a in ('type %TEMP%\6c70ef5709acfbb79de47c27863d64eb') do (
    echo --------------Microsoft Office Word--------------------
reg query "%%a\Word\File MRU" 2>nul
    echo --------------Microsoft Office PowerPoint--------------
reg query "%%a\PowerPoint\File MRU" 2>nul
    echo --------------Microsoft Office Excel-------------------
reg query "%%a\Excel\File MRU" 2>nul

)
复制代码

这样也可以的。最后还是感谢大家回复~~~~

花开不问月,不语笑红尘.

TOP

missll

一级士官

Rank: 2

帖子: 85
积分: 129
技术: 2
捐助: 0
注册时间: 2011-4-15

7楼

发表于 2012-11-16 17:28 | 只看该作者

本帖最后由 missll 于 2012-11-16 17:29 编辑

回复 5# tmplinshi

感谢回复，谢谢讲解，我再看看findstr的帮助学习下。

花开不问月,不语笑红尘.

TOP

missll

一级士官

Rank: 2

帖子: 85
积分: 129
技术: 2
捐助: 0
注册时间: 2011-4-15

8楼

发表于 2012-11-16 17:28 | 只看该作者

回复 4# BAT-VBS

感谢~~~~ 再学习下。

花开不问月,不语笑红尘.

TOP

返回列表

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[注册表类] [已处理]获取word打开历史的批处理为什么执行第一次错误第2次正确呢？

[收藏此主题] [关注此主题的新回复]

[通过 QQ、MSN 分享给朋友]

[注册表类] [已处理]获取word打开历史的批处理为什么执行第一次错误 第2次正确呢？

[收藏此主题] [关注此主题的新回复]

[通过 QQ、MSN 分享给朋友]

[注册表类] [已处理]获取word打开历史的批处理为什么执行第一次错误第2次正确呢？