set a=1
set b=2
set c=3
::用三个 set 分别将 a b c 赋值为 1 2 3
复制代码

set /a a=1,b=2,c=3
::用一个 set /a 来一次性赋三个值
复制代码

if %1==a (
   if %2==b (
      echo a b
   ) else echo 参数有误
) else echo 参数有误
::用 if 嵌套判断两个参数是否都为指定值
复制代码

if %1^&%2==a^&b (
   echo a b
) else echo 参数有误
::将两个 if 合并为一个
复制代码

@echo off&setlocal enabledelayedexpansion
call :test time
pause&exit
:time
echo !%1!
::传递参数 %1 为 time，再显示以 %1 的内容为名的变量值
复制代码

%1@cmd /q/v/c %0 : time
echo !%2!
pause
::用一个 cmd 实现关闭回显、打开变量延迟、替代 call 来修改来传递参数
复制代码

@echo off&setlocal enabledelayedexpansion
set/p s=请输入，用一个空格分开:
echo %time%
set f1=a.txt
set f2=b.txt
>!f1! echo !s:~,1!&set s=!s:~1!
set len=1
for %%a in (%s%) do (
    (for /f %%b in (!f1!) do (
        set tmp=%%b
        for /l %%c in (0,1,!len!) do echo !tmp:~,%%c!%%a!tmp:~%%c!
    ))>!f2!
    set t=!f1!
    set f1=!f2!
    set f2=!t!
    set/a len+=1
)
echo %time%
start %f1%&del/f %f2%
pause
::代码修改自 wankoilz 的代码，这是多个方案中最高效的变量偏移方案
复制代码

@echo off
call:perm "a b c xy z"
pause

:perm <"c1 c2 ..."> // code by plp
setlocal enabledelayedexpansion&set "s=%~1 "
if "!s: =!" == ""  (echo %~2)else for %%b in (%~1)do call:perm "!s:%%b =!" "%~2 %%b"
endlocal&goto:eof
::修改自 plp626 的超短方案，用 call 传递参数引用函数的特性进行迭代，实现输出所有排列组合，十分精彩
复制代码

for /l %%a in (1 1 9) do (
   for /l %%b in (0 1 9) do (
      for /l %%b in (0 1 9) do echo %%a-%%b-%%c
   )
)
::输出 100 到 999 之间的数，两位之间以 - 间隔
复制代码

set "函数=for /l %%a in (0 1 9) do "
%函数:0=1% %函数:a=b% %函数:a=c% echo %%a-%%b-%%c
::将 for 语句设为变量，需要时取用，并可依据实际需求通过变量替进行微调
复制代码

@echo off
for /r c:\ %%a in (*.txt) do echo %%a
for /r d:\ %%a in (*.txt) do echo %%a
for /r e:\ %%a in (*.txt) do echo %%a
for /r f:\ %%a in (*.txt) do echo %%a
pause
::遍历 c: d: e: f:，获取所有非隐藏属性 txt 文本名称。
复制代码

@echo off
for %%a in (c d e f) do call :dir %%a
pause&exit
:dir
for /r %1:\ %%a in (*.txt) do echo %%a
::通过模块化实现反复调用代码的目的
复制代码