批处理之家 - Powered by Discuz! Board

标题: [文本处理] 批处理搜索指定盘符jpg图片文件并更改名图片名称为文件夹的名称？ [打印本页]

作者: qq3475534 时间: 2011-10-4 23:31 标题: 批处理搜索指定盘符jpg图片文件并更改名图片名称为文件夹的名称？

本帖最后由 pcl_test 于 2017-3-19 06:12 编辑

比如
e:\爱情片\鬼来了\xbs.pg

我想批处理先搜索指定分文件的xbs.jpg图片然后
在当前目录下将图片改成文件夹的名称

比如 e:\爱情片\鬼来了\xbs.pg
那么图片名称就改成"鬼来了.jpg" 这样··

不知道是否可以做到。。

作者: qq3475534 时间: 2011-10-4 23:32

电影服务器。。之前是XBS 影视平台，现在换了另外个平台，所以这个图片必须要和文件夹的名称一样才可以。

作者: FOR 时间: 2011-10-5 00:05

@echo off
set /p pan=请输入盘符或文件夹绝对路径：
if "%pan:~-1%"=="\" set "pan=%pan:~0,-1%"
cd/d %pan%
for /f "delims=" %%i in ('dir/b/s "%pan%\*.jpg"') do (
	for /f "delims=" %%j in ("%%~dpi.") do (
	    ren "%%i" "%%~nxj%%~xi"
	)
)
pause
复制代码

作者: guaiwu 时间: 2011-10-5 00:25

本帖最后由 guaiwu 于 2011-10-5 00:27 编辑

@echo off
set /p str=拖动文件到此(或输入文件的完整路径):
for %%a in (%str%) do (
for /f "tokens=3,4 delims=\" %%i in (%str%) do (
cd %%~pda
rename "%%j" %%i.jpg
))
pause
复制代码

将该文件放置在文件处理的当前磁盘里、

作者: Batcher 时间: 2011-10-5 10:08

回复 4# guaiwu

人家就是不知道图片路径才需要先搜索的，你让人家拖放什么？或者输入什么？

作者: Hello123World 时间: 2011-10-5 12:06

本帖最后由 Hello123World 于 2011-10-5 12:10 编辑

@echo off&SetLocal EnableDelayedExpansion
::最后一个路径中不能有空格，例如e:\爱情片\鬼来了\xbs.jpg，不能是e:\爱情片\鬼 来了\xbs.jpg
For /f %%i in ('dir /s /b e:\爱情片\*.jpg') do (
	Set nname=%%~dpi
	Set nname=!nname:\= !
	For %%j in (!nname!) do Set ename=%%j
	ren "%%i" "!ename!%%~xi"
	)
pause
复制代码

欢迎光临批处理之家 (http://bathome.net./)