批处理之家 - Powered by Discuz! Board

标题: [文本处理] 批处理文本替换怎样处理等号？ [打印本页]

作者: abc163635 时间: 2010-12-22 14:11 标题: 批处理文本替换怎样处理等号？

@echo off 
setlocal enabledelayedexpansion 
set replaced=ResultPoint=1
set all=ResultPoint=3
for /f "delims= usebackq" %%i in ( ^^!Setup.txt ) do ( 
    set str=%%i 
    set str=!str:%replaced%=%all%!
    echo !str! >> ^^!Setup.txt_tmp.txt
) 
copy ^^!Setup.txt ^^!Setup.txt_bak.txt >nul 2>nul 
move ^^!Setup.txt_tmp.txt ^^!Setup.txt 
复制代码

我想将!Setup.txt里面的ResultPoint=1替换成ResultPoint=2。注意不能用2替换1，因为文本里面有很多1，只是ResultPoint=1这一个地方需要替换，其他地方不用

[ 本帖最后由 abc163635 于 2010-12-22 18:05 编辑 ]

作者: hanyeguxing 时间: 2010-12-22 15:14

@echo off
(for /f "tokens=1* delims==" %%a in (!Setup.txt) do if "%%b"=="" (echo %%a) else (
    set "Han=%%a"
    set "Ye=%%b"
    setlocal enabledelayedexpansion
    if /i "!Han:~-11!"=="ResultPoint" if "!Ye:~0,1!"=="1" set Gu==
    if defined Gu (echo !Han:~0,-11!ResultPoint=2!Ye:~1!) else echo !Han!=!Ye!
    Endlocal
))>han.ye
del /q !Setup.txt
ren han.ye !Setup.txt
复制代码

[ 本帖最后由 hanyeguxing 于 2010-12-22 15:39 编辑 ]

作者: abc163635 时间: 2010-12-22 16:14

太感谢了！！！

作者: abc163635 时间: 2010-12-22 16:28 标题: 回复 2楼的帖子

我看不大明白呢
如果将!Setup.txt里面的ResultPoint=点卡替换成ResultPoint=元宝怎么改一下啊

作者: ithinkican 时间: 2010-12-22 16:30

每个人的编程思想不一样,方法也亦然。

作者: hanyeguxing 时间: 2010-12-22 16:36 标题: 回复 4楼的帖子

要求文本每行中最多只能有一个=：

@echo off
(for /f "tokens=1* delims==" %%a in (!Setup.txt) do if "%%b"=="" (echo %%a) else (
    set "Han=%%a"
    set "Ye=%%b"
    setlocal enabledelayedexpansion
    if /i "!Han:~-11!"=="ResultPoint" if "!Ye:~0,2!"=="点卡" set Gu==
    if defined Gu (echo !Han:~0,-11!ResultPoint=元宝!Ye:~2!) else echo !Han!=!Ye!
    Endlocal
))>han.ye
del /q !Setup.txt
ren han.ye !Setup.txt
复制代码

如果有有限个数的=，也可以用这个方法扩展。
如果不确定，请参考http://bbs.bathome.net/thread-6038-1-1.html

[ 本帖最后由 hanyeguxing 于 2010-12-22 16:48 编辑 ]

作者: abc163635 时间: 2010-12-22 20:21

谢谢孤星大哥，解决了大问题！

作者: CUer 时间: 2010-12-22 22:45

sed -i "s/ResultPoint=1/ResultPoint=2/g" 1.txt
复制代码

欢迎光临批处理之家 (http://bathome.net./)