Board logo

标题: 笨狼代码大管家.hta [打印本页]
作者: fastslz    时间: 2011-9-7 12:46     标题: 笨狼代码大管家.hta

另存为“笨狼代码大管家.hta”
用于查看、整理、修改、阅读各类脚本代码工具
  1. <HTML>

  2. <HEAD>

  3. <TITLE>笨狼代码大管家</TITLE>

  4. <meta http-equiv="Content-Type" content="text/html; charset=gb2312">

  5. <style>

  6. body 

  7. {

  8. 	font-size:12;

  9. 	BACKGROUND: #DADADA;

  10. 	margin-left:5;

  11. 	overflow:visible;

  12. }

  13.  

  14. .folder

  15. {

  16. 	

  17. 	font-size:18;

  18. 	cursor:hand;

  19. }

  20. .folderIcon

  21. {

  22. 	color:navy;

  23. 	font-family:wingdings;

  24. 	font-size:18;

  25. 	cursor:hand;

  26. }

  27. .file 

  28. {

  29. 	color:navy;	

  30. 	font-size:18;

  31. 	cursor:hand;

  32. 	height:21;

  33. }

  34. .fileIcon

  35. {

  36. 	color:navy;

  37. 	font-family:wingdings;

  38. 	font-size:18;

  39. 	cursor:hand;

  40. 	height:21;

  41. 	display:inline;

  42. }

  43. input

  44. {

  45. 	width:20;

  46. 	overflow:visible;

  47. 	border:1px solid lightblue;

  48. 	background-color:#cccccc;

  49. 	cursor:text;	

  50. }

  51. button

  52. {

  53. 	border:1px solid  gray;	

  54. 	width:60;	

  55. 	margin-left:2;

  56. 	cursor:hand;

  57. 	font-size:12;

  58. 	filter:progid:DXImageTransform.Microsoft.Gradient(startColorStr='#eaeaff', endColorStr='#618fff', gradientType='0'); 

  59. }

  60. textarea

  61. {

  62. 	font-family:Verdana;

  63. 	font-size:12px;

  64. 	overflow-x:visible;

  65. 	overflow-y:scroll;

  66.                 margin-left:40;             

  67. }

  68. 

  69. #frmTree

  70. { 

  71. 	WIDTH:200px;

  72. 	height:630;

  73. 	MARGIN: 0px;

  74. 	PADDING: 0px;	

  75. 	overflow:scroll;

  76. 	overflow-x:scroll;

  77. 	MARGIN-right:10;

  78. }

  79. 	

  80. #frmSeach

  81. { 

  82. 	WIDTH:200px;

  83. 	height:630;

  84. 	MARGIN: 0px;

  85. 	PADDING: 0px;	

  86. 	overflow:scroll;

  87. 	MARGIN-right:10;	

  88. }

  89. 

  90. #hide_control

  91. { 

  92. 	POSITION: absolute;

  93. 	LEFT:213px;

  94. 	TOP:43px;

  95. 	WIDTH:10px;

  96. 	height:630;	

  97. 	BACKGROUND: #DADADA;

  98. 	padding-top:300;

  99. 	cursor:e-resize;

  100. 	border:1 solid gray;

  101. 	z-index:100;

  102. }

  103. #frmTop

  104. {

  105. 	width:100%;

  106. 	height:20;

  107. }		

  108. #txtFrm

  109. { 

  110. 	POSITION: absolute;

  111. 	LEFT:230px;

  112. 	TOP:50px;

  113. 	WIDTH:100%;

  114. 	MARGIN-left: -20px;

  115. 	PADDING: 0px;

  116. 	BACKGROUND: #DADADA;

  117.  } 

  118. #txtRead

  119. {

  120. 	display:none;

  121. 	position:absolute;

  122. 	color:red;

  123. 	font-size:18 px;

  124. 	top:0;

  125. 	left:0;

  126. 	background-color:black;

  127. 	z-index:1000;

  128. }

  129.  

  130.  #tab1

  131.  {

  132. 	border:1 solid  ;

  133. 	cursor:hand;

  134.  }

  135.   #tab2

  136.  {

  137. 	border:1 solid  ;

  138. 	cursor:hand;

  139. 	BACKGROUND: gray;

  140. 	margin-right:200;

  141.  }

  142. 

  143. </style>

  144.  

  145.  

  146. </HEAD>

  147. <BODY onselectstart="vbs:selectControl" onkeydown="vbs:shortCut">

  148. 

  149. <div id="frmTop">

  150. 	<span id="tab1" onclick="vbs:showMe me"> &nbsp;目 录 </span>

  151. 	<span id="tab2" onclick="vbs:showMe me" > &nbsp;搜 索 </span>

  152. 		标题：<input id="articleTitle" style="width:100" readonly/>

  153. 	<button id="browse" onclick="vbs:browseMe" >预览</button>			

  154. 	<button id="saveButton" onclick="vbs:saveFile" >保存</button>

  155. 	<button id="browse" onclick="vbs:createFile" >新建</button>	

  156. 	<button id="format" onclick="vbs:formatXML">格式化XML</button>	

  157. 	<button id="test" onclick="vbs:read">阅读模式</button>	

  158. 	<button id="test" onclick="vbs:showHelp">说明</button>	

  159. 	行&nbsp;<span id="Ln">1</span><hr/>

  160. </div>

  161. <div  id="frmTree" onclick="vbs:f_Click" onkeydown="vbs:deletFile" >

  162. 

  163. 	<div id="tree" style='margin-left:0;color:navy;font-size:12;cursor:hand;' ></div>

  164. </div>

  165.  

  166. <div  id="frmSeach" onclick="vbs:f_Click" >

  167. 

  168. 	<hr/>

  169. 	<div id="list" style='margin-left:0' onkeydown="deletFile">

  170. 	<input id="searchKey" style="width:100" onkeypress="vbs:searchPress"/>	

  171. 	<button onclick="vbs:seachFile" id="searchButton">查找</button><br/>

  172. 		<div id="seachList" style='margin-left:0' >搜索结果</div>

  173. 	</div>

  174. </div>

  175. 

  176. <input type="button"  id="hide_control" onmousedown="vbs:beginDrag" onmouseup="vbs:upHandler"  bgcolor="#eeeeee"/>

  177. <div valign="top" id="txtFrm">

  178. 

  179. 	<textarea id="txt"   onkeydown='vbs:TabTxt' onclick="vbs:showLn"  ></textarea>	

  180. </div>

  181. <div valign="top" id="txtRead" >

  182. 

  183. 	

  184. 	<button  onclick='vbs:closeRead' >关闭</button>

  185. 	<br/>

  186. 	 <iframe id='ifrm' frameborder=0 width="101%"  height="1000" SCROLLING="no" ></iframe> 

  187. </div>

  188. 

  189.  

  190.  

  191. <SCRIPT LANGUAGE="vbscript">

  192. 

  193. 

  194. '**************************

  195. '*****超级大笨狼***********

  196. '**************************

  197. 	on error resume next

  198. 	window.resizeTo window.screen.availWidth,window.screen.availHeight

  199. 	window.moveTo 0,0

  200. 	frmTree.style.height = cint(window.screen.availHeight )-70

  201. 	hide_control.style.height = cint(window.screen.availHeight * 0.98)+5

  202. 	txt.style.height = cint(window.screen.availHeight )-70

  203. 	txt.style.width = cint(window.screen.availWidth - 250) 

  204. 	'txt.style.width = window.screen.availWidth - px2Int(txtFrm.style.left) -20

  205. 	

  206. 	Set fso = CreateObject("Scripting.FileSystemObject")

  207. 	dim thisFileDir'定义本文件绝对路径

  208. 	dim thisFileName'定义本文件名

  209. 	dim thisFileFolder'定义本文件夹路径		

  210. 

  211. 	

  212. 	thisFileDir = replace(window.location.href,"file:///","")

  213. 	thisFileDir = unescape(replace(thisFileDir,"/","\"))	 

  214. 	thisFileName = LastOne(thisFileDir,"\")	

  215. 	thisFileFolder=getFolderDir(thisFileDir)

  216. 	tree.title = thisFileFolder

  217. 	

  218. 	dim currentDir'当前路径

  219. 	dim currentFile'当前文件

  220. 	dim currentDiv'当前DIV对象	

  221. 	dim currentSpan'当前Span对象	

  222. 	dim delatX

  223. 	dim dragAble:dragAble = false	

  224. 	dim Dtitle

  225. 	

  226. 	Dtitle=document.title

  227. 

  228. 	currentDir = thisFileFolder		

  229. 	set currentDiv = tree

  230. 	tree.innerText =  getTxtName(thisFileName)	

  231. 	

  232. 	showMe tab1

  233. 	showFolder tree 

  234. 	

  235. sub read

  236. 	txtRead.style.display="block" 

  237. 	txtRead.style.border="1px solid red"	 

  238. 	 

  239. 	   

  240. 	 HTML="<marquee id= SCROLLAMOUNT='4' SCROLLDELAY='1'  direction='up' height=' " & window.screen.availHeight-80  & "'>" 

  241.  	 HTML=  HTML & "<xmp style='word-wrap:break-word;line-height:60px ;' >" &  txt.value & "</xmp></marquee>"  

  242. 	ifrm.document.body.innerHTML= HTML 

  243. 	ifrm.document.body.style.backgroundColor = "#000000"

  244. 	ifrm.document.body.style.fontSize="40"	 

  245. 	ifrm.document.body.style.color="red"

  246. 	ifrm.document.body.style.textDecoration="underline"

  247. 	set marquee=ifrm.document.body.getElementsByTagName("marquee")(0)

  248. 	marquee.onmousemove=getRef("setMarquee")

  249. end sub

  250.  

  251.  

  252.  

  253. 

  254. sub setMarquee

  255. 	set m=ifrm.document.body.getElementsByTagName("marquee")(0)

  256. 	pos=  ifrm.window.event.clientY 

  257. 	total=  ifrm.window.screen.availHeight 		 

  258. 	if not isnumeric(pos) then exit sub

  259. 	if pos >total*2/5  and pos< total*3/5 then 

  260. 		m.stop  

  261. 		 

  262. 	else 

  263. 		m.start		 

  264. 	end if

  265. 	if  pos< total*2/5 then 	

  266. 		m.direction="down"   

  267. 	else 

  268. 		m.direction="up" 	 

  269. 	end if

  270. 

  271. 	if  pos >total/5  and pos< total*4/5 then

  272. 		m.scrollAmount=1

  273. 	else

  274. 		m.scrollAmount=int(abs((pos-total/2)/20-8))

  275. 	end if

  276. 	 

  277. end sub

  278. 

  279. sub closeRead

  280. 	 txtRead.style.display="none" 

  281. 	 

  282. end sub

  283. 

  284. sub showLn

  285. 	Ln.innerText = cint((window.event.offsetY-2)/15)+1	

  286. 	

  287. end sub

  288. 

  289. sub txt_onscroll

  290. 	frmTop.scrollIntoView

  291. end sub	

  292. 

  293. sub formatXML()	 

  294. 	set doc = createobject("MSXML2.DOMDocument") 

  295. 	if doc.loadXML(txt.value) then

  296. 		Dim rdr, wrt

  297. 		set wrt = createobject("MSXML2.MXXMLWriter")

  298. 		set rdr = createobject("MSXML2.SAXXMLReader") 		

  299. 		wrt.indent = True

  300. 		Set rdr.contentHandler = wrt		

  301. 		rdr.parse(txt.value)

  302. 		txt.value = wrt.output

  303. 	else

  304. 		alert("XML格式不正确，请确保Well-Formed！")

  305. 	end if	 

  306. end sub

  307. 

  308. 

  309. 

  310. sub shortCut

  311.    

  312. 	if window.event.keyCode=83 and window.event.ctrlKey  then

  313. 		if currentFile<>"" then saveFile

  314. 		window.event.cancelBubble = true

  315. 		window.event.returnValue = false		

  316. 	end if

  317. 	if window.event.keyCode=66 and window.event.ctrlKey  then

  318. 		browseMe

  319. 		window.event.cancelBubble = true

  320. 		window.event.returnValue = false

  321. 	end if

  322. 	 

  323. 	if window.event.keyCode=78 and window.event.ctrlKey  then

  324. 		createFile

  325. 		window.event.cancelBubble = true

  326. 		window.event.returnValue = false

  327. 	end if

  328. 	

  329. end sub	 

  330. sub browseMe	

  331. 	dim win 

  332. 	set win=window.open(currentFile)

  333. 	'win.document.write txt.value 

  334. end sub

  335.  

  336. sub createFile

  337. 	'点创建按钮，真的创建了．

  338. 	if vartype(currentSpan)<>0 then currentSpan.style.color = "navy"		

  339. 	if currentDir ="" then 

  340. 		'如果点到了文件

  341. 		currentDir=getFolderDir(currentFile)

  342. 	else

  343. 		'点到了文件夹

  344. 		dim n				

  345. 		set n=currentDiv.nextSibling	

  346. 		do 			

  347. 			if vartype(n) =9 then  exit do	

  348. 			if left(n.title,len(currentDir)) <> currentDir then exit do

  349. 			set  currentDiv	=n 			

  350. 			set n=n.nextSibling						

  351. 		loop

  352. 	end if

  353. 	dim re,newFile,s,f

  354. 	

  355. 	set re = new RegExp	

  356. 	re.Pattern = "[^\d]"

  357. 	re.Global=true

  358. 	newFile = currentDir & "新收藏" & re.Replace(mid(cstr(now()),3),"") & ".txt"	

  359. 	currentFile=newFile'新建文件是当前文件	

  360. 	'构造innerHTML

  361. 	s =  "<div class='file' title='" & newFile		  

  362. 	s = s & "'	style='margin-left:" 

  363. 	if currentDiv.className = "file" then

  364. 		s = s  &  currentDiv.style.marginLeft & ";' >&nbsp;"

  365. 	else

  366. 		s = s  &  px2Int(currentDiv.style.marginLeft) + 8 & ";' >&nbsp;"

  367. 	end if

  368. 	s = s  &  "<span class='fileIcon'>2" & "</span>"

  369. 	s = s  &  "<input value='"	

  370. 	s = s &  getTxtName(lastOne(newFile,"\")) & "' title='" & getTxtName(lastOne(newFile,"\")) & "' onchange='vbs:reName me' />"				 

  371. 	s = s & "</div>"

  372. 	'插入innerHTML

  373. 	currentDiv.insertAdjacentHTML "AfterEnd",s 

  374. 	

  375. 	articleTitle.value = getTxtName(lastOne(newFile,"\"))

  376. 	txt.value = ""

  377. 	currentDir = ""

  378. 	set currentDiv = currentDiv.nextSibling

  379. 	set currentSpan = currentDiv.getElementsByTagName("SPAN")(0)

  380. 	currentSpan.style.color = "red"	

  381. 	'创建文件

  382. 	set f=fso.CreateTextFile(newFile)

  383. 	f.close

  384. end sub

  385. 	

  386. function getFolderDir(fullDir)

  387. '输入得到全路径，得到文件夹路径

  388. 	s=LastOne(fullDir,"\")

  389. 	getFolderDir = left(fullDir,len(fullDir)-len(s))

  390. end function

  391. 

  392. sub saveFile

  393. '保存对文件的修改	 

  394.    Dim  f, st 

  395.    set f= fso.GetFile(currentFile)  

  396.    If f.attributes and 1 Then

  397. 		if	window.confirm("该文件属性为只读,是否改变其属性并保存修改？") then f.attributes = f.attributes - 1

  398. 	end if

  399.    Set st = fso.OpenTextFile(currentFile, 2, True)   

  400.    

  401.    st.Write txt.value 

  402.    st.close 

  403. end sub

  404. 

  405. 

  406. 

  407. 

  408. sub deletFile

  409. '删除文件

  410. dim  n	 

  411. 	if window.event.keyCode =46 and window.event.srcElement.tagName<>"INPUT"  then	

  412. 	

  413. 		if currentFile<>""  then 

  414. 			if currentFile = thisFileDir   then

  415. 				alert "不允许删除本文件！" 

  416. 				exit sub

  417. 			end if

  418. 			if fso.FileExists(currentFile)  then 

  419. 				fso.deletefile currentFile,true

  420. 				currentDiv.parentElement.removeChild currentDiv	

  421. 				txt.value = ""

  422. 				currentFile = ""

  423. 				articleTitle.value = ""

  424. 			end if		

  425. 		end if

  426. 		

  427. 		if currentDir<>""   then 

  428. 			if currentDir = thisFileFolder   then

  429. 				alert "不允许删除根目录！" 

  430. 				exit sub

  431. 			end if					

  432. 			set n = currentDiv.nextSibling

  433. 					if window.confirm( currentDir & vbcrlf & "这个文件夹有子文件，你要删除全部子文件吗?") then

  434. 						do 

  435. 							if vartype(n) =9 then  exit do  

  436. 							if px2Int(n.style.marginLeft) <= px2Int(currentDiv.style.marginLeft)   then exit do 							

  437. 								n.parentElement.removeChild n								

  438. 							set n=currentDiv.nextSibling				

  439. 						loop					

  440. 											

  441. 						if  fso.FolderExists(currentDir)  then fso.DeleteFolder left(currentDir,len(currentDir)-1)

  442. 						currentDiv.parentElement.removeChild currentDiv														

  443. 					end if

  444. 		end if

  445. 		

  446. 	end if	

  447. end sub

  448. 

  449. 

  450. 

  451. sub showMe(obj)

  452. 	if obj.id ="tab1" then

  453. 		tab2.style.backgroundColor="gray"

  454. 		tab1.style.backgroundColor="#DADADA"

  455. 		frmSeach.style.display="none"  

  456. 		frmTree.style.display=""

  457. 	else

  458. 		tab1.style.backgroundColor="gray"

  459. 		tab2.style.backgroundColor="#DADADA"

  460. 		frmSeach.style.display=""

  461. 		frmTree.style.display="none"  

  462. 	end if

  463. 

  464. end sub

  465. 

  466. sub beginDrag

  467. '开始拖拽	

  468. 	delatX=window.event.clientX - px2Int(hide_control.currentStyle.left)	

  469. 	document.attachEvent "onmousemove",getRef("moveHandler")	

  470. 	dragAble = true	

  471. 	window.event.cancelBubble = true	

  472. end sub

  473. 

  474. sub moveHandler

  475. '移动绑定事件

  476. 	if not dragAble then exit sub	

  477. 	dim x

  478. 	x = window.event.clientX - delatX

  479. 	hide_control.style.left= x & "px"

  480. 	txtFrm.style.left=( x + 20) & "px"	

  481. 	txt.style.width = window.screen.availWidth - px2Int(txtFrm.style.left) -20

  482. 	window.event.cancelBubble=true

  483. end sub

  484. 

  485. sub upHandler

  486. '放开绑定事件	

  487. 	document.detachEvent "onmousemove",getRef("moveHandler") 

  488. 	dim x

  489. 	x = window.event.clientX - delatX

  490. 	

  491. 	if px2Int(hide_control.style.left)>205 then

  492. 	 frmTree.style.width = abs( px2Int(hide_control.style.left)-10) & "px"	

  493. 	 frmSeach.style.width = abs( px2Int(hide_control.style.left)-10) & "px"

  494. 	 else

  495. 	 frmTree.style.width = "200px"	

  496. 	 frmSeach.style.width = "200px"

  497. 	end if

  498. 

  499. 	

  500. 

  501. 	dragAble = false		

  502. 	window.event.cancelBubble=true	

  503. end sub 

  504. 

  505. function getTxtName(fullName)

  506. '去掉文件名后缀

  507. 	dim s:s=lastOne(fullName,".")	 

  508. 	getTxtName = left(fullName ,len(fullName)-len(s)-1)

  509. end function

  510.  

  511. 

  512. sub reName(obj)

  513. 	'改名

  514. 	dim Arr,a

  515. 	Arr=array("/","\",":","*","?",chr(34),"|","<",">")

  516. 	for each a in Arr

  517. 		if instr(obj.value,a) >0 then

  518. 			alert "命名不能含有/\:*?" & chr(34) &  "|<>其中的一个"

  519. 			obj.focus

  520. 			exit sub

  521. 		 end if

  522. 	next	

  523. 	dim oldName,newName,oldPath,oldType

  524. 	oldName = obj.parentElement.title

  525. 	oldPath = getFolderDir(oldName)

  526. 	oldType = lastOne(oldName,".")

  527. 	newName = oldPath & obj.value & "." & oldType	

  528. 	Set f = fso.GetFile(oldName)

  529. 	f.copy newName

  530.                 currentFile = newName

  531. 	f.delete True 

  532. 	obj.parentElement.title = newName

  533. 	articleTitle.value = getTxtName(lastOne(newName,"\"))

  534. end sub

  535. 

  536. Function LastOne(Str,splitStr)

  537. '输入字符和分隔符，得到最后一部分

  538. 	LastOne = right(Str,len(Str)-InStrRev(Str,splitStr))

  539. End Function

  540. 

  541. sub  selectControl

  542. '控制页面选择的状态

  543. 	if window.event.srcElement.tagName<>"INPUT" and window.event.srcElement.tagName<>"TEXTAREA"  then

  544. 		document.selection.clear

  545. 	end if

  546. end sub

  547.  

  548. function isTXT(fileNameStr)

  549. '判断是否是文本类型的文件	

  550. 	dim s,Arr,a,returnValue

  551. 	returnValue = false

  552. 	s=lcase(LastOne(fileNameStr,"."))

  553. 	Arr=array("txt","sql","htm","html","asp","csv","aspx","xml","js","vbs","ini","bat","css","htc","hta","xsl","xslt","lrc","vb","cs","cx","asa","aspx","asax","config","shtml","stm","cpp","c","cxx","h","hpp","rc","pl","pm","cgi","php3","php","java","jsp","tpl","wsh","sgf","xsd","udl","asmx","inc","cmd")

  554. 	for each a in Arr

  555. 		if a=s then 

  556. 			returnValue =true

  557. 			exit for

  558. 		end if

  559. 	next

  560. 	isTXT = returnValue

  561. end function

  562. 

  563. sub showFolder(obj)

  564. 	    dim  folderspec :folderspec = obj.title 

  565. 	    obj.setAttribute "parsed",true	   

  566. 		if not fso.FolderExists(folderspec) then

  567. 			alert folderspec & "该文件夹不存在，也许是被移动了，所以刷新一下本程序"

  568. 			window.location.reload 

  569. 		exit sub

  570. 		end if

  571. 		dim f, f1, sf,sf1,i,s,fName

  572. 		set f=fso.GetFolder(folderspec)        

  573. 		set sf=f.Subfolders

  574. 		re = re &   f.name & "\"   

  575. 		s=""           

  576. 		for each sf1 in sf

  577. 			s =  s & "<div class='folder' title='" & sf1.path & "\' style='margin-left:" & cint(replace(obj.style.marginLeft,"px","")) + 8 & ";'>"

  578. 			s =  s & "<span class='folderIcon'>0" & "</span><input value='" & sf1.name & "' readonly style='cursor:hand;'/></div>" 				        

  579. 		next 

  580. 		

  581. 		For Each f1 in f.Files 

  582. 			if isTXT(f1.name)  then				  

  583. 				s =  s & "<div class='file' title='" &  f1.path			  

  584. 				s = s & "'	style='margin-left:" 

  585. 				s = s  &  px2Int(obj.style.marginLeft) + 8 & ";' >&nbsp;"

  586. 				s = s  &  "<span class='fileIcon'>2" & "</span>"

  587. 				s = s  &  "<input value='"

  588. 				fName = getTxtName(f1.name)

  589. 				s = s & fName & "' title='" & fName & "' onchange='vbs:reName me' />"				 

  590. 				s = s & "</div>" 

  591. 			end if

  592. 		Next	

  593. 		 obj.insertAdjacentHTML "AfterEnd",s 		 

  594. end sub

  595. 

  596. 

  597. 

  598. function px2Int(px)

  599. 	px2Int = cint(replace(px,"px",""))

  600. end function 

  601. 

  602.  

  603. 

  604. sub f_Click()

  605. 	dim obj,d,f,state

  606. 	set obj = window.event.srcElement

  607. 	if obj.id="searchKey" then exit sub

  608. 	if  obj.tagName<>"SPAN" and obj.tagName<>"INPUT"  then exit sub

  609. 	set currentDiv = obj.parentElement	

  610. 	set obj = currentDiv.getElementsByTagName("SPAN")(0)

  611. 	 window.event.cancelBubble = true

  612. 	select case obj.className 

  613. 		case  "folderIcon"  

  614. 			'点到了文件夹	

  615. 			if vartype(currentSpan)=8 then

  616. 				 currentSpan.style.color = "navy"

  617. 			end if

  618. 			set currentSpan = obj		

  619. 			state = abs(cint(obj.innerHTML)  -1)

  620. 			obj.innerHTML = state

  621. 			obj.style.color="red"

  622. 			set d = obj.parentElement			

  623. 			currentDir = d.title

  624. 			currentFile = ""

  625. 			if d.getAttribute("parsed")=true then

  626. 				'合拢

  627. 					 

  628. 				fold d,state			 

  629. 			else

  630. 				'解析	

  631. 				showFolder d 	 

  632. 			end if

  633. 			

  634. 			

  635. 		case  "fileIcon"  

  636. 			'点到了文件,在textArea里面载入文本文件

  637. 			

  638. 			if vartype(currentSpan)=8 then

  639. 				 currentSpan.style.color = "navy"

  640. 			end if

  641. 			set currentSpan = obj

  642. 			obj.style.color="red"

  643. 			readText obj.parentElement.title

  644. 			currentDir = ""

  645. 			currentFile = obj.parentElement.title

  646. 			

  647. 	end select	

  648. end sub	

  649. 

  650. sub fold(o,stateOpen)	'合拢	

  651. 	dim n

  652. 	set n=o.nextSibling	

  653. 	do 

  654. 		if vartype(n) =9 then  exit do 		

  655. 		if px2Int(n.style.marginLeft) <= px2Int(o.style.marginLeft)   then exit do   	

  656. 		if stateOpen=1 then n.style.display="" else  n.style.display="none"	

  657. 		set n=n.nextSibling			

  658. 	loop	

  659. end sub

  660. 

  661. 

  662. sub readText(filePath)  

  663. 	Dim f,fName 

  664. 	

  665. 	if not fso.FileExists(filePath) then

  666. 		alert filePath & vbcrlf & "该文件不存在，也许是被移动了，所以刷新一下本程序"

  667. 		window.location.reload 

  668. 		exit sub

  669. 	end if

  670. 		

  671. 	'TXT已经加载的当前文件不再加载.

  672. 	

  673. 	if filePath = currentFile then exit sub

  674. 	txt.value = ""

  675. 	Set f = fso.OpenTextFile(filePath, 1, true)

  676. 		if not f.AtEndOfStream  then 

  677. 			txt.value = f.readAll

  678. 		 else

  679. 			txt.value = ""

  680. 		 end if		

  681. 		fName = lastOne(filePath,"\")		

  682. 		articleTitle.value =  getTxtName(fName)			

  683. 	f.Close

  684. 	Ln.innerText = 1

  685. End sub

  686. 

  687. sub TabTxt()

  688. 	'支持tab键的文本框 

  689. 	if  window.event.keyCode=38  then 

  690. 		if cint(Ln.innerText) >1 then Ln.innerText =  cint(Ln.innerText)-1

  691. 	end if

  692. 	if window.event.keyCode=40 then 

  693. 		Ln.innerText =  cint(Ln.innerText)+1	 

  694. 			

  695. 	end if

  696. 	

  697. 	if window.event.keyCode<> 9 then exit sub	

  698. 	dim sel,mytext	

  699. 	set sel = document.selection.createRange()

  700. 	 'txt.createTextRange

  701. 	mytext = sel.text

  702. 	if len(mytext)=0   then

  703. 		sel.text =string(4," ")

  704. 		window.event.cancelBubble = true 

  705. 		window.event.returnValue = false		

  706. 		exit sub

  707. 	end if

  708. 	

  709. 	dim  t,Arr

  710. 	t=0

  711. 	Arr = split(mytext,vbcrlf)	

  712. 	if window.event.shiftKey then 

  713. 	'按sift			

  714. 		for i=0 to ubound(Arr)

  715. 			if left(Arr(i),1)=vbtab then 

  716. 				Arr(i) = mid(Arr(i),2)

  717. 				t= t + 1

  718. 			else

  719. 				for j=1 to 4

  720. 					if left(Arr(i),1)=" " then 

  721. 						Arr(i) = mid(Arr(i),2)

  722. 						t= t + 1

  723. 					else

  724. 						exit for

  725. 					end if			

  726. 				next

  727. 			end if 

  728. 		next

  729. 		t= t 

  730. 	else

  731. 	'不按sift	

  732. 		for i=0 to ubound(Arr)

  733. 			Arr(i) = vbtab & Arr(i)

  734. 			t= t +1

  735. 		next				

  736. 	end if

  737. 		mytext = join(Arr,vbcrlf)

  738. 		sel.text = mytext 

  739. 		sel.collapse true 

  740. 		sel.moveEnd "character",0 	

  741. 		sel.moveStart "character",(len(mytext) * -1) + t		

  742. 		sel.select()

  743. 	window.event.cancelBubble = true 

  744. 	window.event.returnValue = false

  745. end sub

  746.  

  747. '下面是关于搜索

  748. dim  seachResult'查找结果

  749. dim num '结果数量

  750. dim word'搜索关键字

  751.  

  752. tagStop = false 

  753. seachResult =""	

  754. 

  755. '按回车后响应

  756. sub searchPress

  757. 	if window.event.keyCode=13  then

  758. 		seachFile

  759. 	end if

  760. end sub

  761. 

  762. '显示搜索结果

  763. sub seachFile()	

  764. 		num =0	

  765. 		seachList.innerText = "搜索结果"		 

  766. 		word = searchKey.value		

  767. 		 seachResult =""		 

  768. 		 if trim(word)="" then

  769. 			alert "关键字为空！"

  770. 			searchKey.focus

  771. 			exit sub

  772. 		else

  773. 			dim l

  774. 			for each l in list.getElementsByTagName("DIV") 

  775. 				if l.id<>"seachList" then list.removeChild l		 

  776. 			next

  777. 			seachList.innerText = "搜索结果"			

  778. 			seachWord thisFileFolder

  779. 			seachList.insertAdjacentHTML "AfterEnd",seachResult

  780. 			seachList.innerText = "搜索结果：" & num & "个"

  781. 			alert "搜索完毕！"	

  782. 		 end if 

  783. end sub

  784. 

  785. sub seachWord(theFolder)	

  786. 	dim f,f1,st,re,fd,fd1

  787. 	set f = fso.GetFolder(theFolder)

  788. 	for each f1 in f.Files

  789. 		if isTxt(f1.path)  then

  790. 			if instr(f1.path,word)>0 then

  791. 				seachResult = seachResult & "<div class='file' title='" &  f1.path 

  792. 				seachResult = seachResult & "'><span class='fileIcon'>2" & "</span>"

  793. 				seachResult = seachResult &  "<input value='"

  794. 				fName = getTxtName(f1.name)

  795. 				seachResult = seachResult & fName & "' title='" & fName & "'>"				 

  796. 				seachResult = seachResult & "</div>"

  797. 				num = num + 1

  798. 			else

  799. 				set st = f1.OpenAsTextStream

  800. 				'逐行读		

  801. 				Do While st.AtEndOfStream <> True

  802. 					if instr(st.ReadLine,word)>0 then 

  803. 						num = num +1						

  804. 						seachResult = seachResult & "<div class='file' title='" &  f1.path 

  805. 						seachResult = seachResult & "'><span class='fileIcon'>2" & "</span>"

  806. 						seachResult = seachResult &  "<input value='"

  807. 						fName = getTxtName(f1.name)

  808. 						seachResult = seachResult & fName & "' title='" & fName & "'>"				 

  809. 						seachResult = seachResult & "</div>"

  810. 						exit do				

  811. 					end if

  812. 				 Loop

  813. 				st.Close

  814. 			end if	

  815. 		end if

  816. 	next

  817. 	set fd = fso.GetFolder(theFolder)

  818. 		for each  fd1 in fd.SubFolders

  819. 			seachWord fd1

  820. 		next

  821. end sub

  822. 

  823. 

  824. sub showHelp

  825. 	dim msg,f,re,version

  826. 	set f=fso.GetFile(thisFileDir)

  827. 	version = f.DateLastModified 

  828. 	set re = new RegExp	

  829. 	re.Pattern = "[^\d]"

  830. 	re.Global=true

  831. 	version =  re.Replace(mid(cstr(version),3),"/") 

  832.                 version =   left(version ,len(version)-3)

  833. 	set re = nothing	

  834. 	msg =		"  文本代码管理工具【IE5.5以上版本】" & vbcrlf

  835. 	msg = msg & "------------------------------------------------" & vbcrlf

  836. 	msg = msg & "  使用方法：放到文本类型的文件夹里面，双击运行。" & vbcrlf

  837. 	msg = msg & "功能：" & vbcrlf

  838. 	msg = msg & "1，快速浏览,预览CTRL+B，搜索文本类型的文件和代码；" & vbcrlf

  839. 	msg = msg & "2，按DEL可以删除点中的文件和文件夹；" & vbcrlf

  840. 	msg = msg & "3，可以修改文件名和文字内容,CTRL+S保存；" & vbcrlf

  841. 	msg = msg & "4，可以创建文件CTRL+N并且编辑保存；" & vbcrlf

  842. 	msg = msg & "5，文本编辑支持TAB和shift+TAB键；" & vbcrlf

  843. 	msg = msg & "6，格式化Well-Formed的XML文件；"	& vbcrlf

  844. 	msg = msg &    vbcrlf

  845. 	msg = msg & "作者：CSDN超级大笨狼[" & version & "版本]请随时到网站检查最新版本" & vbcrlf	

  846. 	msg = msg & "欢迎传播使用,交流代码panyuguang962@hotmail.com" & vbcrlf

  847. 	msg = msg & "http://superdullwolf.cnzone.net/index.asp" & vbcrlf

  848. 	alert msg

  849. end sub

  850. </SCRIPT>

  851.  

  852. </BODY>

  853. </HTML>
复制代码
作者: BillGates    时间: 2011-9-7 13:03

干嘛用的？
作者: wc726842270    时间: 2011-9-7 13:21

真不知要过多少年少有这水平，唉、
原来是在这儿啊
  1. HTML="<marquee id= SCROLLAMOUNT='4' SCROLLDELAY='1'  direction='up' height=' " & window.screen.availHeight-80  & "'>" 

  2. 

  3.          HTML=  HTML & "<xmp style='word-wrap:break-word;line-height:60px ;' >" &  txt.value & "</xmp></marquee>"  
复制代码




欢迎光临 批处理之家 (http://bathome.net./) Powered by Discuz! 7.2