type INTL.INF>INTL.TMP@echo off&setlocal enabledelayedexpansion
(for /f "tokens=1* delims=:" %%a in ('findstr /n .* "INTL.TMP"') do if "%%b"=="" (echo/) else (
    set "hy=%%b"
    set hy=!hy:E00E0804=E0860804!
    set hy=!hy:pintlgnt.ime=sun86.ime!
    if /i not "!hy:~0,18!"=="simsun.ttc,,,65536" echo !hy!
))>"INTL.INF"
复制代码

@echo off
(for /f "delims=" %%i in ('findstr /iv "simsun.ttc,,,65536" INTL.INF') do (
   set "str=%%i"
   setlocal enabledelayedexpansion
   set str=!str:e00e0804=e0860804!
   set str=!str:pintlgnt.ime=sun86.ime!
   set num=!str:pintlgnt=!
   if "!num!"=="!str!" echo;!str!
   if /i "!str!"=="[sourcedisksfiles]" (
      echo Sun86.IME    = 107,,,,,,,0,0
      echo Sun86.mb     = 107,,,,,,,0,0
      echo Sun86.chm    = 107,,,,,,,0,0
   )
   endlocal
))>tem
move tem INTL.INF
start "" "INTL.INF"
复制代码

@echo off&setlocal enabledelayedexpansion
type "INTL.INF">temp
set c==
(for /f "tokens=1* delims=:" %%a in ('findstr /nivx "simsun.ttc,,,65536" "temp"') do if "%%b"=="" (echo/) else (
   set "b=%%b"
   if "!c!!d!"=="==" if "!b:~0,1!!b:~-1!"=="[]" (
      echo Sun86.IME    = 107,,,,,,,0,0
      echo Sun86.mb     = 107,,,,,,,0,0
      echo Sun86.chm    = 107,,,,,,,0,0
      set c=&set d=
   )
   if /i "!b!"=="[sourcedisksfiles]" set d==
   set b=!b:e00e0804=e0860804!
   set b=!b:pintlgnt.ime=sun86.ime!
   set a=!b:pintlgnt=!
   if "!a!"=="!b!" echo/!b!
))>"INTL.INF"
del temp
复制代码

@echo off
(for /f "delims=" %%i in ('findstr /iv "simsun.ttc,,,65536" INTL.INF') do (
   set "str=%%i"
   if /i "%%i"=="[sourcedisksfiles]" set /a flag+=1
   setlocal enabledelayedexpansion
   set str=!str:e00e0804=e0860804!
   set str=!str:pintlgnt.ime=sun86.ime!
   set num=!str:pintlgnt=!
   if "!num!"=="!str!" echo;!str!
   if !flag! equ 1 (
      echo Sun86.IME    = 107,,,,,,,0,0
      echo Sun86.mb     = 107,,,,,,,0,0
      echo Sun86.chm    = 107,,,,,,,0,0
   )
   endlocal
))>tem
move tem INTL.INF
start "" "INTL.INF"
复制代码

@echo off&setlocal enabledelayedexpansion
type "INTL.INF">temp
set c==
(for /f "tokens=1* delims=:" %%a in ('findstr /nivx "simsun.ttc,,,65536" "temp"') do if "%%b"=="" (echo/) else (
   set "b=%%b"
   if "!c!!d!"=="==" if "!b:~0,1!!b:~-1!"=="[]" (
      echo Sun86.IME    = 107,,,,,,,0,0
      echo Sun86.mb     = 107,,,,,,,0,0
      echo Sun86.chm    = 107,,,,,,,0,0
      set c=&set d=
   )
   if /i "!b!"=="[sourcedisksfiles]" set d==
   set b=!b:e00e0804=e0860804!
   set b=!b:pintlgnt.ime=sun86.ime!
   set a=!b:pintlgnt=!
   if "!a!"=="!b!" echo/!b!
))>temp2
move temp2 "INTL.INF"
del /q temp
复制代码

@echo off
set wjm=a.txt
(for /f "delims=" %%i in ('findstr /ivn "simsun.ttc,,,65536" %wjm%') do (
   set "str=%%i"
   if defined h set "h="
   if not defined v (
      for /f "tokens=1* delims=:" %%j in ("%%i") do (
         if /i "%%k"=="[sourcedisksfiles]" set s=1
         if defined s if /i "%%k"=="[Locales]" set h=a&set v=a&set "s="
       )
    )
   setlocal enabledelayedexpansion
   set str=!str:*:=!
   if not defined str (echo;) else (
      set str=!str:e00e0804=e0860804!
      set str=!str:pintlgnt.ime=sun86.ime!
      set num=!str:pintlgnt=!
      if defined h (
         echo Sun86.IME    = 107,,,,,,,0,0
         echo Sun86.mb     = 107,,,,,,,0,0
         echo Sun86.chm    = 107,,,,,,,0,0
       )
      if "!num!"=="!str!" echo;!str!
   )
   endlocal
))>tem
move tem "%wjm%"
start "" "%wjm%"
复制代码

哦，经过一番仔细琢磨，终于想明白了：

原来寒夜老师的开关是无值开关，它只是用来控制到处理完第一个[sourcedisksfiles]节之后关闭用的，是一个进程时间控制器。由此理解了寒夜老师的讲解：
1，首先，要找到[sourcedisksfiles]行，并设置标志d
2，当标志d存在时，检查行的首和尾是否分别为 []，为了不包括[sourcedisksfiles]本身，本代码需要在1代码前
4，同时删除标志c和标志d：这里删除标志d是为了减少对行的判断；

——这就是说，[]包括前后两节的[]号在内，用来控制程序处理范围。   if /i "!b!"=="[sourcedisksfiles]" set d==表示如果触发[sourcedisksfiles]，变量d处于=状态，再触发[]号，就处于不等于状态。
——所以随风老师说：“所以 set h=a&set v=a 只是为了给这两个变量定义，值是什么不重要，重要的是这两个变量被定义了，也就是这两个变量存在”！

真是太奥妙了！！！=号也能当开关用……
复制代码

@echo off
SetLocal EnableDelayedExpansion

echo 请稍等...

rem =============== 设置 ===============
rem 设置文件名
set "INF_File=INTL.INF"

rem 设置要删除的行
set "Delete_Line=simsun.ttc,,,65536"

rem 设置哪一段下面要添加内容
set Section=[SourceDisksFiles]

    rem --------- 段下面要添加的内容 ---------
    rem 必须用双引号括起来
    for %%a in (
        "Sun86.IME    = 107,,,,,,,0,0"
        "Sun86.mb     = 107,,,,,,,0,0"
        "Sun86.chm    = 107,,,,,,,0,0"
    ) do set Append_Lines=!Append_Lines! %%a
    rem --------- /段下面要添加的内容 ---------

rem --------- 替换字符串 ---------
rem 必须用双引号括起来
for %%a in (
    "E00E0804=E0860804"
    "pintlgnt.ime=sun86.ime"
) do set Old-New=!Old-New! %%a
rem --------- /替换字符串 ---------

rem 删除含有某字符串的行
set "ContainStr=pintlgnt"
rem =============== /设置 ===============

type "%INF_File%" | findstr /nivc:"%Delete_Line%" >.findstr

rem 去除 INF_File 文件的“只读”属性
attrib -r "%INF_File%"

(for /f "tokens=*" %%a in (.findstr) do (
    set var=%%a
    for %%a in (%Old-New%) do set var=!var:%%~a!
    if "!var:%ContainStr%=!" equ "!var!" (
        if defined Monitor_Section_End (
            set var2=!var: =!
            set var2=!var:*:=!
            if "!var2:~0,1!!var2:~-1!"=="[]" (
                for %%a in (%Append_Lines% !Above_Lines! "!var:*:=!") do (
                    echo,%%~a
                )
                set Monitor_Section_End=
                set Above_Lines=
                set Append_Finish=#
            ) else if "!var2!"=="" (
                set Above_Lines=!Above_Lines! "!var:*:=!"
            ) else if "!var2:~0,1!"==";" (
                set Above_Lines=!Above_Lines! "!var:*:=!"
            ) else (
                for %%a in (!Above_Lines! "!var:*:=!") do echo,%%~a
                set Above_Lines=
            )
        ) else (
            if "!var:*:=!"=="%Section%" (
                if not defined Append_Finish set Monitor_Section_End=#
            )
            echo,!var:*:=!
        )
    )
)) >"%INF_File%"

del .findstr

rem 为了防止要添加内容的段为最后一段。
if defined Monitor_Section_End (
    for %%a in (%Append_Lines% %Above_Lines%) do echo,%%~a
) >>"%INF_File%"
复制代码