返回列表发帖

yj850624

一级士官

Rank: 2

帖子: 7
积分: 108
技术: 0
捐助: 0
注册时间: 2009-5-11

1楼 跳转到 » 倒序看帖

打印

字体大小: tT

发表于 2013-1-24 22:14 | 只看该作者

[文本处理] 字符查询测试的BAT脚本为何出错？

@echo off & setlocal EnableDelayedExpansion
title 字符查询测试脚本
color 0a
for /f "delims=" %%i in (1.txt) do (
  set string=%%i
  echo !string!
  for /f "delims=" %%t in ('findstr /m "!string!" 2.txt') do (
    set str=%%t
    call :abc
)
)
pause
exit
:abc
if not "!str!"=="" (
echo !string!存在于文件：!str! >>reasult.txt
set str=
) else (
echo !string!不存在 >>reasult1.txt
)  
:eof
复制代码

这段代码的大意是想凡是在2.txt凡是能查找到的关键字都写到reasult.txt文件中了，同时还想把没有查到的关键字写到reasult1.txt中，但是在if子句中前半句可执性，后半句else子句执行不了。这是为什么啊？？有人能解释一下吗?谢谢！

配套的1.txt和2.txt我上传到附件里了。如果有知道的兄弟，帮忙给指教一下吧，谢谢啊！

batman

荣誉版主

Rank: 8 Rank: 8

帖子: 2702
积分: 14562
技术: 177
捐助: 630
注册时间: 2008-6-16

2楼

发表于 2013-1-24 22:26 | 只看该作者

本帖最后由 batman 于 2013-1-24 22:28 编辑

findstr /g:1.txt 2.txt>reasult.txt
findstr /v /g:1.txt 2.txt>reasult1.txt
复制代码

ps:请楼主以后像我这样把代码括起来

＊＊＊共同提高＊＊＊

TOP

BAT-VBS

少将

Rank: 8 Rank: 8

帖子: 888
积分: 6682
技术: 88
捐助: 0
注册时间: 2012-10-27

3楼

发表于 2013-1-24 22:54 | 只看该作者

按照楼主的思路：

@echo off
for /f "delims=" %%i in (1.txt) do (
    for /f "delims=" %%t in ('findstr /m "%%i" 2.txt') do (
        call :abc %%i %%t
    )
)
goto :eof

:abc
if "%2" neq "" (
    >>reasult.txt echo %1存在于文件：%2
) else (
    >>reasult1.txt echo %1不存在
)
复制代码

TOP

yj850624

一级士官

Rank: 2

帖子: 7
积分: 108
技术: 0
捐助: 0
注册时间: 2009-5-11

4楼

发表于 2013-1-25 10:25 | 只看该作者

回复 2# batman

您好！首先，不好意思。下次发帖我会将代码括起来的。您提供的代码中给findstr加上/v参数能达到我的目标，中文

的cmd帮助机器翻译的太抽象了，我理解的不好所致。您的方法曲线救国、非常巧妙，但是不知您可否指出我的代码中

为什么在if-else中，else之后的代码始终没有执行呢？

TOP

yj850624

一级士官

Rank: 2

帖子: 7
积分: 108
技术: 0
捐助: 0
注册时间: 2009-5-11

5楼

发表于 2013-1-25 10:25 | 只看该作者

回复 3# BAT-VBS

您好！首先，谢谢您给出的代码，您的这套代码比我的强多了，变量传递用的很好，给我非常大的启发。但是您的代码存在一样的问题，就是在if-else中，else之后的代码始终没有执行。我想知道这是为什么？谢谢啊！

TOP

hankerer

一级士官

Rank: 2

帖子: 61
积分: 102
技术: 12
捐助: 0
注册时间: 2011-9-3

6楼

发表于 2013-1-25 12:43 | 只看该作者

回复 4# yj850624

因为findstr /m这一行如果找不到的话就会返回空，而返回空的话，这条for语句根本就不会执行的。

TOP

hankerer

一级士官

Rank: 2

帖子: 61
积分: 102
技术: 12
捐助: 0
注册时间: 2011-9-3

7楼

发表于 2013-1-25 12:49 | 只看该作者

回复 5# yj850624

改成这样试试吧

@echo off & setlocal EnableDelayedExpansion
 title 字符查询测试脚本
 color 0a
 for /f "delims=" %%i in (1.txt) do (
   set string=%%i
   echo !string!in 1.txt
   for /f "delims=" %%t in ('findstr /m "!string!" 2.txt') do (
     set str=%%t
   )
  if defined str (
 		echo !string!存在于文件：!str! >>reasult.txt
	         ) else (
 	             echo !string!不存在 >>reasult1.txt
	        )
 )
 pause
复制代码

TOP

terse

中将

Rank: 8 Rank: 8

帖子: 2339
积分: 9739
技术: 475
捐助: 0
注册时间: 2008-2-25

8楼

发表于 2013-1-25 15:41 | 只看该作者

本帖最后由 terse 于 2013-1-25 15:57 编辑

上面变量 STR 不清呢
去除变量直接写

@echo off & setlocal EnableDelayedExpansion
title 字符查询测试脚本
color 0a
for /f "delims=" %%i in (1.txt) do (
   (for /f "delims=" %%j in ('findstr /im "%%i" 2.txt') do (
       >>reasult.txt echo %%i存在于文件：%%j
   ))||>>reasult1.txt echo %%i不存在 
)
pause
复制代码

TOP

yj850624

一级士官

Rank: 2

帖子: 7
积分: 108
技术: 0
捐助: 0
注册时间: 2009-5-11

9楼

发表于 2013-1-25 18:47 | 只看该作者

回复 6# hankerer

非常感谢啊！原来是这样的，我也做了相关的实验，证明的确如此啊。不知这算不算for语句的一个小bug呢？哈哈。

TOP

yj850624

一级士官

Rank: 2

帖子: 7
积分: 108
技术: 0
捐助: 0
注册时间: 2009-5-11

10楼

发表于 2013-1-25 18:49 | 只看该作者

回复 7# hankerer

if语句中的defined参数，我之前看的教程中没有，查阅cmd命令帮助学习了，在这里用的真好，真巧。谢谢啊！

TOP

yj850624

一级士官

Rank: 2

帖子: 7
积分: 108
技术: 0
捐助: 0
注册时间: 2009-5-11

11楼

发表于 2013-1-25 18:56 | 只看该作者

回复 8# terse

wow！
说实话，我是初学者，所以代码写的有些罗嗦。感谢前面的几位坛友，顺着我的思路帮我解决问题。而您的代码能达到目的并且很简洁，这的确是我要学习的，并且是我下一步要改进的地方。感谢您的帮忙！

TOP

BAT-VBS

少将

Rank: 8 Rank: 8

帖子: 888
积分: 6682
技术: 88
捐助: 0
注册时间: 2012-10-27

12楼

发表于 2013-1-25 19:12 | 只看该作者

回复 9# yj850624

不是bug，它的工作方式就是那个样子的。

TOP

返回列表

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[文本处理] 字符查询测试的BAT脚本为何出错？

[收藏此主题] [关注此主题的新回复]

[通过 QQ、MSN 分享给朋友]