批处理之家 - Powered by Discuz! Board

标题: [特效代码] 谁能帮我写个数青蛙的批处理？ [打印本页]

作者: jsbba 时间: 2011-5-17 17:58 标题: 谁能帮我写个数青蛙的批处理？

当输入回车后就输出一行格式是 1只青蛙1张嘴2只眼睛4条腿扑通1声跳下水在一会车就显示 2只青蛙2张嘴4只眼睛8条腿扑通扑通2声跳下水这样累加的
谢谢啊我用for怎么没搞出来啊
for /l %%i in (1,1,1000) do echo %%i只青蛙%%i张嘴%%i*2只眼睛%%i*4条腿扑通
后门的%%i*2根本就没计算而且那个扑通扑通做不出来啊麻烦高手指点

作者: namejm 时间: 2011-5-17 18:22

本帖最后由 namejm 于 2011-5-17 18:30 编辑

算术运算是需要用 set /a 来做的
写一个玩玩：
居然还要对声音进行重复
修改一下
不过貌似变量最大只能存储8192字节（具体数目忘记了，不是很确定）
所以
到了4000多只青蛙的时候就会game over了

@echo off
set num=0

:loop
cls
set /a num+=1
set /a num_eyes=%num%*2
set /a num_legs=%num%*4
set sound=%sound%扑通
echo %num%只青蛙%num%张嘴%num_eyes%只眼睛%num_legs%条腿%sound%%num%声跳下水
echo.
pause
goto loop
复制代码

作者: mxxcgzxxx 时间: 2011-5-17 18:22

本帖最后由 mxxcgzxxx 于 2011-5-17 18:27 编辑

@echo off&setlocal enabledelayedexpansion
for /l %%i in (1,1,1000) do (
           set /a a=2*%%i
           set /a b=4*%%i
           set "c=!c!扑通"
           echo %%i只青蛙%%i张嘴!a!只眼睛!b!条腿!c!%%i声跳下水
       pause>nul
          )
复制代码

作者: jsbba 时间: 2011-5-17 20:14

算术运算是需要用 set /a 来做的
写一个玩玩：
居然还要对声音进行重复
修改一下
不过貌似变量最大只能存储8192字节（具体数目忘记了，不是很确定）
所以
到了4000多只青蛙的时候就会game over了
@echo off
...
namejm 发表于 2011-5-17 18:22

谢谢版主的代码很有写的很他有条理啊我太笨了啊想不上来

作者: jsbba 时间: 2011-5-17 20:14

@echo off&setlocal enabledelayedexpansion
for /l %%i in (1,1,1000) do (
         set /a a=2*%%i
         set /a b=4*%%i
         set "c=!c!扑通"
         echo %%i只青蛙%%i张嘴!a!只眼睛! ...
mxxcgzxxx 发表于 2011-5-17 18:22

for 实现的短小精悍太给力了谢谢这位朋友

作者: Hello123World 时间: 2011-5-18 16:17

@echo off
setlocal EnableDelayedExpansion
for /l %%i in (1 1 100) do (
set c=%%i & set /a a=!c!*2
set /a b=!c!*4
echo %%i只青蛙%%i张嘴!a!只眼睛!b!条腿
for /l %%j in (1 1 %%i) do echo 扑通
echo %%i声跳下水
pause>nul
)
复制代码

作者: Hello123World 时间: 2011-5-18 16:21

namejm实现了最大化，版主还是版主。
最大的亮点是set sound=%sound%扑通

作者: applba 时间: 2011-5-18 17:06

为什么要一直扑通呢…………

作者: zz100001 时间: 2011-5-18 17:20

我来给你扑通扑通补上：

@echo off
set num=0

:loop
cls
set /a num+=1
set /a num_eyes=%num%*2
set /a num_legs=%num%*4
set/p/=%num%只青蛙%num%张嘴%num_eyes%只眼睛%num_legs%条腿<nul
for /l %%i in (1,1,%num%) do (set/p/=扑通<nul)
set/p/=%num%声跳下水<nul
echo.
pause
goto loop
复制代码

欢迎光临批处理之家 (http://bathome.net./)