批处理之家 - Powered by Discuz! Board

标题: [已解决]批处理中为何用goto语句跳不出for的无限循环 [打印本页]

作者: yjstone 时间: 2011-5-10 00:59 标题: [已解决]批处理中为何用goto语句跳不出for的无限循环

下面代码当if !n!==100的条件成立时会马上跳出for循环执行"echo count=%n%"语句，这是毫无疑问的。

@echo off&setlocal enabledelayedexpansion
for /l %%i in (1,1,1000) do (
set /a n+=1
if !n!==100 goto :end
)
:end 
echo count=%n%
pause
复制代码

而将for的步进改为0让for无限循环，则当if !n!==100的条件成立时却不能跳出for循环。

@echo off&setlocal enabledelayedexpansion
for /l %%i in (1,0,1000) do (
set /a n+=1
if !n!==100 goto :end
)
:end 
echo count=%n%
pause
复制代码

经测试当n到达100时脚本暂停了。这是为什么呢？

已解决，原因是当goto的条件成立时不会马上跳出for循环，要等for全部循环完才执行，这期间所有for循环体内的执行语句（do后面的语句）不会执行，只执行in后面括号内的加步进和判断是否到达for循环的终点语句。所以当%%i到达100时脚本好象暂停了，其实是这时批处理只执行(1,0,1000)的语句，因为是无限循环语句，所以永远跳不出循环。而call和exit命令则不受此限制。

作者: techon 时间: 2011-5-10 02:37

同样预见这个问题，看了一下在死循环的 for 里 goto 是不会跳出这个循环的，无论你怎样 goto，
完后这个死循环还在走着，不理你goto

作者: batman 时间: 2011-5-10 10:09

在严格意义上goto是跳不出for循环，如下面的代码end会要等到for循环结束后才会显示出来：

@echo off
for /l %%a in (1,1,1000000) do (
    if %%a equ 10 goto next
    echo bathome
)
:next
echo end
pause
复制代码

作者: slore 时间: 2011-5-10 12:43

echo on 一目了然

作者: hanyeguxing 时间: 2011-5-10 14:09

本帖最后由 hanyeguxing 于 2011-5-10 14:22 编辑

@echo off&setlocal enabledelayedexpansion
for /l %%i in (1,0,1000) do (
set /a n+=1
if !n!==100 goto :end
)
:end 
echo count=%n%
pause
复制代码

1，“经测试当n到达100时脚本暂停了。这是为什么呢？”
没有暂停，去掉 echo off 就可以看到循环依旧，不然怎么叫无限循环。
goto 必须等待 for /l 完成元素的全部迭代才执行跳转。
2，要暂停无限循环则将 goto 改成 call ，call 不作此等待。

作者: yjstone 时间: 2011-5-10 17:10

本帖最后由 yjstone 于 2011-5-10 20:17 编辑

多谢大家的解答，结论：当goto的条件成立时不会马上跳出for循环，要等for全部循环完才执行，而call和exit命令则不受此限制，马下跳出循环。这期间所有for循环体内的执行语句（do后面的语句）不会执行，只执行in后面括号内的加步进和判断是否到达for循环的终点语句。

作者: ▄︻┻═┳一 时间: 2011-5-10 18:01

多谢大家的解答，结论：当goto的条件成立时不会马上跳出for循环，要等for全部循环完才执行，这期间所有for循环体内的执行语句（do后面的语句）不会执行，只执行in后面括号内的加步进和判断是否到达for循环的终点语句 ...
yjstone 发表于 2011-5-10 17:10

有意思，，，

setlocal enabledelayedexpansion
for /l %%i in (1,1,1000) do (
set/a n+=1&if !n!==100 goto:end
if %%i==102 call:end %%i
)

:end
echo %1
pause
复制代码

作者: ▄︻┻═┳一 时间: 2011-5-10 18:02

setlocal enabledelayedexpansion
for /l %%i in (1,1,1000) do (
if %%i==102 call:end %%i
set/a n+=1&if !n!==100 goto:end
)

:end
echo %1
pause
复制代码

作者: ▄︻┻═┳一 时间: 2011-5-10 18:03

setlocal enabledelayedexpansion
for /l %%i in (1,1,1000) do (
if %%i==102 call:end %%i
set/a n+=1&if !n!==105 goto:end
)

:end
echo %1
pause
复制代码

作者: changedirectory 时间: 2013-12-14 21:29

@echo off&setlocal enabledelayedexpansion
for /l %%i in (1 1 1000) do (
     if %%i==100 call :end %%i
     set /a n+=1&if !n!==102 goto end
     if %%i==105 call :end %%i
)

:end
echo %1
pause
复制代码

又学习了新的知识点！

欢迎光临批处理之家 (http://bathome.net./)