[注册表类] [已解决]批处理怎样提取已安装软件的资料？

systeminfo | findstr "主机名.* 初始安装日期.* 物理内存总量.* [1-9].*\.[1-9].*\.[1-9].*\.[1-9]"
复制代码

reg query HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall /s
复制代码

@echo off&setlocal enabledelayedexpansion
(set uninsRoot=HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall)
(set _skip=0)
for /f "delims=" %%z in ('reg query !uninsRoot! /s ^| findstr /i "displayname uninstallstring"') do (
  (set _F=%%z)&(set QUSP=!_F!)&(set nameP=!_F!)&(set sp_rjgxP=!_F!)&(set sp_gxP=!_F!)&(set usP=!_F!)
  (set nameP=!nameP:DisplayName=!)&(set usP=!usP:UninstallString=!)&(set QUSP=!QUSP:QuietUninstallString=!)
  (set sp_rjgxP=!sp_rjgxP:软件更新=!)&(set sp_gxP=!sp_gxP:(KB=!)
  
  if "!_F!" neq "!nameP!" (
    (set _skip=0)   
    if "!_F!" neq "!sp_rjgxP!" (set _skip=1)
    if "!_F!" neq "!sp_gxP!" (set _skip=1)
  )
  
  if !_skip! equ 0 if "!_F!" equ "!QUSP!" ( rem 跳过 QuietUninstallString
    (set line=%%z)&(set line=!line:*REG_SZ=!)&(set line=!line:*REG_EXPAND_SZ=!)&(set line=!line:~1!)  
    if "!_F!" neq "!nameP!" (echo.)&echo !line!

    if "!usP!" neq "!_F!" (
      for /f "delims=" %%B in ("!line!") do (
        (set softdir=%%~sdpB)
        if exist !softdir!nul (
          for /f "delims=" %%l in ('dir "%%~dpB" /a-d /s /-c ^| findstr "个文件"') do (
            for /f "tokens=3 delims= " %%a in ("%%l") do (set size=%%a)
          )
          set /a "size=(size+1048576/2)/1048576"
          echo %%~dpB !size!MB %%~tB
        )       
      )
    )
  )
)
pause
复制代码