批处理之家 - Powered by Discuz! Board

标题: [日期时间] 批处理文件里面%%~t为何有时出错？ [打印本页]

作者: fyr000000 时间: 2012-5-13 00:20 标题: 批处理文件里面%%~t为何有时出错？

for /f "delims=" %%i in ('dir /b C:\batch_test\source\"*.*"') do echo %%~ti
复制代码

就这样一句简单的话,返回C:\batch_test\source根目录下所有文件的日期,我的批处理文件取名叫st.bat,然后在跑批处理的时候,有时候能出结果,有时候却会出现echo错误,谁能跟我说一下这个%%~t,在这里到底是什么意思不,注:这句简单代码本身也是我网上找的

作者: 冷玉公子 时间: 2012-5-13 12:15

for /R C:\batch_test\source\ %%i in (*) do echo %%~ti 
复制代码

这样就行了，如果想知道你的问题是为什么的话。
去分析一下你的命令：dir /b C:\batch_test\source\"*.*"
第一：*.* 不需要引号
第二：这样有空行的时候，echo 就是空了所以错误

作者: gawk 时间: 2012-5-13 14:12

请问报错信息是什么？

作者: fyr000000 时间: 2012-5-13 15:51

回复 2# 冷玉公子

这个的确有用,而且我在ms-dos下运行此段批处理,也不需要把当前的盘符转到批处理的盘符,那个程序如果不转到批处理的盘符,运行批处理结果就是echo打开或者echo关闭的错误,什么结果都不能显示

作者: poter 时间: 2012-5-13 22:57

一般只有字符串，或者引用字符串变量的时候才加双引号

作者: 幼稚园 时间: 2012-8-24 17:41

本帖最后由幼稚园于 2012-8-25 14:49 编辑

for /f "delims=" %%i in ('dir /b C:\batch_test\source\"*.*"') do echo %%~ti
复制代码

用echo,"%%~i就能发现%%~i只是个文件名(包括扩展名)；
故此时,%%~ti就表示在当前工作目录找到"%%~i"文件，然后扩展其时间信息。
::dir /b显示的是文件名，dir /b/s会显示绝对路径
根据上面的分析，当批处理处在C:\batch_test\source\时，便能无误的运行。
下面是我改写的代码，批处理放哪都不会出错:
代码1(通过获取绝对路径的方法):

for /f "delims=" %%i in ('dir /b C:\batch_test\source\"*.*"') do (
set a=%%~i
call :main
)
pause>nul
exit
:main
for %%i in ("C:\batch_test\source\%a%") do (
echo,%%~ti
)
goto :eof
复制代码

代码2(同过改变工作目录的方法):

pushd "C:\batch_test\source\"
for /f "delims=" %%i in ('dir /b C:\batch_test\source\"*.*"') do (
echo,%%~ti
)
pause>nul
exit
复制代码

另外，%%~si也是一样的。
不过%%~ni、%%~xi就不会出现这样的情况，我觉得大概是因为%%~ni不需要找到目标文件，而是直接在%%i的值中扩展。

欢迎光临批处理之家 (http://bathome.net./)