批处理之家 - Powered by Discuz! Board

标题: [文本处理] 退格符获取批处理函数 [打印本页]

作者: batman 时间: 2011-4-23 21:02 标题: 退格符获取批处理函数

示例代码如下：

@echo off&setlocal enabledelayedexpansion
::下面tg为退格符的变量名，可以自行修改
call :get_tg tg
for /l %%a in (1,1,6) do set "k=!k!%tg% %tg%"
set /p=bathome-123456<nul
ping /n 2 127.1>nul
set /p=%k%batman<nul
pause>nul&goto :eof

%------------------------退格符获取函数------------------------%
:get_tg
(echo A100&echo MOV DL,08&echo MOV AH,02&echo INT 21&echo INT 20&echo,&echo G&echo q)>db&set "%1="
for /f "skip=8" %%a in ('debug^<db') do if not defined %1 set "%1=%%a"
del /q db
%------------------------退格符获取函数------------------------%
复制代码

作者: batman 时间: 2011-4-23 21:12

这下大家在写特效时不要到处找别人的代码复制粘贴退格了，呵呵。。。

正在设法获取tab中（苦恼+头痛ing...）。。。

作者: cutebe 时间: 2011-4-23 22:53

@echo off
set JSF="%TMP%\TAB.JS"
echo=WScript.echo(String.fromCharCode(9));>%JSF%
for /f "delims=" %%t in ('cscript //nologo %JSF%')do set "t=%%t"
::变量t为TAB
pause
复制代码

作者: plp626 时间: 2011-4-24 00:46

1# batman

如果掉debug这个三方的话有些大材小用，我们一般都是到了最无奈的时候，比如必须要使用一个三方工具，但又嫌下载麻烦，直接嵌到bat中。

如果用它了，那完全可以做个ascii码获取通用函数了

作者: plp626 时间: 2011-4-24 01:01

1# batman

退格符的获取，可以用cmd的内置命令得到：

@echo off
call:getbs bs
echo abc%bs%#
pause
:getbs 
for /F %%a in ('"prompt $h&for %%b in (1) do rem"')do Set "%~1=%%a"
复制代码

作者: cjiabing 时间: 2011-4-24 01:37

看看就好，不必当真

作者: applba 时间: 2011-4-28 02:40

我只看到几句汇编了，我想不用看懂了

作者: techon 时间: 2011-5-9 14:17

可以用debug做个从文件读入十六进制，然后输出为二进制文件的批处理了

echo exit|cmd /k prompt ecs:100 01 02 11 12 21 22 31 32$_rcx$_8$_ntmp.bin$_w$_q$_|debug

作者: Batcher 时间: 2014-3-8 14:11

生成退格键

【方法1】

for /f %%i in ('"prompt $H & for %%j in (1) do rem"') do (
    set "KeyBackspace=%%i"
)
复制代码

【方法2】

for /f %%i in ('echo prompt $H ^| cmd') do (
    set "KeyBackspace=%%i"
)
复制代码

【方法3】
打开edit，按Ctrl+P，按完之后按下退格键，保存文本。

【方法4】
打开记事本，按住ALT不放，按小键盘上的127。

【方法5】
bat + mshta

@echo off
mshta vbscript:inputbox("",,chr(8))(close)
复制代码

【方法6】

@echo off&title 请关闭此窗口 Code By plp626&if not %1.==. goto%*
for /f "delims=" %%a in ('cmd /s/k "prompt $h&%~s0 :x"')do echo.%%a>tuige.txt
:x
复制代码

【方法7】

echo exit/b>a.bat&prompt $h&a.bat>>a.bat&notepad a.bat
复制代码

【方法8】

::@@ 运行后，@就变成了退格符了
@echo off
pushd "%~dp0"
(echo e 102 8 8&echo;w&echo;q)|debug %~nx0
notepad %~nx0
复制代码

生成ESC键
【方法1】

for /f %%i in ('"prompt $E & for %%j in (1) do rem"') do (
    set "KeyESC=%%i"
)
复制代码

【方法2】

for /f %%i in ('echo prompt $E ^| cmd') do (
    set "KeyESC=%%i"
)
复制代码

作者: 猪豆三 时间: 2014-5-25 08:16

了解学习一下

欢迎光临批处理之家 (http://bathome.net./)