[文本处理] 批处理如何每5分钟批量ping多个ip 并将ave值放入txt文件？

@echo off &&color 0a
setlocal enabledelayedexpansion
pushd "%cd%\"
:main
if not exist "ip.txt" msg %username% /time:5 "错误！！请确认IP地址已存入当前目录下的ip.txt文本！！！" &&call exit
if not exist "ping_result.txt" echo.IP		Date		Time		AVE >ping_result.txt
for /f "delims=" %%a in (ip.txt) do (
  set "ip=%%a"
  echo.正在Ping !ip! , 请稍后 ....
  ping -w 500 -n 4 !ip! | findstr /i "Average" >tmp.txt ||set "Ave=NULL" 
  for /f "tokens=3 delims=," %%i in (tmp.txt) do (
    set "Average=%%i"
    for /f "tokens= 3 delims= " %%m in ("!Average!") do (
    set "Ave=%%m"
    )
  )
  echo.!ip!	!date:~,10!	!time:~,8! 	!Ave! >>ping_result.txt
)
del /q /f tmp.txt
call exit
复制代码

192.168.1.1
192.168.1.2
......
复制代码

for i=0 to 65536
  WSCript.CreateObject("WSCript.shell").run "pp.bat", 1
  WSCript.sleep "300000"
next
复制代码

taskkill /f /im "wscript.exe"
复制代码

if "%~1"=="" mshta vbscript:createobject("wscript.shell").run("%~s0 0",0)(window.close)&exit
@echo off&setlocal enabledelayedexpansion
if not exist "ip.txt" msg %username% /time:5 "错误！！请确认IP地址已存入当前目录下的ip.txt文本！！！"&exit
if not exist "ping_result.txt" >ping_result.txt echo.IP		Date		Time		AVE
:loop
for /f "delims=" %%i in (ip.txt) do (
  set "Ave=NULL"
  for /f "skip=11 tokens=4 delims==" %%j in ('ping -w 500 -n 4 %%i') do set "Ave=%%j"
  >>ping_result.txt echo;%%i	!date:~,10!	!time:~,8!	!Ave: =!
)
ping/n 300 127.1>nul
goto loop
复制代码