批处理之家 - Powered by Discuz! Board

标题: [问题求助] [已解决]vbs判断指定标题的窗口并激活该窗口 [打印本页]

作者: 522235677 时间: 2013-4-9 14:45 标题: [已解决]vbs判断指定标题的窗口并激活该窗口

本帖最后由 522235677 于 2013-4-9 19:00 编辑

判断所有的窗口中是否含有“百度”标题的窗口，
如果没有则一直循环查找，直到查到到有这个窗口后，
然后把就把这窗口激活，就是把这个窗口调到最上方，然后自动按下回车键

作者: 522235677 时间: 2013-4-9 14:56

set ws=createobject("wscript.shell")  
ws.appactivate "记事本"
ws.sendkeys "{enter}"
复制代码

这个可以激活窗口，但是不知道怎么修改让他一直检测，我加do 和loop后，然后就不管在哪窗口上都狂按回车键。

作者: yu2n 时间: 2013-4-9 16:24

本帖最后由 yu2n 于 2015-4-18 20:25 编辑

在5秒内查找含有“百度”文字的窗口，若存在，则激活并提示 "找到一个含有“百度”文字的窗口！"，提示后退出。

'VBS 查找含有“百度”文字的窗口，激活并提示 By yu2n

'在5秒内查找含有“百度”文字的窗口，
'  若存在，则激活并提示 "找到一个含有“百度”文字的窗口！"
'  若不存在，则提示 "找不到含有“百度”文字的窗口！"

Const sTitle = "百度"   ' 查找窗口名称
Const nTimeOut = 5      ' 指定超时时间

Dim dtStart, bFind
dtStart = Now()
Do While DateDiff("s", dtStart, Now()) < nTimeOut
  WScript.Sleep 200
  If CreateObject("WScript.Shell").Appactivate(sTitle) Then
    bFind = True  ' 做标记-已找到
    Exit Do
  End If
Loop

If bFind Then
  Msgbox "找到一个含有“百度”文字的窗口！耗时 " & DateDiff("s", dtStart, Now()) _
    & " 秒。", vbSystemModal+vbInformation, WScript.ScriptName
Else
  Msgbox "找不到含有“百度”文字的窗口！耗时 " & DateDiff("s", dtStart, Now()) _
    & " 秒。", vbSystemModal+vbCritical, WScript.ScriptName
End If
复制代码

作者: 9zhmke 时间: 2013-7-8 23:54

Appactivate很不可靠，为了编写个机房注册autocad和3dmax的小vbs，我只有启用大漠组件来写vbs了，推荐你也使用。

作者: lidin 时间: 2019-5-8 19:37

回复 3# yu2n
学习了，正好用上，感谢！

欢迎光临批处理之家 (http://bathome.net./)

Powered by Discuz! 7.2