批处理之家 - Powered by Discuz! Board

标题: [文本处理] [已解决]这个代码怎么改成兼容多分割地址的批处理？ [打印本页]

作者: samsung4203 时间: 2013-4-16 16:25 标题: [已解决]这个代码怎么改成兼容多分割地址的批处理？

下面这段带代码是读取a.txt批量修改文件名现在出现的问题是这个代码是根据"/"分隔了多少名称来修改文件名的

@echo off
for /f "delims=" %%a in (a.txt) do (
  set "str=%%a"  
  call :lp %%str:/= %%
)
pause&goto :eof
:lp
set/a n+=1
if %n% lss 10 (set "name=X00%n%%~x6") else set "name=X0%n%%~x6"
if exist "%6" ren "%6" "%name%"
复制代码

比如说a.txt里面的"http://img01.taobaocdn.com/imgextra/i1/737837801/T2q8enXoJXXXXXXXXX_!!737837801.jpg”用"/"分割了6个名称，另一个a.txt里面用"/"分了不等的名称，可能是3个、4个、5个等等。如果这样的话每次使用都得修改

if %n% lss 10 (set "name=X00%n%%~x6") else set "name=X0%n%%~x6"
if exist "%6" ren "%6" "%name%"
复制代码

代码中的两个X6和两个%6，有没有办法改成兼容的代码！

作者: BAT-VBS 时间: 2013-4-16 17:31

@echo off
for /f "delims=" %%a in (a.txt) do (
    call :lp %%~nxa
)
goto :eof

:lp
set /a n+=1
if %n% lss 10 (
    set "name=X00%n%%~x1"
) else (
    set "name=X0%n%%~x1"
)
if exist "%1" (
    ren "%1" "%name%"
)
复制代码

作者: apang 时间: 2013-4-16 17:49

@echo off
set /a n=1000
for /f "delims=" %%a in (a.txt) do (
   set "Name=%%~nxa"
   set /a n+=1
   setlocal enabledelayedexpansion
   if exist "!Name!" ren "!Name!" "X!n:~-3!%%~xa"
   endlocal
)
pause
复制代码

作者: samsung4203 时间: 2013-4-16 17:54

多谢Apang大哥！问题解决了！

作者: samsung4203 时间: 2013-4-16 17:55

多谢BAT-VBS！问题解决了

作者: BAT-VBS 时间: 2013-4-16 18:14

回复 5# samsung4203

问题解决后，请编辑顶楼帖子在标题前面注明[已解决]，并给回答者加分。

作者: wangx 时间: 2014-11-3 15:59

对我很有帮助，学习啦。

欢迎光临批处理之家 (http://bathome.net./)