@echo off&setlocal enabledelayedexpansion
(for /f "delims=" %%a in (a.txt) do (
   set /a a+=1,b=0
   echo %%a
   rem 输出 a.txt 内容
   for /f "delims=" %%b in (b.txt) do (
      set /a b+=1
      if !a!==!b! echo %%b
      rem 逐行对比行号，当相等时输出 b.txt 内容
   )
))>合并ab文本.txt
::循环次数为 a.txt*b.txt 的行数
复制代码

@echo off&setlocal enabledelayedexpansion
for %%a in (a b) do (
   for /f "delims=" %%b in (%%a) do set /a "%%a+=10001"&echo !%%a:~-4!%%a:%%b
)>>tmp.txt
::将ab两文件补位，使对行的前缀均为 [行号][文件名]，这样排序时行号相同的内容将被输出为上下行
sort tmp.txt /o tmp.txt
::排序tmp.txt，并输出到原文件
(for /f "tokesn=1* delims=:" %%a in (tmp.txt) do echo %%b)>合并ab文本.txt
::循环次数为 (a.txt+b.txt)*2 的行数
复制代码

::解约瑟夫环问题，详细介绍请自行百度。
@echo off&setlocal enabledelayedexpansion&set "str= "
echo %time%
for /l %%a in (1,1,29) do set "str=!str!%%a "
   for /l %%a in () do (
   for %%a in (!str!) do (
      set /a "n=(n+1)%%3"
      if !n!==0 set "str=!str: %%a = !"
   )
   for /f "tokens=1,2" %%a in ("!str!") do if "%%b"=="" echo 最后剩下的是%%a号&echo !time!&pause>nul&exit
)
::修改自 batman 的代码，使用 for 嵌套逐个去除复合条件的项，运算量为 !29（就是 1*2*3*4 一直到 29）
复制代码

@echo off
set /a n=29,k=1,m=3,s=0
for /l %%a in (2,1,%n%) do set /a s=(s+m)%%%%a
set /a x=(s+k)%%n
if %x% equ 0 (set x=%n%)
echo 最后剩下是:%x%
pause
::修改自 inittab 的公式法方案，运算量为 29
复制代码

(for %%a in (*.txt) do findstr /v ". $" "%%a"&&echo 文件 %%a 为空)>空文件列表.txt
::逐个判断文件是否为空，为空则输出文件名。
复制代码

(for /f "delims=" %%a in ('findstr /mv ". $" *.txt') do echo 文件 %%a 为空)>空文件列表.txt
::一次性输出空文件名，再将结果修正为所需的格式
复制代码

for %%a in (*.bat) do ren "%%a" "%%~na.txt"
::用 for 逐个重命名 bat 文件为txt，这是典型的加法思路
复制代码

ren *.bat *.txt
::一次性重命名所有bat文件为txt，这是减法思路中一次成型的特例
复制代码