[文本处理] 批处理LRC歌词脚本编辑器,按按空格键轻松做歌词

foxJL

@echo off & setlocal enabledelayedexpansion
color 37 & mode con cols=62 lines=40
::2013.9.10 解决文件名中存在空格运行出错的问题.
::2013.9.11 使LRC歌词保存在TXT文件同一目录.
title LRC歌词脚本编辑器  by foxjl   bathome.net做最实用的批处理论坛
set errorcode=0%1
echo,
echo,       使用说明:
echo,
echo,       首先请准备与歌曲完全匹配的歌词,用TXT文本格式
echo,       保存,制作时把歌词拖到此脚本图标上或此脚本的对
echo,       话框里.
echo,       使用音乐播放器播放相同的歌曲,用空格键使制作中
echo,       的歌词与播放中的音乐保持同步.
echo,       制作成功的LRC歌词与TXT文件在同一目录
echo,
echo ━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━
if %errorcode% equ 0 (set /p lrc=拖入歌词文本:) else (set lrc=%1)
for %%i in (%lrc%) do (set txtpath=%%~dpni)
echo,&echo,按空格键开始制作[%txtpath%.LRC]&pause>nul
echo,>!txtpath!.lrc
call :s %time:~0,2% %time:~3,2% %time:~6,2% %time:~9,2% startMS
cls&echo,&echo,━━━━━━━━━━请与播放中的音乐保持同步━━━━━━━━━&echo,
for /f "usebackq delims=" %%i in (%lrc%) do (
call :s !time:~0,2! !time:~3,2! !time:~6,2! !time:~9,2! endMS
set /a MS=!endMS!-!startMS!,M=ms/6000,S=ms%%6000/100,MS%%=100
echo [!M!:!S!.!MS!]%%i 
echo [!M!:!S!.!MS!]%%i>>!txtpath!.lrc
pause>nul
echo,
)
echo,&echo,━━歌词制作完成,请检查[%txtpath%.LRC]文件.按任意键退出.
pause>nul
exit
 
:s
set /a %5=(1%1%%100*360000)+(1%2%%100*6000)+(1%3%%100*100)+1%4%%100
goto :eofCOPY

歌词制作中:

用foobar2000验证,完美同步.

hepeisheng

厉害