批处理之家 » BAT求助&讨论 » [已解决]找出10000以内的所有回文数的批处理代码错在哪里？

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

返回列表发帖

Rank: 5 Rank: 5

帖子: 226
积分: 1298
技术: 9
捐助: 0
注册时间: 2012-7-4

1楼 跳转到 » 倒序看帖

字体大小: tT

发表于 2014-7-24 20:25 | 只看该作者

[数值计算] [已解决]找出10000以内的所有回文数的批处理代码错在哪里？

本帖最后由悬崖之树于 2014-7-25 21:06 编辑

@echo off

setlocal enabledelayedexpansion

for /l %%i in (1 1 10000) do (
   set str=%%i
   set /a n=0
   call :loop
   if !str!==!res! echo %%i   
)
pause
:loop
if "!str:~%n%,1!" neq "" (
   set /a n+=1&goto loop
)
for /l %%i in (1 1 %n%) do (
   set "i=-%%i"
   call set res=!res!%%str:~!i!,1%%
)
复制代码

下面的代码也不行：

@echo off

setlocal enabledelayedexpansion

for /l %%i in (1 1 10000) do (
   set str=%%i
   set /a n=0
   call :loop
   if !str!==!res! echo %%i   
)
pause
:loop
call set t=%%str:~!n!,1%%
if "!t!" neq "" (
   set res=!t!!res!
   set /a n+=1
   goto loop
)
复制代码

我的算法是把10000以内的所有的数反写，如果反写后的数和正写的数一样的话，就认为是回文数。

1 评分人数

Batcher: 感谢给帖子标题标注[已解决]字样PB + 2

时光荏苒||新陈代谢&&涛声依旧||本性难移

Rank: 8 Rank: 8

帖子: 6388
积分: 18843
技术: 982
捐助: 100
注册时间: 2010-10-9

2楼

发表于 2014-7-24 21:23 | 只看该作者

因为缺了 set "res=" 呀

1 评分人数

悬崖之树: 乐于助人技术精湛技术 + 1

链接：在线第三方命令行工具下载 bat、vbs、js 原生混编

Rank: 8 Rank: 8

帖子: 6388
积分: 18843
技术: 982
捐助: 100
注册时间: 2010-10-9

3楼

发表于 2014-7-24 21:35 | 只看该作者

写完可以看下别人的思路，感觉顶楼代码优化的余地还很大...
举几个例子：
1、与其先生成再判断查找，不如根据规则直接生成
2、已知长度在可容忍范围内时，避免用 loop 计算长度

:loop
if "!str:~%n%,1!" neq "" (
   set /a n+=1&goto loop
)
复制代码

可以简化成：

for /l %%a in (9 -1 1) do if "!str:~%%a!"=="" set n=%%a
复制代码

或更高效的：

set list=!str!987654321
set n=!list:~9,1!
复制代码

3、

   set "i=-%%i"
   call set res=!res!%%str:~!i!,1%%
复制代码

这里没必要 set "i=-%%i" 啊，可以简化成：

   set res=!res!!str:~-%%i,1!
复制代码

链接：在线第三方命令行工具下载 bat、vbs、js 原生混编

Rank: 5 Rank: 5

帖子: 226
积分: 1298
技术: 9
捐助: 0
注册时间: 2012-7-4

4楼

发表于 2014-7-24 22:16 | 只看该作者

回复 3# CrLf

谢谢 crlf 的提醒，让我茅塞顿开啊。

时光荏苒||新陈代谢&&涛声依旧||本性难移

Rank: 8 Rank: 8

帖子: 2339
积分: 9739
技术: 475
捐助: 0
注册时间: 2008-2-25

5楼

发表于 2014-7-26 00:30 | 只看该作者

回复 4# 悬崖之树
这个效率提升点

@echo off&setlocal enabledelayedexpansion
for /l %%i in (1 1 10000) do (
    set str=%%i&set "var=!str:~-1!"
    set "len=%%i543210"
    for /l %%j in (2,1,!len:~5^,1!) do set "var=!var!!str:~-%%j,1!"
    if "%%i" == "!var!" echo,%%i
)
pause
复制代码

Rank: 8 Rank: 8

帖子: 6388
积分: 18843
技术: 982
捐助: 100
注册时间: 2010-10-9

6楼

发表于 2014-7-26 03:02 | 只看该作者

回复 5# terse

其实截一半就好，判断大数字效率提升很明显

@echo off&setlocal enabledelayedexpansion
for /l %%i in (1 1 100000000) do (
    set str=%%i&set var=!str:~-1!
    set "len=%%i443322111"
    for /l %%j in (2,1,!len:~9^,1!) do set "var=!var!!str:~-%%j,1!"
    for %%j in (!len:~9^,1!) do if "!str:~,%%j!" == "!var!" echo,%%i
)
pause
复制代码

话说vbs有原生的 StrReverse，做这个还是很方便的...

For i=1 To 10000
	If StrReverse(i)=CStr(i) Then WScript.Echo i
Next
复制代码

2 评分人数

xxpinqz: 厉害啊技术 + 1
terse: 思路决定效率，技术 + 1

链接：在线第三方命令行工具下载 bat、vbs、js 原生混编

Rank: 2

帖子: 55
积分: 129
技术: 6
捐助: 0
注册时间: 2013-5-25

7楼

发表于 2014-7-26 18:12 | 只看该作者

这是我自己的方法（原创，代码可能不好，但可以找出10000以内的回文数）：

@echo off
setlocal enabledelayedexpansion
set ctr=0
set "str="
:head
set /a ctr=ctr+1
set nm=!ctr!
if !nm! leq 99 goto:head
if !nm! leq 999 set str=!nm:~2,1!!nm:~1,1!!nm:~0,1!& goto:pd
if !nm! leq 9999 set str=!nm:~3,1!!nm:~2,1!!nm:~1,1!!nm:~0,1!& goto:pd
:pd
if /i asd!str!asd equ asd!nm!asd echo !nm!>>shu.txt
if !ctr!==10000 exit
goto:head
复制代码