VBS如打开百度搜索，其中关键字从配置文件提取？

@set /p k=<k.txt
@start iexplore "http://www.baidu.cn/s?wd=%k%"
复制代码

Option Explicit

OpenBaidu GetRandomLine("k.txt")



Sub OpenBaidu(sKey)
        Dim oShell
        Set oShell = CreateObject("WScript.Shell")
        oShell.Run "iexplore http://www.baidu.cn/s?wd=" + sKey
        Set oShell = Nothing
End Sub

Function GetRandomLine(sFile)
        Dim oFso, oFile, iLineNo
        Set oFso = CreateObject("Scripting.FileSystemObject")
        Set oFile = oFso.OpenTextFile(sFile)
        iLineNo = GetRandom(GetFileLineCount(sFile))
        Do Until oFile.AtEndOfLine
                If iLineNo = oFile.Line Then
                        GetRandomLine = oFile.ReadLine
                        Exit Do
                Else
                        oFile.SkipLine
                End If        
        Loop
        oFile.Close
        Set oFile = Nothing
        Set oFso = Nothing        
End Function

Function GetFileLineCount(sFile)
        Dim oFso, oFile
        Set oFso = CreateObject("Scripting.FileSystemObject")
        Set oFile = oFso.OpenTextFile(sFile)
        While Not oFile.AtEndOfLine
                oFile.SkipLine        
        Wend
        GetFileLineCount = oFile.Line
        oFile.Close
        Set oFile = Nothing
        Set oFso = Nothing
End Function

Function GetRandom(n)
        Randomize
        GetRandom = Int(Rnd * n + 1)
End Function
复制代码

Dim objIE,Lines
CreateIe
RegExpTest(ReadText("sh.ini"))

Function RegExpTest(string)
msgbox lines
   Set RegEx1=New RegExp
   RegEx1.Pattern="(.*)(\n)"     
   RegEx1.IgnoreCase=True 
   RegEx1.Global=True      
   Set A=RegEx1.Execute(string)
   Do
      Set AA=A(Int((Lines-1)*rnd))
      BB=AA.SubMatches(0)
      SendWeb BB
      WScript.Sleep 5000
   Loop
End Function

Sub SendWeb(sText)
With objIe
.Navigate "www.baidu.com"
Do While (.Busy)
Wscript.Sleep 200
Loop
.Visible=1
.Document.All.wd.Value=sText
.Document.All.sb.click
End With
End Sub 

Function CreateIe
Set objIE=WScript.CreateObject("InternetExplorer.Application","UE_")
objIE.Navigate("about:blank")
End Function

Function ReadText(FilePath)
Dim Fso,Rso
Set Fso=CreateObject("Scripting.FileSystemObject")
Set Gso=Fso.GetFile(FilePath)
Set Rso=Gso.OpenAsTextStream(1)
ReadText=Rso.ReadAll
Lines=Rso.Line
Set Fso=Nothing
End Function

Sub UE_OnQuit()
WScript.Quit
End Sub
复制代码