@echo off&setlocal enabledelayedexpansion
set hh=^


::获取换行符
for %%a in (
        "@echo off" "pause&rem" "echo abc" "pause&rem"
) do set str=!str!!hh!%%~a
echo !str:~2!>3.txt
::只用换行符断行

cmd<3.txt
echo;
echo ________end________
pause
复制代码

@echo off
pause&rem
echo abc
pause&rem
复制代码

        请按任意键继续. . .
        'cho' 不是内部或外部命令，也不是可运行的程序
        或批处理文件。
        请按任意键继续. . .
复制代码

@echo off
(for /l %%a in (1 1 10) do set /p .%%a=)<%0
set.
pause
复制代码

(set /p .a=
set /p .b=)<只有一行的文件.txt
set.
复制代码

set /p .a=<只有一行的文件.txt
::取首行
set /p .b=<nul
::从空设备获取输入，等于无输入
set.
::显示以 . 开头的变量
复制代码

@echo off
set /p line=要获取的行所在行数：
(for /l %%a in (1 1 %line%) do set /p 内容=)<a.txt
set 内容
::获取指定行内容的新方法，由于无需遍历整个文本，要获取的行位置靠前的情况下有很大优势
复制代码

@echo off
(for /l %%a in (1 1 100) do set /p .%%a=)<%0

::不跳过空行赋值，但是 tmplinshi 版主的测试结果表明这比常规办法稍慢，它只在某些场合有优势，比如只获取前 N 行时，或者要兼容空行的情况，再或者需要兼容特殊字符的时候。
复制代码

@echo off&setlocal enabledelayedexpansion

set n=1
(for /l %%a in (1 1 5) do (
    if defined .!n! set /a n+=1
    set /p .!n!=
))<%0
::当然也同样可以跳过空行只将前 N 行赋值，但是这里的“前 N 行”计数时其实还是包括空行的，如果是要求取不把空行计算在内的前 N 行，我想最经济的方法就是先用 findstr . a.txt 输出非空行再分别赋值了
复制代码

@echo off
(for /l %%a in (1 1 7) do (
    pause
    set /p echo=
    echo !echo!
)<%0
::去除每行行首第一个任意字符的另一种方法，如果不计较效率的话，用 choice 可以只保留指定字符
复制代码

@echo off
(for /l %%a in (1 2 7) do (
    set /a a=1,b=2
    set /p a=
    set /p b=
    if !a!==!b! echo 相等
)<%0
::以两行为周期判断其内容是否相等，这比起老方法省下了许多麻烦，比如无需用 setlocal、endlocal 来兼容特殊字符
复制代码

@echo off
(for %%a in (
1-关回显 2-循环体 3-循环内容 4-do 4-设变量 5-输入 6-查看变量 7-注释
) do (
    set /p .%%a=
))<%0
set.
::可以通过无参数的for来循环，实现了以往无法实现的效果
复制代码

@echo off&setlocal enabledelayedexpansion
(for /f "tokens=1* delims=:" %%a in ('findstr /n .* 1.txt') do (
    set t2=
    set /p t2=
    echo;%%b!t2!
))<2.txt>合并.txt
::由于可以有两个不同的输入来源并存，所以双文本乃至多文本合并就成为轻而易举的事了
复制代码

@echo off&setlocal enabledelayedexpansion
for %%a in (a\*.txt b\*.txt) do set /a n+=1
dir /b /a-d /o-n b\*.txt>list.$
::计算文件总数为 %n%，生成要复制的文件列表为 list.$
(for /l %%a in (1 1 %n%) do (
	if not exist a\%%a.txt (
		set /p f=
		copy "b\!f!" "a\%%a.txt"
	)
))<list.$
::以往让人头疼的按递增文件名复制文件的问题，也可以这样解决
del /f list.$>nul
pause
复制代码

@echo off
set str=
(
    for /l %%a in (1 1 7) do (
        setlocal enabledelayedexpansion
        set /p str=
        if defined str (echo !str!) else echo ---------空行
        endlocal
    )
) <a.txt
pause
复制代码

find /c /v ""<1.txt
复制代码

@echo off
(
    for /l %%a in (1 1 11651) do (
        setlocal enabledelayedexpansion
        set /p str=
        echo,!str: =_!
        endlocal
    )
) <test.txt >test_1.txt
复制代码

@echo off
(
    for /f "delims=" %%a in (test.txt) do (
        set str=%%a
        setlocal enabledelayedexpansion
        echo,!str: =_!
        endlocal
    )
) >test_2.txt
复制代码

@echo off
setlocal enabledelayedexpansion
(
    for /l %%a in (1 1 7) do (
        pause >nul
        set /p echo=
        echo !echo!
    )
) <%0
pause
复制代码

@echo off
setlocal enabledelayedexpansion
::从每行第三个字符截取
(
    for /l %%a in (1 1 10) do (
        for /l %%1 in (1 1 3) do pause >nul
        set /p echo=
        echo %%a !echo!
        )
) <%0
pause
复制代码

@echo off
setlocal enabledelayedexpansion

(
    for /l %%a in (1 1 10) do (
        pause>nul
        set /p echo%%a=
        echo %%a !echo%%a!
        )
) <%0
pause
复制代码

@echo off
echo %time%
(
    for /f "delims=" %%a in (test.txt) do (
        set str=%%a
        setlocal enabledelayedexpansion
        echo,!str: =_!
        endlocal
    )
) >test_2.txt
echo %time%
pause
复制代码

 0:55:30.77
 0:55:32.83
请按任意键继续. . .
复制代码

@echo off
echo %time%
(
    for /l %%a in (1 1 2235) do (
        setlocal enabledelayedexpansion
        set /p str=
        echo,!str: =_!
        endlocal
    )
) <test.txt >test_1.txt
echo %time%
pause
复制代码

 0:55:34.07
 0:55:36.37
请按任意键继续. . .
复制代码

!@#~#$%^&*()_+-={}|":?><;'\`"~!@#$%^&*()_+|":?><
复制代码

@echo off
setlocal enabledelayedexpansion
(
    for /l %%a in (1 1 1) do (
        set/p echo=
        echo.!echo!
        )
) <1.txt >2.txt

for /f "delims=" %%1 in (1.txt) do (
       set "str=%%1"
       echo !str!
       )>>2.txt
复制代码

!@#~#$%^&*()_+-={}|":?><;'\`"~!@#$%^&*()_+|":?><
?><;'\`"~?><
复制代码

@echo off
setlocal enabledelayedexpansion
(
       set/p a=
       set/p b=
       set/p c=
       echo.!a!
       echo.!b!
       echo.!c!
       )<1.txt >2.txt
复制代码

@echo off
(
     for /l %%1 in (1 1 10 ) do (
       setlocal enabledelayedexpansion
       set/p 偶数行=
       set/p 奇数行=
       echo.!偶数行!>>2.txt
       echo.!奇数行!>>3.txt
       endlocal
       )
)<1.txt 
复制代码

@echo off
for /f "delims=" %%1 in (1.txt) do (
       endlocal
       rem 此时关闭变量延迟以免 %%1 中含有 ! 致错
       set "str=%%1"
       setlocal enabledelayedexpansion
       rem 此时打开变量延迟以即时读取变量
       echo !str!
)>>2.txt
复制代码

(@echo off

for /l %%a in (1 1 12) do (
    set .1=
    set .2=
    set /p .1=
    set /p=
    set /p .3=
    echo;!.1!
    echo;!.2!
))<%0
pause
复制代码

@echo off


(for /l %%a in (1 1 10) do (
pause>nul
pause>nul
rem 用两个pause测试，看究竟是否吞了两组 0D 0A，如果 pause 是吞整个 0D 0A，那结果应该不会出现空行或者带换行符的变量
set /p .%%a=))<%0
set.
pause
复制代码

@echo off



(for /l %%a in (1 1 10) do (
pause>nul
rem 用两个pause测试，看究竟是否吞了两组 0D 0A，如果 pause 是吞整个 0D 0A，那结果应该不会出现空行或者带换行符的变量
set /p .%%a=))<%0
set.>1.txt
pause
复制代码

@echo off
set x0a=^



::空行请自行添加
for /f %%a in ('copy /z %~s0 nul') do set x0d=%%a
cmd /v:on /c echo abc!x0a!!x0d!123!x0a!!x0d!>1.txt
(for /l %%a in (1 1 10) do set /p .%%a=)<1.txt
set.
pause>nul
复制代码

@echo off&setlocal enabledelayedexpansion
set a=^


(for /f %%a in ('copy /z %0 nul') do set b=%%a
set<nul /p=赋值成功!a!!b!赋值失败)>1.txt
set /p e=<1.txt
echo !e!
pause
echo d|debug 1.txt
::如果未出现赋值失败的字眼则代表 0A 0D 成功地结束了 set /p 的输入，结果证明确实如此
复制代码

 
:
@echo off
::获取0A换行符
(pause>nul&set /p a=)<%0
echo 你好%a%我在哪?
pause>nul
复制代码

 
:
@echo off
setlocal enabledelayedexpansion
::获取0A换行符
(set/p=&pause>nul&set /p a=)<%0
echo 你好！!a!我在哪啊？!a!你也不知道吗？!a!真是可惜……
pause>nul
set "b=123!a!456!a!789"
echo !b!
pause>nul
复制代码

 
:
@echo off
setlocal enabledelayedexpansion
::获取0A换行符
(pause>nul&set /p a=)<%0
::通过赋值用退格符将换行符后的空格修整得到完整实用的换行符
set "b=!a!"
echo !b!123456!b!789
pause>nul
复制代码

(pause>nul&set /p a=)<%0
复制代码

set "b=!a!"
复制代码

@echo off
(set/p a1=

   (set /p b1=
   set /p b2=
   )<bb.txt

set/p a2=)<aa.txt


set a
set b

pause
复制代码

@echo off&color a&setlocal enabledelayedexpansion
::用法 call :insert "要修改的本文文档路径" "在哪一行下面插入文字" "所要插入的文字"
call :insert "C:\Users\Administrator\Desktop\新建 Text Document.txt" "5" "我好喜欢你啊，哈哈哈"
endlocal
echo 操作完成,按任意键退出&pause>nul
exit

:insert
FOR /F %%l in ('find /c /v ""^< %1') do (
	for /l %%a in (1 1 %%l) do (
		set /p str=
		set /a 当前行=当前行+1
		if !当前行! GTR %~2 (
			echo.!str!
			) else (
			if !当前行! EQU %~2 (echo.!str!&echo.%~3) else (echo.!str!)
		)
		set str=
	)
)< %1 >> "%~d1%~p1%~n1_已处理%~x1"
goto :eof
复制代码

dir | set /p v=0
复制代码

dir | set /p VAR=^& set VAR
::此处已经捕获变量
pause

set VAR
::此处变量消失
pause
复制代码

cmd /c dir | cmd /c "set /p VAR=& set VAR"
复制代码