[文件操作] [已解决]批处理如何根据列表文件查找并复制文件？

@echo off & setlocal EnableDelayedExpansion
cd.>4.txt
for /f "delims=" %%a in ('dir/a-d/b/s "e:\2"') do (
    set /a total+=1
    findstr /i /x /c:"%%~na" "1.txt">nul 2>nul&&(
       set /a num+=1
       set/p=复制 %%~nxa 到 [e:\3]目录<nul & (copy /y "%%a" "e:\3\">nul 2>nul && echo 成功 || echo 失败)
       set/p=复制 %%~nxa 到 [d:\4]目录<nul & (copy /y "%%a" "d:\4\">nul 2>nul && echo 成功 || echo 失败)
       echo %%~na [sound:_%%~na%%~xa]>>4.txt
    ) || set /a number+=1)

echo. & echo 总查找[%total%]条, 找到[%num%]条, 未找到[%number%]条。
pause
复制代码

@echo off & setlocal EnableDelayedExpansion
cd/d "%~dp0"
pushd "%~dp0"

for /f "delims=" %%a in ('type 1.txt') do (
   set "name="
   set /a total+=1
   for /f "delims=" %%e in ('dir/a-d/b/s "e:\2\%%a.*"') do (
      pushd "%%~dpe"
      if "%%~xe" neq "" if /i exist "%%~nxe" (
        set /a num+=1
        set "name=true"
        echo 复制 %%~nxe  到 [e:\3] && copy /y "%%~nxe" "e:\3">nul 2>&1
        echo 复制 %%~nxe  到 [d:\4] && copy /y "%%~nxe" "d:\4">nul 2>&1
        echo %%~ne [sound:_%%~nxe]>>"%~dp04.txt")
        popd
        )
   if not defined name set /a number+=1
   )

echo. & echo 总查找[%total%]条, 找到[%num%]条, 未找到[%number%]条。
pause
复制代码