[文件操作] 【已解决】批处理如何把每个文件夹里面的图片合成单独的视频？

zhengzhenhui

一个大文件夹下里面的每个子文件夹的图片，合成一个视频
比如A文件夹里面的图，就是A视频
B文件夹  就是B视频
谢谢，求大佬

smss

https://blog.csdn.net/qq_54410547/article/details/132104735

DOSforever

回复 2# smss


    我估计他的意思是要把一个文件夹里的一组静态图片合成为一个动态视频

zhengzhenhui

回复 3# DOSforever


    是的是的

newswan

参考
https://yanke.info/?id=182

Batcher

回复 1# zhengzhenhui

@echo off
for /f "delims=" %%i in ('dir /b /ad') do (
    echo --- Processing folder: %%i
    pushd "%%i"
    (for /f "delims=" %%j in ('dir /b /a-d *.jpg') do (
        echo file '%%j'
    ))>"FileList.txt"
    ffmpeg -v quiet -f concat -safe 0 -i "FileList.txt" -c:v libx264 -r 1 -pix_fmt yuv420p "%%i.mp4"
    popd
)
复制代码

打开记事本，复制粘贴以上代码，文件，另存为：
    文件名：MyRun.bat
    编码：ANSI
下载命令行工具 FFmpeg 例如：ffmpeg-n7.0-latest-win64-gpl-7.0.zip
    https://github.com/BtbN/FFmpeg-Builds/releases
解压缩之后把 ffmpeg.exe 和此脚本放在同一个文件夹下
双击执行脚本：MyRun.bat

zhengzhenhui

回复 6# Batcher


    再次麻烦您了，终于找人下载下来【ffmpeg-n7.0-latest-win64-gpl-7.0】解压之后批处理和图片文件夹是放在包含ffmpeg.exe的解压文件里面嘛

zhengzhenhui

回复  zhengzhenhui 打开记事本，复制粘贴以上代码，文件，另存为：
    文件名：MyRun.bat
    编码：AN ...
Batcher 发表于 2024-6-4 13:52

    测试成功，忘记加变量环境了，我又重新优化代码和注释

@echo off
for /f "delims=" %%i in ('dir /b /ad') do (
    rem 遍历当前目录下的所有子文件夹
    echo --- Processing folder: %%i
    rem 输出正在处理的文件夹名称
    pushd "%%i"
    rem 进入该子文件夹

    (for /f "delims=" %%j in ('dir /b /a-d *.jpg *.png') do (
        rem 遍历子文件夹中的所有 JPG 图片文件
        echo file '%%j'
        rem 输出图片文件路径
        echo duration 2
        rem 设定每张图片的显示时长为
    ))>"FileList.txt"
    rem 将上述信息写入 FileList.txt 文件

    ffmpeg -v quiet -f concat -safe 0 -i "FileList.txt" -c:v libx264 -pix_fmt yuv420p "%%i.mp4"
    rem 使用 ffmpeg 依据 FileList.txt 中的信息将图片合成为 MP4 视频

    popd
    rem 退出当前子文件夹回到上一级目录
)
复制代码