[文件操作] 批处理如何修改压缩包内文件的文件名为压缩包的文件名？

@echo off & cd /d "%~dp0"
rem 获取RAR安装位置
reg query "HKLM\SOFTWARE\WinRAR" /v exe64>nul 2>nul && (
	for /f "tokens=2*" %%a in ('reg query "HKLM\SOFTWARE\WinRAR" /v exe64') do set "R_Path=%%b"
) || for /f "tokens=2*" %%a in ('reg query "HKLM\SOFTWARE\WOW6432Node\WinRAR" /v exe32') do set "R_Path=%%b"

for /f "delims=" %%m in ("%R_Path%\..") do set "RarPath=%%~fm"

REM 假定RAR密码为 123456
md "%temp%\RARtmp" 2>nul
for /f "delims=" %%a in ('dir/a-d/b "*.rar"') do (
	"%RarPath%\rar.exe" e ".\%%a" "%temp%\RARtmp\" -hp123456
	for /f "delims=" %%i in ('dir/a-d/b "%temp%\RARtmp\"') do "%RarPath%\rar.exe" rn ".\%%a" %%i "%%~na%%~xi"
	del /q/f "%temp%\RARtmp\*"
)
rd /s/q "%temp%\RARtmp"
pause
复制代码

@echo off

rem 设置7ZIP路径
set "path=%path%;C:\Program Files\7-Zip"

rem 设置解压密码
set "password=123456"

for /r %%a in (*.rar,*.7z,*.zip) do (
	set "archpath=%%a"
	set "archname=%%~na"
	for /f "skip=18 tokens=6 delims= " %%b in ('7z l "%%a" *.* -p"%password%" -r^|find /v "files"') do (
		set "fullname=%%b"
		set "basename=%%~nb"	
		call :get_name
	)
)
pause&exit

:get_name
call,set "newname=%%fullname:%basename%=%archname%%%"
7z rn "%archpath%" "%fullname%" "%newname%" -p"%password%">nul
exit /b 0
复制代码