最高人民法院公报
1985年
　第01期
　第02期
　第03期
　第04期
1986年
　第01期
　第02期
　第03期
　第04期
1987年
　第01期
　第02期
　第03期
　第04期
1988年
　第01期
　第02期
　第03期
　第04期
1989年
　第01期
　第02期
　第03期
　第04期
复制代码

最高人民法院公报		　第03期			　第02期	
1985年			　第04期			　第03期
　第01期			1987年			　第04期	
　第02期			　第01期			1989年
　第03期			　第02期			　第01期
　第04期			　第03期			　第02期
1986年			　第04期			　第03期
　第01期			1988年			　第04期
　第02期			　第01期	
复制代码

@echo off
set /a 列数=5,列宽=32
%1 %0 :|more /t%列宽% >b.txt&pause&exit
for /f "delims=U" %%a in ('cmd /u /c echo 唉') do set "tab=%%a"
(for /f "delims=" %%a in (a.txt) do (
   set str=%%a
   setlocal enabledelayedexpansion
   set /p=!str!%tab%
   endlocal
   set /a n+=1,n%%=列数,n/n||echo;
))<nul 2>nul
复制代码

@echo off&setlocal enabledelayedexpansion
set /a 列数=3,列宽=32
%1 %0 :|more /t%列宽% >b.txt&pause&exit
for /f "delims=U" %%a in ('cmd /u /c echo 唉') do set "tab=%%a"
(for /f "delims=" %%a in (a.txt) do set /a n+=1&set /p ar[!n!]=)<a.txt

set /a 行数=(n+列数-1)/ 列数
for /l %%a in (1 1 %行数%) do (
	set "str="
	for /l %%b in (%%a %行数% %n%) do (
		set "str=!str!!ar[%%b]!%tab%"
	)
	echo;!str!
)
复制代码

@echo off&setlocal enabledelayedexpansion
set /a 列数=3,列宽=32
%1 %0 :|more /t%列宽% >$&(for /f "tokens=*" %%a in ($) do echo %%a)>b.txt&del $&exit

for /f "delims=U" %%a in ('cmd /u /c echo 唉') do set "tab=%%a"
(for /f "delims=" %%a in (a.txt) do set /a n+=1&set /p ar[!n!]=)<a.txt

set /a 行数=(n+列数-1)/ 列数
for /l %%a in (1 1 %行数%) do (
        set "str="
        for /l %%b in (%%a %行数% %n%) do (
                set "str=!str!%tab%!ar[%%b]!"
        )
        echo;!str!
)
复制代码

1行 5行  9行 13行 17行 21行 25行 29行 33行
2行 6行 10行 14行 18行 22行 26行 30行 34行
3行 7行 11行 15行 19行 23行 27行 31行
4行 8行 12行 16行 20行 24行 28行 32行
复制代码

当文档总行数=26,列数c=5，每列行数x=5，余数=1时
即：c≥x时,按你15楼理解应该排成这样：（前余数=1列为x+1=6行，后面剩余的列按x行）
1    7    12   17   22
2    8    13   18   23
3    9    14   19   24
4    10   15   20   25
5    11   16   21   26
6
但是1楼给出的却是：
当文档总行数=26,列数c=5，每列行数x=5，余数=1时
1    7    13   19   25
2    8    14   20   26
3    9    15   21
4    10   16   22
5    11   17   23
6    12   18   24
同理当文档总行数=26,列数c=7，每列行数x=3，余数=5时，此时c≥x是应是按以下排版，可对?：
1    5    9    13   17   21   24
2    6    10   14   18   22   25
3    7    11   15   19   23   26
4    8    12   16   20

所以按你文字说明,下面的情况应该是按下面前者而非后者，可对？
当文档总行数=26,列数c=4，每列行数x=6，余数=2时，c<x,这样排:
1    8    15   22
2    9    16   23
3    10   17   24
4    11   18   25
5    12   19   26
6    13   20
7    14   21
当文档总行数=26,列数c=4，每列行数x=6，余数=2时,c<x,而非这样排:
1    8    15   21
2    9    16   22
3    10   17   23
4    11   18   24
5    12   19   25
6    13   20   26
7    14

如果上面理解正确，那么12/5,34/11,28/9则均属于c>x的情况，即按你15楼给出的（前余数列为x+1行，后面剩余列按x行）
这有什么特殊呢？
如果我的描述有误，你就以26行为例，把分割成3,4,5,6,7列的结果排上来看看。整除的就不用了。
然后把正确描述更新到顶楼吧，目前描述的错误蛮多的。
草拟了一个代码，不过好像有点繁杂了，等着看看terse的算法...
复制代码

@echo off&setlocal enabledelayedexpansion
set L=11
set "file=test.txt"
for /f "delims=U" %%a in ('cmd /u /c echo 唉') do set "tab=%%a"
for /f "usebackq tokens=*" %%i in ("%file%") do set /a N+=1&set #!N!=%%i
set /a h=(n+l-1)/l,j=(n%%l)*H,i=h-1
if !j! leq 0 set j=n
for /l %%i in (1 1 %n%) do (
    if %%i leq %j% (
       set /a "m=(%%i-1)%%h+1"
    ) else set /a "m=-~%%i %% i+1"
      for %%j in (!m!) do set "$%%j=!$%%j!%tab%!#%%i!"
)
(for /l %%i in (1 1 %h%) do for /f "tokens=*" %%j in ("!$%%i!") do echo %%j)>$T.em
more /t16 $T.em >n.txt
del $T.em
pause
复制代码

@echo off&setlocal enabledelayedexpansion

rem 生成测试文件
(for /l %%a in (1,1,26) do echo %%a)>$1

rem 以下主体部分
for /f "delims=U" %%a in ('cmd /u /c echo 唉') do set "tab=%%a"
(for /f "delims=" %%a in ($1) do set /a n+=1&set /p ar[!n!]=)<$1
set /a 列数=5,列宽=5,m=n/列数,余数=n%%列数,行数=(n+列数-1)/列数,修正递增=行数-1,修正终值=行数*余数

if !修正终值! neq 0 (
  set 有余数=.
  if %列数% leq %m% set /a 修正终值="(列数-1)*行数"
  call :sc "!修正终值!"
) else (
  call :sc "!n!"
)
more /t%列宽% $t>b.txt
del $?&start b.txt&exit /b

:sc
set /a a=c=行数,b=0,d=%~1
:loop
for /l %%a in (1 1 %a%) do (
    set /a b+=1
    for /l %%b in (!b! %c% %d%) do (
      if "!str%%a!"=="" (
        set "str%%a=!ar[%%b]!"
      ) else (
        set "str%%a=!str%%a!%tab%!ar[%%b]!"
      )
    )
)
if defined 有余数 (
    set /a a=行数-1,b=修正终值,c=修正递增,d=n
    set "有余数="
    goto :loop
)
(
	echo 当文档总行数=%n%,列数c=%列数%，每列行数x=%m%，余数=%余数%时
	if !列数! leq !m! (echo 即c小于等于x) else echo 即c大于x
	for /l %%a in (1,1,%行数%) do echo,!str%%a!
)>$t
goto :eof
复制代码

@echo off&setlocal enabledelayedexpansion
set L=5
set "file=a.txt"
for /f "delims=U" %%a in ('cmd /u /c echo 唉') do set "tab=%%a"
for /f "usebackq tokens=*" %%i in ("%file%") do set /a N+=1&set #!N!=%%i
set /a h=(n+l-1)/l,j=(n%%l)*H,_i=h-1
if !j! leq 0 set j=n
for /l %%i in (1 1 %n%) do (
    if %%i leq %j% (
       set /a "m=(%%i-1)%%h+1"
    ) else set /a "m=(%%i--~j)%%_i+1"
      for %%j in (!m!) do set "$%%j=!$%%j!%tab%!#%%i!"
)
(for /l %%i in (1 1 %h%) do for /f "tokens=*" %%j in ("!$%%i!") do echo %%j)>csm.txt
more /t16 csm.txt >nmn.txt
pause
复制代码

@echo off&setlocal enabledelayedexpansion
%1 %0 REM|more /t32 >n.txt
set L=5
set "file=a1.txt"
for /f "delims=U" %%a in ('cmd /u /c echo 唉') do set "tab=%%a"
for /f "usebackq tokens=*" %%i in ("%file%") do set /a N+=1&set #!N!=%%i
set /a h=(n+l-1)/l,j=n,i=1
if !h! lss !l! set /a j=(n%%l)*H
for /l %%i in (1 1 %n%) do (
    set /a "t=^!^!(~-%%i/j)"
    set /a "m=(~-%%i-(t*j))%%(~-H+i*^!t)+1"
    for %%j in (!m!) do set "$%%j=!$%%j!%tab%!#%%i!"
)
for /l %%i in (1 1 %h%) do for /f "tokens=*" %%j in ("!$%%i!") do echo %%j
复制代码

@echo off&setlocal enabledelayedexpansion
%1 %0 :|more /t32 >n.txt&exit
set L=9
set "file=a.txt"
for /f "delims=U" %%a in ('cmd /u /c echo 唉') do set "tab=%%a"
for /f "usebackq tokens=*" %%i in ("%file%") do set /a N+=1&set #!N!=%%i
set /a h=(n+l-1)/l,j=n
if !h! lss !l! set /a j=(n%%l)*h 
for /l %%i in (1 1 %n%) do (
    set /a "i=^!(~-%%i/j),m=(~-%%i-(^!i*j))%%(~-H+i)+1"
    for %%j in (!m!) do set "$%%j=!$%%j!%tab%!#%%i!"
)
for /l %%i in (1 1 %h%) do for /f "tokens=*" %%j in ("!$%%i!") do echo %%j
复制代码

:: 代码代号含义：
:: k=文本总行数
:: cut=切分的列数
:: x=k/c=每列的行数
:: r=remainder=余数行=k-cx
:: ak=总添加的行数=(cut*(x+1))-k
:: s=记录当前文件需要排列的行数=x或(x+1)
:: s2=少行列=s-ak
:: n=记录当前列输出到第几行
:: m=记录当前输出到第几个文件

@echo off
title 切分文本程序（三分法）

set file=a
set Cut=9
setlocal enabledelayedexpansion
for /f "delims=" %%a in (%file%.txt) do set/a k+=1
set /a x=%k%/%Cut%
set /a r=%k%-%Cut%*%x%
set /a ak=(%Cut%*(%x%+1))-%k%
set m=
set m=1
set n=
for /f "delims=" %%i in (%file%.txt) do (
set /a n+=1
	if !r! leq 0 (
	set /a s=%x%
	if !n! leq !s! echo %%i>>%file%_!m!.txt
	if !n! equ !s! set n=0 & set /a m+=1
		) else (
		set /a s=%x%+1
		if !ak! lss !s! (
		if !n! leq !s! echo %%i>>%file%_!m!.txt
		if !n! equ !s! set n=0 & set /a m+=1
		if !m! equ !cut! set /a s2=!s!-!ak!
		if !n! equ !s2! for /l %%i in (1,1,%ak%) do echo.>>%file%_!cut!.txt
			) else (
			if !m! leq !r! (
			if !n! leq !s! echo %%i>>%file%_!m!.txt
			if !n! equ !s! set n=0 & set /a m+=1
				) else (
				if !m! gtr !r! if !n! leq !x! echo %%i>>%file%_!m!.txt
				if !m! gtr !r! if !n! equ !x! echo.>>%file%_!m!.txt
				if !n! equ !x! set n=0 & set /a m+=1
					)
				)
			)
		)
endlocal
goto:eof
复制代码

@echo off&setlocal enabledelayedexpansion
%1 %0 :|more /t32 >n.txt&exit
set L=9
set "file=test.txt"
for /f "delims=U" %%a in ('cmd /u /c echo 唉') do set "tab=%%a"
for /f "usebackq tokens=*" %%i in ("%file%") do set /a N+=1&set #!N!=%%i
set /a h=(n+l-1)/l
if !h! gtr !l! set /a j=(n%%l)*h
if !j! equ 0 set j=!n!
for /l %%i in (1 1 %n%) do (
    set /a "i=^!(~-%%i/j),m=(~-%%i-(^!i*j))%%(~-H+i)+1"
    for %%j in (!m!) do set "$%%j=!$%%j!%tab%!#%%i!"
)
for /l %%i in (1 1 %h%) do for /f "tokens=*" %%j in ("!$%%i!") do echo %%j
复制代码

@echo off&setlocal enabledelayedexpansion
%1 %0 :|more /t32 >n.txt&exit
set "file=test.txt"
for /f "delims=U" %%a in ('cmd /u /c echo 唉') do set "tab=%%a"
for /f "usebackq tokens=*" %%i in ("%file%") do set /a N+=1&set #!N!=%%i
set L=9
set /a "h=(n+l-1)/l,i=^!(~-l/h),j=^!i*(n%%l)*h+i*n"
for /l %%i in (1 1 !n!) do (
    set /a "i=^!(~-%%i/j),m=(~-%%i-(^!i*j))%%(~-h+i)+1"
    for %%j in (!m!) do set "$%%j=!$%%j!%tab%!#%%i!"
)
for /l %%i in (1 1 !h!) do for /f "tokens=*" %%j in ("!$%%i!") do echo %%j
复制代码

@echo off&setlocal enabledelayedexpansion
%1 %0 :|more /t32 >n.txt&exit
set "file=test.txt"
for /f "delims=U" %%a in ('cmd /u /c echo 唉') do set "tab=%%a"
for /f "usebackq tokens=*" %%i in ("%file%") do set /a N+=1&set #!N!=%%i
set L=9
set /a "h=(n+l-1)/l,j=n%%l,i=^!(l/h)"
if !j! equ 0 (set j=!n!)else set /a "j=~-l*h*i+j*h" 
for /l %%i in (1 1 !n!) do (
    set /a "i=^!(~-%%i/j),m=(~-%%i-(^!i*j))%%(~-h+i)+1"
    for %%j in (!m!) do set "$%%j=!$%%j!%tab%!#%%i!"
)
for /l %%i in (1 1 !h!) do for /f "tokens=*" %%j in ("!$%%i!") do echo %%j
复制代码