[文件操作] 【已解决】求助批处理行未空格去除办法

@echo off
set /p _user=please enter your Domain ID:
set /p _pw=Please enter your Domain PW:
cls 
for /f "delims=:" %%a in ('findstr /in "^:setup$" "%~f0") do set line=%%a
for /f "tokens=1,2* delims=:" %%i in ('more +%line% "%~f0"') do (
	for /f "tokens=1 delims=/" %%s in (%%j) do cmdkey add:%%s /user:%_user% /pass:%_pw%
    call :rightTrim "%%j"
	net use %%i: "%return%" /p:y
)
echo;Done!
exit /b
:rightTrim
set "str=%~1"
set /a pos=-1
set return=
if not defined str exit /b
if "%str: =%"=="" exit /b
:loop
call set "char=%%str:~%pos%,1%%"
if "%char%"==" " (
    set /a pos-=1
    goto loop
)
if %pos% equ -1 (
    set "return=%str%"
) else (
    set /a pos+=1
    call set "return=%%str:~0,%pos%%%"
)
exit /b
:setup
N:\\10.21.119.168\AllDept  
O:\\scnfsvr01\AllDept    
P:\\scnfsvr01\Shared     
S:\\10.21.119.168\Shared   
Z:\\scnfsvr01\Air\Huawei CS 
复制代码

@echo off
for /f "delims=:" %%i in ('findstr /n "^:netdrive$" "%~f0"') do more ++%%i "%~f0" >.\backup\%username%.cmd
for /f "tokens=2*" %%i in ('net use^|find ":"') do (
	setlocal enabledelayedexpansion
	set dr=%%j
	set dr=!dr:Microsoft Windows Network=!
	echo %%i!dr!
	endlocal)>>.\backup\%username%.cmd
msg * Backup done!!	
exit /b
:netdrive
@echo off & title Network Driver Re-Map Tools for GWM/ Network Driver Re-Map is in progress...
set /p _user=please enter your Domain ID:
set /p _pw=Please enter your Domain PW:
cls
for /f "delims=: tokens=1,2*" %%a in ('for /f "delims=:" %%i in ^('findstr /n "^:setup$" "%~f0"'^) do @more ++%%i "%~f0"') do (
	for /f "delims=\ tokens=1" %%x in ("%%b") do cmdkey /add:%%x /user:schenker_sc\%_user% /pass:%_pw%
	net use %%a: "\\%%~pnb" /p:y /y
)
msg * Done
explorer
exit
:setup
复制代码

(for /f "tokens=2*" %%i in ('net use^|find ":"') do (
    setlocal enabledelayedexpansion
    set dr=%%j
    set dr=!dr:Microsoft Windows Network=!
    for /f "tokens=*" %%a in ("%%i!dr!") do (
        echo %%~fa
    )
    endlocal
))>.\backup\%username%.cmd
复制代码