批处理之家 - Powered by Discuz! Board

标题: [文本处理] [已解决]批处理如何读取出ini文件中的指定节点及其下键值对 [打印本页]

作者: aries215 时间: 2012-4-8 02:20 标题: [已解决]批处理如何读取出ini文件中的指定节点及其下键值对

本帖最后由 pcl_test 于 2016-9-8 22:34 编辑

=== 本贴解决了两个处理INI文件的问题! ===

最近要整理一些INI配置文件, 想通过批处理实现高效作业.

要求:
1, 获取各 [...] 标签的名字并赋值, 并分别输出下面相关的行;
2, 忽略以";"开头的行, 也无需保留空行;
3, 无临时文件, 速度快.

......
[FILE]
; 系统启动文件
%SystemDriver%\autoexec.bat
%SystemDriver%\config.sys
%SystemDriver%\io.sys
%SystemDriver%\msdos.sys
%SystemDriver%\ntldr

[FOLDER]
%ProgramFiles%\Internet Explorer
......
复制代码

不知道标签名, 想要读取出标签名 "FILE"和"FOLDER", 并分别输出该标签内的所有行, 如何实现?

拜托了!

作者: gawk 时间: 2012-4-8 13:35

chenall那个你看懂了没？
如果能看懂的话，略加修改就会变成你要的了吧。

作者: fatcat 时间: 2012-4-8 13:43

@echo off & setlocal enabledelayedexpansion
> b.txt (
  for /f "delims=" %%a in ('findstr /b /v ";" a.txt') do (
    set lin=%%a
    if "!lin:~0,1!"=="[" (set print=0
      if /i "!lin:~0,6!"=="[intel" set print=1
    ) else if "!print!"=="1" echo %%a
  )
)
复制代码

从 a.txt 输出到 b.txt

作者: aries215 时间: 2012-4-8 13:45

没看懂啊, 太复杂了.

我想实现这样的批处理命令:
1, 跳至"INTEL"所在行, 输出下面的行;
2, 忽略以";"开头的行;
3, 遇到"["开头的行则终止.

啊~~~

作者: aries215 时间: 2012-4-8 13:51

回复 3# fatcat
结果是, 连"AMD"标签的内容也全部出来了...

作者: fatcat 时间: 2012-4-8 13:55

回复 5# aries215

我测试过, 没有那样, 你把代码修改过了没有

作者: aries215 时间: 2012-4-8 14:06

回复 6# fatcat
哦, 是我搞错了.
抱歉!

作者: aries215 时间: 2012-4-8 14:35

本帖最后由 aries215 于 2012-4-8 14:40 编辑

回复 3# fatcat
为什么是 >b.txt 在最前面呢?
有什么特殊含义?

作者: gawk 时间: 2012-4-8 14:36

回复 8# aries215

你希望放在后面也无所谓，没啥。

作者: apang 时间: 2012-4-8 14:38

@echo off
for /f "delims=[] skip=2" %%i in ('find /i /n "[INTEL" a.txt') do set n=%%i
for /f "eol=; skip=%n% delims=" %%i in ('type a.txt') do (
  set "str=%%i"
  setlocal EnableDelayedExpansion
  if "!str:~0,1!"=="[" pause&goto :eof
  endlocal
  echo %%i
)
pause
复制代码

作者: aries215 时间: 2012-4-8 14:45

本帖最后由 aries215 于 2012-4-8 14:51 编辑

回复 10# apang
大哥, 这代码还能精简一些吗?
6行能实现吗?

作者: aries215 时间: 2012-4-8 14:51

本帖最后由 aries215 于 2012-4-8 14:53 编辑

回复 9# gawk
如果放在后面, 能直接输出减少一层括号吗?
如果不是把结果输出到文本, 能否帮忙再改一下吧~

作者: apang 时间: 2012-4-8 14:55

回复 11# aries215

要精简就不能考虑特殊字符了。。。

@echo off&setlocal EnableDelayedExpansion
for /f "delims=[] skip=2" %%i in ('find /i /n "[INTEL" a.txt') do set n=%%i
(for /f "eol=; skip=%n% delims=" %%i in ('type a.txt') do (
  set "str=%%i"&(if not "!str:~0,1!"=="[" (echo !str!) else goto :eof)
))>b.txt
复制代码

作者: aries215 时间: 2012-4-8 14:58

本帖最后由 aries215 于 2012-4-8 15:05 编辑

回复 13# apang
你太强悍了! 真的是5行...
为什么要 skip=2 ? 实际是任意行啊.
eol=; 是可以省略的吧.

如果不是要输出到文件呢, 我要把结果作为一个值用到一组命令中...

作者: gawk 时间: 2012-4-8 15:08

回复 14# aries215

3行，有意思吗？

@echo off&setlocal EnableDelayedExpansion
for /f "delims=[] skip=2" %%i in ('find /i /n "[INTEL" a.txt') do set n=%%i
(for /f "eol=; skip=%n% delims=" %%i in ('type a.txt') do (set "str=%%i"&(if not "!str:~0,1!"=="[" (echo !str!) else goto :eof)))>b.txt
复制代码

作者: apang 时间: 2012-4-8 15:12

用find要忽略2行，用findstr不用加skip，eol=;可以不要。至少6行，再少不会搞了。。。

@echo off&setlocal EnableDelayedExpansion
for /f "delims=:" %%i in ('findstr /in "[INTEL" a.txt') do set n=%%i
for /f "skip=%n% delims=" %%i in ('type a.txt') do (
  set "str=%%i"&(if not "!str:~0,1!"=="[" (echo !str!) else pause&goto :eof)
)
pause
复制代码

作者: aries215 时间: 2012-4-8 15:17

本帖最后由 aries215 于 2012-4-8 15:18 编辑

大侠请息怒~

顺便帮忙把输出到文件改成echo吧~

作者: find 时间: 2012-4-8 15:17

2行：

@echo off&setlocal EnableDelayedExpansion&for /f "delims=[] skip=2" %%i in ('find /i /n "[INTEL" a.txt') do set n=%%i
(for /f "eol=; skip=%n% delims=" %%i in ('type a.txt') do (set "str=%%i"&(if not "!str:~0,1!"=="[" (echo !str!) else goto :eof)))>b.txt
复制代码

作者: aries215 时间: 2012-4-8 15:27

行数越少, 感觉越复杂了, 还得自己再次排版.
行数不重要, 其实我前面只是说能不能精简的意思, 不是单纯要求行数少.

作者: aries215 时间: 2012-4-8 15:32

回复 16# apang
请问一下, "delims=:" 是什么意思? 貌似我的样本里面没有":"字符啊.
不过结果也对的.

作者: apang 时间: 2012-4-8 15:37

回复 20# aries215

在命令提示符下分别输入findstr /in "[INTEL" a.txt
和find /i /n "[INTEL" a.txt 就知道是啥意思了，呵呵

作者: aries215 时间: 2012-4-8 15:44

本帖最后由 aries215 于 2012-4-8 16:42 编辑

前面的那些代码, 套到别的样品中, 结果不对, 整不出来啊.

作者: apang 时间: 2012-4-8 16:01

"[INTEL"你改了吗
如改成[REGISTR

作者: aries215 时间: 2012-4-8 16:16

哦, 好了. 非常感谢 apang , fatcat , gawk , find !!
特别鸣谢 apang 不厌其烦的解答!

作者: aries215 时间: 2012-4-8 17:06

本帖最后由 aries215 于 2012-4-8 17:14 编辑

回复 16# apang
还有疑问!

我在处理一些文件和文件夹的时候, 需要针对不同类型的对象采用不同的处理方式.

比如我想要对下面这个列表分别使用不同的命令进行处理:

......
[FILE]
; 系统启动文件
%SystemDriver%\autoexec.bat
%SystemDriver%\config.sys
%SystemDriver%\io.sys
%SystemDriver%\msdos.sys
%SystemDriver%\ntldr

[FOLDER]
%ProgramFiles%\Internet Explorer
......
复制代码

假如我不知道标签名, 想要读取出标签名 "FILE"和"FOLDER", 并分别输出该标签内的所有行, 如何实现?

拜托各位了!

作者: find 时间: 2012-4-8 17:46

回复 25# aries215

读取标签名：

@echo off
for /f "delims=[]" %%a in ('findstr "^\[" a.txt') do (
    echo %%a
)
pause
复制代码

作者: aries215 时间: 2012-4-8 18:37

本帖最后由 aries215 于 2012-4-8 18:46 编辑

回复 26# find
这个能合并到一起吗?

就是说, 从第一个"[]"开始逐行输出整个INI文件的内容, 碰到"[]"就获取标签的名字赋值给另一个变量, 以便使用不同的命令参数来处理, 只使用一次findstr命令行不?

像上面25楼的INI格式, 我要分别对里面的文件和文件夹分开用不同的命令参数来处理, 应该是用什么方式比较合适??

作者: aries215 时间: 2012-4-8 18:59

我自己整的只能显示最后一组标签的相关内容, 前面的被忽略掉了:

FOLDER
%ProgramFiles%\Internet Explorer

代码如下:

@echo off
setlocal EnableDelayedExpansion
for /f "delims=[]" %%a in ('findstr "^\[" a.txt') do set opt=%%a
for /f "delims=:" %%i in ('findstr /in "!opt!" a.txt') do set n=%%i
for /f "skip=%n% delims=" %%i in ('type a.txt') do (
	set "str=%%i"
	if not "!str:~0,1!"=="[" (echo !opt!&echo !str!) else (
	pause
	goto :eof
	)
)
pause
复制代码

怎么能分别输出INI的所有有效行??

作者: fatcat 时间: 2012-4-8 20:12

回复 28# aries215

@echo off & setlocal enabledelayedexpansion
> b.txt (for /f "delims=" %%l in ('findstr /v "^$" a.txt^|findstr /b /v ";"') do (
  set "lin=%%l"
  if "!lin:~0,1!"=="[" (echo !lin:~1,-1!) else echo %%l
))
复制代码

作者: aries215 时间: 2012-4-8 20:43

本帖最后由 aries215 于 2012-4-8 20:46 编辑

回复 29# fatcat
好码! 聪明! 我咋没想到呢~?

欢迎光临批处理之家 (http://bathome.net./)