:: date2i // 求1900-3-1到y-m-d所经历的天数i; y-m-d 范围：[1900-3-1, 2100-3-1) 
set/a "m=(m+9)%%12,y-=m/10+1900,i=365*y+y/4+(m*153+2)/5+d-1"
复制代码

:: i2date // 求1900-3-1日后第i天的日期; i 的范围：[0, 73049)
set/a "y=(4*i+3)/1461,t=i-y*365-y/4,m=(t*5+2)/153+2,d=t-(m*153-304)/5+1,y+=m/12+1900,m=m%%12+1"
复制代码

:date2i <year> <month> <day> <RetVarName>
setlocal&set/a y=%1,m=%2,d=%3
set/a m=(m+9)%%12,y-=m/10,i=365*y+y/4-y/100+y/400+(m*153+2)/5+d-1
endlocal&set %4=%i%&goto:eof
复制代码

:i2date <index> <Ret1> <Ret2> <Ret3>
setlocal&set/a i=%1, y=(4*i+999)/1461
set/a "y+=i-y*365-y/4+y/100-y/400>>9,t=i-y*365-y/4+y/100-y/400"
set/a "m=(t*5+2)/153,d=t-(m*153+2)/5+1,y+=(m+2)/12,m=(m+2)%%12+1"
endlocal&set/a %2=%y%,%3=%m%,%4=%d%&goto:eof
复制代码

::  获取指定日期的星期数；返回值为0表示星期日，返回值为1表示星期1，。。。类推
:date2week <year> <month> <day> <RetVarName> 
call:i2date %*&set/a %4=(%4+3)%%7&goto:eof
复制代码

@echo off
:: # 获取指定日期之前或之后的日期 nextdate
:: 日期格式(仅支持月数，日数前面 有1位0的格式)：
::           2012-1-01，2012-01-11，2012-1-1，1941-10-01，...
:: 适用范围： 不好描述，完全够日常生活使用；
:: 要计算100年后或100年前的，请选择数值计算版date2i；i2date进行定制；
rem  函数调用格式演示：
call:nextdate mydate="2012-1-1" -7
echo %mydate%
call:nextdate mydate="2012-01-1" -7
echo %mydate%
call:nextdate mydate="2012-1-01" -7
echo %mydate%
call:nextdate mydate="2012-01-01" -7
echo %mydate%
pause&goto:eof

:nextdate <RetVarName> <"DATE"> <[+|-]int> // 获得 给定日期第n天 的日期
setlocal&set tp=%~2
for /f "tokens=1-3delims=-" %%a in ("%tp:-0=-%")do (
  set/a "y=%%a,m=%%b,d=%%c+%3,m=(m+9)%%12,y-=m/10+1900"
  set/a "i=365*y+y/4+(m*153+2)/5+d-1,y=(4*i+3)/1461,t=i-y*365-y/4"
  set/a "m=(t*5+2)/153+2,d=t-(m*153-304)/5+1,y+=m/12+1900,m=m%%12+1"
)
endlocal&set %1=%y%-%m%-%d%&goto:eof
复制代码

:: 求两个日期相隔的天数
:edate <RetVarName> <"DATE1"> <"DATE2">  
setlocal&set d1=%~2&set d2=%~3
:: 参考代码
set d1=%d1:-= %&set d2=%d2:-= %
call :date2i %d1: 0= % r1
call :date2i %d2: 0= % r2
set/a c=r2-r1
endlocal&set ans.%~1=%c%&set ans.%~1&goto:eof
复制代码

:: 方便讨论这6个整数分别用如下字母表示[y,m,d,h,f,s]
y取值范围[-10000,10000]；
（暂时不考虑y为负值的情形，只考虑公元1年1月1日之后的情形；视难度而定）
m取值范围[1,12] 
d取值范围[1,31] 
h取值范围[0,23]
f取值范围[0,59]
s取值范围[0,59]
:: 比如 2012-04-03，1:02:09秒这个时间对应的值为 y=2012,m=4,d=3,h=1,f=2,s=9
复制代码

:fun1
set/a y=2012,m=4,d=3,h1=1,f1=2,s1=9
set/a                h2=1,f2=3,s2=9
rem ---- 你的代码1 -----
echo %out%
rem 输出值out=60
复制代码

:fun2
set/a y1=2012,m1=4,d1=3,h=1,f=2,s=9
set/a y2=2012,m2=5,d2=3
rem ---- 你的代码1 -----
echo %out%
rem 输出值out=31
复制代码

:fun3
set/a y1=2012,m1=4,d1=3,h1=1,f1=2,s1=9
set/a y2=2012,m2=4,d2=5,h2=1,f2=2,s2=10
rem ---- 你的代码1 -----
echo %out%
rem 输出值out=2 1
复制代码

:fun4
set/a y=2012,m=4,d=3,h=1,f=2,s=9
set/a x=-4
rem ---- 你的代码 -----
echo %out%
rem 输出值out=2012 3 30 1 2 9
复制代码

:fun5
set/a y=2012,m=4,d=3,h=1,f=2,s=9
set/a x=-61
rem ---- 你的代码 -----
echo %out%
rem 输出值out=2012 4 3 1 1 8
复制代码

:fun6 给定一个日期，求其星期数
set/a y=2012,m=4,d=3
rem ---- 你的代码 -----
echo %out%
rem 输出值out=2
复制代码

:d2ymd <day> <ret:y> <ret:m> <ret:d>
@echo off
:d2ymd
setlocal enabledelayedexpansion
set/a d=%1
set/a "d+=719050,d-=d/1461-d/36524+d/146097,y=d/365+1,r=^!(y%%4)-^!(y%%100)+^!(y%%400),d+=(d%%=365)/(212+r)*30+r,d+=^!^!(d/(59+r))*(2-r),m=d/61*2+d%%61/31,d-=m*61/2+m*61%%2-1,m+=1-m/8"
endlocal&if %4. neq . (set %2=%y%&set %3=%m%&set %4=%d%)else echo %y% %m% %d%
复制代码

->d2ymd 841
1971 12 31
->d2ymd 842
1972 1 2
->d2ymd 1223
1973 1 16
->d2ymd 1222
1973 1 16
还有很多bug。。。
复制代码

set/a y=2012,m=4,d=3,h1=1,f1=2,s1=9
set/a                h2=1,f2=3,s2=9
rem -------------------
set out=(h2-h1)*3600+(f2-f1)*60+s2-s1
rem -------------------
echo %out%
rem 输出值out=60
复制代码

set/a days=d-719446+30*m+m/9*-~m/2+!(m/9)*m/2+!!(m/3)*(!(y%%4)-!(y%%100)+!(y%%400)-2)+y*365+~-y/4-~-y/100+~-y/400
rem 日期转天数

set/a d+=719050,d-=d/1461-d/36524+d/146097,y=d/365+1,r=!(y%%4)-!(y%%100)+!(y%%400),d+=(d%%=365)/(212+r)*30+r,d+=!!(d/(59+r))*(2-r),m=d/61*2+d%%61/31,d-=m*61/2+m*61%%2-1,m+=1-m/8
rem 天数转日期

set /a m+=!(m/=3)*12,week=(d+2*m+3*(m+1)/5+(y-=m/13)+y/4-y/100+y/400+1)%%7
rem 日期转星期
复制代码

@echo off
set/a y1=2012,m1=4,d1=3,h1=1,f1=2,s1=9
set/a y2=y1,m2=m1,d2=d1,h2=1,f2=3,s2=9
set/a out=(d2-d1+30*(m2-m1)+m2/9*-~m2/2+!(m2/9)*m2/2+!!(m2/3)*(!(y2%%4)-!(y2%%100)+!(y2%%400)-2)-m1/9*+~m1/2-!(m1/9)*m1/2-!!(m1/3)*(!(y1%%4)-!(y1%%100)+!(y1%%400)-2)+(y2-y1)*365+~-y2/4-~-y2/100+~-y2/400-~-y1/4+~-y1/100-~-y1/400)*86400+(h2-h1)*3600+(f2-f1)*60+s2-s1
echo %out%
rem 输出值out=60
pause
复制代码

年份之差*365+天数之差
按大小月、平闰年修正天数
所得天数乘一日总秒数
最后加上秒数差即可
复制代码

@echo off
set/a y1=2012,m1=4,d1=3,h1=1,f1=2,s1=9
set/a y2=y1,m2=5,d2=3,h2=1,f2=2,s2=9
set/a out=d2-d1+30*(m2-m1)+m2/9*-~m2/2+!(m2/9)*m2/2+!!(m2/3)*(!(y2%%4)-!(y2%%100)+!(y2%%400)-2)-m1/9*+~m1/2-!(m1/9)*m1/2-!!(m1/3)*(!(y1%%4)-!(y1%%100)+!(y1%%400)-2)+(y2-y1)*365+~-y2/4-~-y2/100+~-y2/400-~-y1/4+~-y1/100-~-y1/400+((h2-h1)*3600+(f2-f1)*60+s2-s1)/86400
echo %out%
rem 输出值out=31
pause
复制代码

@echo off
set/a y1=2012,m1=4,d1=3,h1=1,f1=2,s1=9
set/a y2=2012,m2=4,d2=5,h2=1,f2=2,s2=10
set/a days=d2-d1+30*(m2-m1)+m2/9*-~m2/2+!(m2/9)*m2/2+!!(m2/3)*(!(y2%%4)-!(y2%%100)+!(y2%%400)-2)-m1/9*+~m1/2-!(m1/9)*m1/2-!!(m1/3)*(!(y1%%4)-!(y1%%100)+!(y1%%400)-2)+(y2-y1)*365+~-y2/4-~-y2/100+~-y2/400-~-y1/4+~-y1/100-~-y1/400,secs=(h2-h1)*3600+(f2-f1)*60+s2-s1
set out=%days% %secs%
echo %out%
rem 输出值out=2 1
pause
复制代码

@echo off
set/a y=2012,m=4,d=3,h=1,f=2,s=9
set/a x=-4
set/a d=d-397+30*m+m/9*-~m/2+!(m/9)*m/2+!!(m/3)*(!(y%%4)-!(y%%100)+!(y%%400)-2)+y*365+~-y/4-~-y/100+~-y/400+x,d-=d/1461-d/36524+d/146097,y=d/365+1,r=!(y%%4)-!(y%%100)+!(y%%400),d+=(d%%=365)/(212+r)*30+r,d+=!!(d/(59+r))*(2-r),m=d/61*2+d%%61/31,d-=m*61/2+m*61%%2-1,m+=1-m/8
set out=%y% %m% %d% %h% %f% %s%
echo %out%
rem 输出值out=2012 4 3 1 1 8
pause
复制代码

取天数加上偏移量
计算闰年数量取得年数
取得月份数量
取得天数（好像都是废话...）
复制代码

set/a s=h*3600+f*60+s+x,d=d-397+30*m+m/9*-~m/2+!(m/9)*m/2+!!(m/3)*(!(y%%4)-!(y%%100)+!(y%%400)-2)+y*365+~-y/4-~-y/100+~-y/400+s/86400,d-=d/1461-d/36524+d/146097,y=d/365+1,r=!(y%%4)-!(y%%100)+!(y%%400),d+=(d%%=365)/(212+r)*30+r,d+=!!(d/(59+r))*(2-r),m=d/61*2+d%%61/31,d-=m*61/2+m*61%%2-1,m+=1-m/8,h=s/3600%%60,f=s/60%%60,s%%=60
复制代码

@echo off
set/a y=2012,m=4,d=3
set /a m+=!(m/=3)*12,out=(d+2*m+3*(m+1)/5+(y-=m/13)+y/4-y/100+y/400+1)%%7
echo %out%
rem 输出值out=2
pause
复制代码

@echo off&setlocal enabledelayedexpansion
for /l %%i in (1 1 31) do set "D%%i=0%%i"
set "Xq=一二三四五六日"
set "Ymda=1990 1 1"&set "Ymdb=2012 4 3"
for /f "tokens=1-6" %%i in ("%Ymda% %Ymdb%") do set /a "JDA=%%k-32075+1461*(%%i+4800+(%%j-14)/12)/4+367*(%%j-2-(%%j-14)/12*12)/12-3*((%%i+4900+(%%j-14)/12)/100)/4,JDB=%%n-32075+1461*(%%l+4800+(%%m-14)/12)/4+367*(%%m-2-(%%m-14)/12*12)/12-3*((%%l+4900+(%%m-14)/12)/100)/4,JD=JDB-JDA"
   echo %Ymda% 至 %Ymdb% 相隔  %JD% 天
   REM 查询N天前或后的日期;
   set/p N=请输入天数(往前查询加上-如:-10000 表示10000天前的日期。):
   set /a JD=N+JDA,W=JD%%7,JD+=68569,N=(4*JD)/146097,JD-=(146097*N+3)/4,I=(4000*JD+1)/1461001,JD-=(1461*I)/4-31,J=(80*JD)/2447,D=JD-(2447*J)/80,JD=J/11,M=J+2-(12*JD),Y=100*(N-49)+I+JD
   for /f "tokens=1-3" %%i in ("!M! !D! !W!") do echo;你查询的是：!Y!年!D%%i:~-2!月!D%%j:~-2!日	星期!Xq:~%%k,1!
pause
复制代码

@echo off&setlocal enabledelayedexpansion
set/a y1=2012,m1=4,d1=3,h1=1,f1=2,s1=9
set/a y2=y1,m2=m1,d2=d1,h2=1,f2=3,s2=9
set /a "out=(1461*(y2+(m2-14)/12)/4+367*(m2-2-(m2-14)/12*12)/12-3*((y2+(m2-14)/12)/100+1)/4-1461*(y1+(m1-14)/12)/4-367*(m1-2-(m1-14)/12*12)/12+3*((y1+(m1-14)/12)/100+1)/4-d1+d2)*86400+(h2-h1)*3600+(f2-f1)*60+s2-s1"
echo %out%
rem 输出值out=60
pause
复制代码

set /a "m+=9, m%%=12, y-=m/10, index=365*y + y/4 - y/100 + y/400 + (m*306 + 5)/10 + d - 1
复制代码

set /a n=m, n+=9, n%=12, t=y, t-=n/10
复制代码

set /a n=m, n+=9, n%=12
复制代码

for /l %a in (0 1 11) do >nul set /a "fn=%a*306+5" & set fn
for /l %a in (0 1 11) do >nul set /a "fn=%a*306+5, ifn=fn/10" & set ifn
for /l %a in (0 1 10) do >nul set /a "delta=((%a+1)*306+5)/10-(%a*306+5)/10" & set delta
复制代码

static double cdm[] = {0,31,59,90,120,151,181,212,243,273,304,334};
        if (mon < 1) {
            mon = 1;
        }
        if (mon > 12) {
            y += (mon-1)/12;
            mon = ((mon-1) % 12) + 1;
        }
        *t = 365.*y + ceil(y/4.) - ceil(y/100.) + ceil(y/400.) + cdm[mon-1] + *d;
        if (mon > 2) {
            iy = (int) y;
            if ((iy%4 == 0) && (iy%100 != 0) || (iy%400 == 0)) {
                *t += 1.;
            }
        }
复制代码

(153*M+2)/5
复制代码

set /a "y=(i-1)*250/91311+1, dd=i-(365*y + y/4 - y/100 + y/400)"
set /a "y+=dd>>31, dd=i-(365*y + y/4 - y/100 + y/400)"
复制代码

@echo off & setlocal enabledelayedexpansion
echo mon len ind    s     e     f(s)    f(e)  int(f(s))   int(f(e))
for %%i in ("Feb 28" "Feb 29") do (
  set /a "i=100, s=1000, e=1000-1"
  for %%a in ("Mar 31" "Apr 30" "May 31" "Jun 30" "Jul 31" "Aug 31"
  "Sep 30" "Oct 31" "Nov 30" "Dec 31" "Jan 31" %%i) do (
    set "l=%%~a"
    set /a "e+=!l:~-2!, fs=(5*(s-1000)+2)*1000/153+100000,fe=(5*(e-1000)+2)*1000/153+100000"
    set /a "ifs=(5*(s-1000)+2)/153+100,ife=(5*(e-1000)+2)/153+100"
    set "lin=!l!   !i:~-2!   !s:~-3!   !e:~-3!   !fs:~-5!   !fe:~-5!     !ifs:~-2!          !ife:~-2!"
    set "lin=!lin: 0=  !"
    if %%i=="Feb 28" (echo !lin!) else if %%a=="Feb 29" echo !lin!
    set /a "s+=!l:~-2!, i+=1"
))
复制代码

set /a "y=(i-1)*250/91311+1,dd=i-(365*y+y/4-y/100+y/400)"
set /a "y+=dd>>31,dd=i-(365*y+y/4-y/100+y/400)"
set /a "mi=(5*dd+2)/153"
set /a "m=(mi+2)%%12+1" & rem {0,1,2,..9,10,11} -> {3,4,5,..12,1,2}
set /a "y-=m-3>>31" & rem 1,2月到了下一年
set /a "d=1+dd-(153*mi+2)/5"
复制代码

@echo off & setlocal enabledelayedexpansion
REM 7305155=20000.12.31
for /l %%i in (0 1 7305155) do (
  set /a "i=%%i"
  set /a "y=(i-1)*250/91311+1,dd=i-(365*y+y/4-y/100+y/400)"
  set /a "y+=dd>>31,dd=i-(365*y+y/4-y/100+y/400)"
  set /a "mi=(5*dd+2)/153"
  set /a "m=(mi+2)%%12+1" & rem {0,1,2,..9,10,11} -> {3,4,5,..12,1,2}
  set /a "y-=m-3>>31" & rem 1,2月到了下一年
  set /a "d=1+dd-(153*mi+2)/5"
  set "test=%%i:   !y!.!m!.!d!"

  set /a "m+=9,m%%=12,y-=m/10,i=365*y+y/4-y/100+y/400+(m*306+5)/10+d-1"
  set "test=!test!     !i!"
  if "!i!" neq "%%i" set "test=!test!     error"
  echo !test!
  if "!test:error=!" neq "!test!" pause
)
复制代码

struct sdate dtf(long d) { /* convert day number to y,m,d format */
  struct sdate pd;
  long y, ddd, mm, dd, mi;

  y = (10000*d + 14780)/3652425;
  ddd = d - (y*365 + y/4 - y/100 + y/400);
  if (ddd < 0) {
    y--;
    ddd = d - (y*365 + y/4 - y/100 + y/400);
    }
  mi = (52 + 100*ddd)/3060;
  pd.y = y + (mi + 2)/12;
  pd.m = (mi + 2)%12 + 1;
  pd.d = ddd - (mi*306 + 5)/10 + 1;
  return pd;
  }
复制代码

->m 1/365.2425
0.00273790701

->m 250/91311
0.00273789576
　
->m 250/91310
0.00273792575
复制代码

var
  d1st, p, pMin, pMax: longint;
  pOffs, pOffsMin, pOffsMax: real;
begin
  pOffsMin := 0;
  pOffsMax := -1;
  for p := 1 to 20000 do
  begin
    d1st := 365 * p + p div 4 - p div 100 + p div 400;
    pOffs := (d1st * 10000.0) / 3652425 - p;
    if pOffs < pOffsMin then begin pOffsMin := pOffs; pMin := p; end
    else if pOffs > pOffsMax then begin pOffsMax := pOffs; pMax := p; end;
    WriteLn(p, '  ', d1st, '  ', pOffs: 0: 6);
  end;
  WriteLn('The pOffsMin is: ', pOffsMin: 0: 6, ';  the pOffsMax is: ', pOffsMax: 0: 6);
  WriteLn('The pMin is: ', pMin: 0, ';  the pMax is: ', pMax: 0);
  WriteLn('pOffsMin = ', pOffsMin: 0: 6, ',  pOffsMax + 365*10000 / 3652425 = ', pOffsMax + 365 * 10000 / 3652425: 0: 6);
  Readln;
end.
复制代码

>nul (set /a "mi=0,ma=0,ii=1,ia=1"&(for /l %y in (1 1 400) do set /a "y=%y,d=y*365+y/4-y/100+y/400,d*=10000,d=y*3652425-d,ii^=(d-mi>>31)&(y^ii),ia^=(ma-d>>31)&(y^ia),mi^=(d-mi>>31)&(d^mi),ma^=(ma-d>>31)&(d^ma)"))&set m&set i
复制代码

@echo off&setlocal enabledelayedexpansion
FOR /l %%i in (0 1 7305155) DO (
    set JD=%%i
    IF !JD! GEQ 2299161 set /a "JD+=1+(JD*100-186721625)/3652425-(JD*100-186721625)/3652425/4"
    set /a "B=JD+1524,Y=(B*100-12210)/36525,D=36525*Y/100"
    set /a "M=(B-D)*10000/306001,D=B-D-306001*M/10000,M=(M-2)%%12+1,Y-=4715+^!(2/M)"
    set "test=%%i:   !y!.!m!.!d!"
    set /a "M=(M+9)%%12+3,Y-=M/13,JD=36525*(Y+4716)/100+306001*(M+1)/10000+D-1524"
    set /a "JD+=(2-Y/100+Y/400)*^!(2299161/JD)"
    set "test=!test!     !JD!"
    if "!JD!" neq "%%i" set "test=!test!     error"
    echo !test!
    if "!test:error=!" neq "!test!" pause
)
PASUE
复制代码

set /a "y=(i*99+145)/36159,y+=i-365*y-y/4+y/100-y/400>>31,dd=i-365*y-y/4+y/100-y/400"
set /a "mi=(5*dd+2)/153,m=(mi+2)%%12+1,y-=m-3>>31,d=1+dd-(153*mi+2)/5"
复制代码

set /a "y=(i*99+145)/36159,y+=i-365*y-y/4+y/100-y/400>>31,d=i-365*y-y/4+y/100-y/400,m=(5*d+2)/153,d+=1-(153*m+2)/5,y+=m/10,m=(m+2)%%12+1"
复制代码

@echo off & setlocal enabledelayedexpansion
REM nextIndex := date2index(1.1.1);
for /l %%y in (1 1 20000) do (
  set "y=%%y"
  set /a "leap = (^!(%%y %% 4) & ^!^!(%%y %% 100)) | ^!(%%y %% 400)"
  if "!leap!"=="1" (set "eFeb=29") else set "eFeb=28"
  for %%t in ("1 31" "2 !eFeb!" "3 31" "4 30" "5 31" "6 30" "7 31" "8 31" "9 30" "10 31" "11 30" "12 31") do (
    for /f "tokens=1,2" %%m in ("%%~t") do (
      set "m=%%m"
      for /l %%d in (1 1 %%n) do (
        set "d=%%d"

        REM testing...
        REM if date2index(y.m.d) <> nextIndex (
          REM error
        REM )
        REM if index2date(date2index(y.m.d)) <> y.m.d (
          REM error
        REM )
        REM nextIndex += 1;
        echo !y!.!m!.!d!
      )
    )
    pause
  )
)
复制代码

@echo off
:date2i <year> <month> <day> // 显示year-month-day 所对应的索引值；
setlcoal&set/a y=%1,m=%2,d=%3
set/a	m+=9
set/a	m%%=12
set/a	y-=m/10
set/a	i=365*y+y/4-y/100+y/400+(m*153+2)/5+d-1
endlocal&echo %i%
复制代码

@echo off
:i2date <index> // 显示 %1 所对应的日期 %1 取值范围0~2千万
setlocal&set/a i=%1
set/a 	y=(i*99+145)/36159
set/a	t=i-y*365-y/4+y/100-y/400
set/a	"y+=t>>9"
set/a	t=i-y*365-y/4+y/100-y/400  
set/a	m=(t*5+2)/153				
set/a 	d=t-(m*153+2)/5
set/a	d=d+1	
set/a	y+=(m+2)/12				
set/a	m=(m+2)%%12+1				
endlocal&echo %y%-%m%-%d%
复制代码

//&cls&@type %~fs0|tcc -run -

// 把tcc.exe 和 lib\msvcrt.def 放在当前目录下；双击本脚本解释执行下面C代码
int i2date(int i, int *, int *, int *);
int date2i(int, int, int);

	/*
	 * 把0-3-1作为参考日历{0-0-0}的0号索引，后面依次类推;
	 * 参考日历月份数为 0,1,2,...,11; 
	 * 11月分闰月和平月；当所在年份+1为闰年时为闰月；
	 * 参考日历日期数为 0,1,...,30;
	 * 大月最大偏移30,小月最大偏移29; 
	 * 11月中，闰月最大偏移28；平月最大偏移27；
	 */
int main(){

int i,j;
int y,t,m,d;

for (i=0; i<1461*100000; i++){ // 0 ~ 40万年索引号
	i2date(i,&y,&m,&d);
	j=date2i(y,m,d);
	if (i!=j) { // 测试，寻找不对称转换的具体值。。
		printf("/%5d:%4d/%2d/%2d\n",i,y,m,d);
		getchar();
	}
}

return 0;
}

int i2date(int i, int *year, int *month, int *day){ // 索引转日期

	int t,y,m,d;
	
	y=(i*4+999)/1461;          // 1/365.2425的前6位小数最佳有理逼近
	// y=(i*99+145)/36159;
	// y=i*33/12053;            //1/365.2425的前9位小数最佳有理逼近

	t=i-y*365-y/4+y/100-y/400;
	y+=t>>9;		// 获得参考年份；若t为负数,将参考年减1
	t=i-y*365-y/4+y/100-y/400;  // 获得参考年0月0日的偏移数

	m=(t*5+2)/153;	// 获得参考月份
	d=t-(m*153+2)/5;	// 获得参考日期

	d=d+1;		// 获得实际日期	
	y+=(m+2)/12;	// 获得实际年份
	m=(m+2)%12+1;	// 获得实际月份

	*year=y;
	*month=m;
	*day=d;
	return 0;
}

int date2i(int y, int m, int d){// 日期转索引
	int i;

	m+=9;
	m%=12;
	y-=m/10;	 
//上面三句做平移取模，3月作为当年的0月；2月作为上1年的11月；

	i=365*y+y/4-y/100+y/400+(m*153+2)/5+d-1;
// 11月初的偏移为337；337/11≈153/5; 
// (m*153+2)/5 将 {0,1,2,...,11}映射为{0,31,61,...,337}

	return i;
}
复制代码

@echo off & setlocal enabledelayedexpansion
REM Index := date2index(1.1.1);
set /a "y=1,m=1,d=1"
set /a "m+=9, m%%=12,y-=m/10, i=365*y + y/4 - y/100 + y/400 + (m*306 + 5)/10 + d - 1"
set /a "Index=i"

for /l %%y in (1 1 20000) do (
  set "y=%%y"
  set /a "leap = (^!(%%y %% 4) & ^!^!(%%y %% 100)) | ^!(%%y %% 400)"
  if "!leap!"=="1" (set "eFeb=29") else set "eFeb=28"
  for %%t in ("1 31" "2 !eFeb!" "3 31" "4 30" "5 31" "6 30" "7 31" "8 31" "9 30" "10 31" "11 30" "12 31") do (
    for /f "tokens=1,2" %%m in ("%%~t") do (
      set "m=%%m"
      for /l %%d in (1 1 %%n) do (
        set "d=%%d"

        REM testing...
        REM if date2index(y.m.d) <> Index (
          REM error
        REM )
        REM if index2date(date2index(y.m.d)) <> y.m.d (
          REM error
        REM )
        REM Index += 1;

        set /a "m+=9, m%%=12,y-=m/10, i=365*y + y/4 - y/100 + y/400 + (m*306 + 5)/10 + d - 1"

        if "!i!" neq "!Index!" ((echo error at %%y.%%m.%%d date2index(y.m.d^)=!i!^<^> !Index!) & pause)

        set /a "y=(i*99+145)/36159,y+=i-365*y-y/4+y/100-y/400>>31,d=i-365*y-y/4+y/100-y/400,m=(5*d+2)/153,d+=1-(153*m+2)/5,y+=m/10,m=(m+2)%%12+1"

        set /a "error=(y-%%y)|(m-%%m)|(d-%%d)"
        if "!error!" neq "0" ((echo error at %%y.%%m.%%d index2date(date2index(y.m.d^)^)=!y!.!m!.!d!) & pause)

        echo %%y.%%m.%%d  Index=!Index!
        set /a "Index+=1"
      )
    )
  )
)
pause
exit
复制代码

>> datestr(36584,26)

ans =

0100/02/28

>> datestr(36585,26)

ans =

0100/03/01

>> 
复制代码

y=(i*99+145)/36159;
复制代码

@echo off&setlocal enabledelayedexpansion
(FOR /l %%i in (2298883 1 2299603) DO (
    set JD=%%i
    IF !JD! GEQ 2299161 set /a "JD+=1+(JD*100-186721625)/3652425-(JD*100-186721625)/3652425/4"
    set /a "B=JD+1524,Y=(B*100-12210)/36525,D=36525*Y/100"
    set /a "M=(B-D)*100/3061,D=B-D-3061*M/100,M=(M-2)%%12+1,Y-=4715+^!(2/M)"
    set "str=!Y!:!M!:!D!"
    set /a "M=(M+9)%%12+3,Y-=M/13,JD=36525*(Y+4716)/100+3061*(M+1)/100+D-1524"
    REM 1582年10月4日后重新计算闰年,先前每4年一闰.
    set /a "JD+=(2-Y/100+Y/400)*^!(2299161/JD)"
    ECHO !str! !JD!
))>Yjd.txt
start "" "Yjd.txt"
PAUSE
复制代码

@echo off&setlocal enabledelayedexpansion
for %%i in (31 28 31 30 31 30 31 31 30 31 30 31) do set /a N+=1&set "M_!N!=%%i"
set JDX=2298883
for /l %%i in (1582 1 1583) do (
     IF %%i gtr 1582 (
        set /a "N=^!(%%i%%4)^^^!(1582/%%i)&^!(%%i%%400)^^^!(1582/%%i)&^!(%%i%%100)"
     ) else set /a "N=^!(%%i%%4)"
     set /a M_2=28+N
     for /l %%j in (1 1 12) do (
         set /a "M=(%%j+9)%%12+3,Y=%%i-M/13"
         for /l %%k in (1 1 !M_%%j!) do (
             set /a "JD=36525*(Y+4716)/100+3061*(M+1)/100+%%k-1524,JDX+=1"
             set /a "JD+=(2-Y/100+Y/400)*^!(2299161/JD)"  2>nul
             IF !JDX! NEQ !JD! set ERR=!err!$err:%%i:%%j:%%k !JD! !JDX!$
             REM 1582年10月4日后初始日须减10天
             if "%%i:%%j:%%k" == "1582:10:5" set/a JDX-=10
         )
     )
)
IF DEFINED ERR echo !err:$=^

!
ECHO !JD! !JDX!
pause
复制代码

 y=(i*33+999)/12053 //索引反求日期中年份的
复制代码

int isdate(int y, int m, int d){
	int mi[]={0,31,28,31,30,31,30,31,31,30,31,30,31};
	if ((y%4 == 0) && (y%100 != 0) || (y%100 == 0))
		mi[2]+=1;
	if (m<=0||m>12)
		return 0;
	if (d<=0||d>mi[m])
		return 0;
	return 1;
}
复制代码

(i*4+99)/1461; 3301-2-28以内正确；
复制代码

(i*4+999)/1461; 33301-2-28以内正确；
复制代码

//&cls&@type %~fs0|tcc -run -
// 把tcc.exe 和 lib\msvcrt.def 放在当前目录下；双击本脚本解释执行下面C代码

int i2date(int , int *, int *, int *);
int date2i(int, int, int);
int isdate(int, int, int);

int main(){
int i,j,y,t,m,d;
for (i=0; i<1461*100000; i++){ // 0 ~ 40万年索引号
	i2date(i,&y,&m,&d);
	if (!isdate(y,m,d)){
		printf("wrongdate: /%5d:%4d/%2d/%2d\n",i,y,m,d);
		getchar();
	}
	j=date2i(y,m,d);
	if (i!=j) {
		printf("/%5d:%4d/%2d/%2d\n",i,y,m,d);
		getchar();
	}
}
return 0;
}
int isdate(int y, int m, int d){
	int mi[]={0,31,28,31,30,31,30,31,31,30,31,30,31};
	if ((y%4 == 0) && (y%100 != 0) || (y%100 == 0))
		mi[2]+=1;
	if (m<=0||m>12)
		return 0;
	if (d<=0||d>mi[m])
		return 0;
	return 1;
}
int i2date(int i, int *year, int *month, int *day){ // 索引转日期
   int t,y,m,d;      y=(i*33+999)/12053;
    t=i-y*365-y/4+y/100-y/400;  y+=t>>9;  t=i-y*365-y/4+y/100-y/400; 
    m=(t*5+2)/153;  d=t-(m*153+2)/5+1;
    y+=(m+2)/12;  m=(m+2)%12+1;
   *year=y;  *month=m;  *day=d;
    return 0;
}
int date2i(int y, int m, int d){// 日期转索引
	m+=9;m%=12; y-=m/10;
	return 365*y+y/4-y/100+y/400+(m*153+2)/5+d-1;
}
复制代码

    /*
     * shift new year to March 1 and start months from 1 (not 0),
     * it is needed for Gauss' formula
     */

    if (--month <= 0) {
        month += 12;
        year -= 1;
    }

    /* Gauss' formula for Grigorian days since March 1, 1 BC */

    time = (uint64_t) (
            /* days in years including leap years since March 1, 1 BC */

            365 * year + year / 4 - year / 100 + year / 400

            /* days before the month */

            + 367 * month / 12 - 30

            /* days before the day */

            + day - 1

            /*
             * 719527 days were between March 1, 1 BC and March 1, 1970,
             * 31 and 28 days were in January and February 1970
             */

            - 719527 + 31 + 28) * 86400 + hour * 3600 + min * 60 + sec;
复制代码

  /* days in years including leap years since March 1, 1 BC */
             365 * year + year / 4 - year / 100 + year / 400

            /* days before the month */

            + 367 * month / 12 - 30

            /* days before the day */

            + day - 1
复制代码

:date2i <year> <month> <day> <RetVarName>  // 一楼计算公式
setlocal&set/a y=%1,m=%2,d=%3
set/am+=9,m%%=12,y-=m/10,i=365*y+y/4-y/100+y/400+(m*153+2)/5+d-1
endlocal&if %4.==. (echo %i%)else set %4=%i%
goto:eof
复制代码

:Gauss_date2i <year> <month> <day> [RetVarName]  // Gauss 日期计算公式
setlocal&set/a "y=%1,m=%2-2,d=%3
if %m% leq 0 set/a m+=12,y-=1
set/a i=365*y+y/4-y/100+y/400+367*m/12+d-31
endlocal&if %4.==. (echo %i%)else set %4=%i%
复制代码