批处理之家 - Powered by Discuz! Board

@echo off&setlocal enabledelayedexpansion
set /p "var=请输入字符串:"
echo ========================
echo [法一]
set time1=%time%
set /a time1_second=1%time1:~-5,2%-100
set /a time1_millisec=1%time1:~-2,2%-100
rem ----------[法一]主程序开始---------------------
:loop
set /a a+=1
if not "!var:~%a%,1!" equ "" goto :loop
echo 共有%a%个字符
rem ----------[法一]主程序结束---------------------
set time2=%time%
set /a time2_second=1%time2:~-5,2%-100
set /a time2_millisec=1%time2:~-2,2%-100
if %time2_millisec% lss %time1_millisec% set /a time2_millisec+=100&set /a time2_second-=1
set /a second=time2_second-time1_second
set /a millisec=time2_millisec-time1_millisec
echo 开始时间:%time1% 结束时间:%time2%
echo 程序1运行时间为%second%秒%millisec%0毫秒
echo ========================
echo [法二]
set time1=%time%
set /a time1_second=1%time1:~-5,2%-100
set /a time1_millisec=1%time1:~-2,2%-100
rem ----------[法二]主程序开始---------------------
for /l %%a in (0,1,10000) do if "!var:~%%a,1!" equ "" set length=%%a&goto end
:end
echo 共有%length%个字符
rem ----------[法二]主程序结束---------------------
set time2=%time%
set /a time2_second=1%time2:~-5,2%-100
set /a time2_millisec=1%time2:~-2,2%-100
if %time2_millisec% lss %time1_millisec% set /a time2_millisec+=100&set /a time2_second-=1
set /a second=time2_second-time1_second
set /a millisec=time2_millisec-time1_millisec
echo 开始时间:%time1% 结束时间:%time2%
echo 程序2运行时间为%second%秒%millisec%0毫秒
echo ========================
echo [法三]
set time1=%time%
set /a time1_second=1%time1:~-5,2%-100
set /a time1_millisec=1%time1:~-2,2%-100
rem ----------[法三]主程序开始---------------------
set count=0
:loop2
set /a num+=1
for /f %%i in ("%num%") do if not "!var:~%%i,1!"=="" goto loop2
echo 共有%num%个字符
rem ----------[法三]主程序结束---------------------
set time2=%time%
set /a time2_second=1%time2:~-5,2%-100
set /a time2_millisec=1%time2:~-2,2%-100
if %time2_millisec% lss %time1_millisec% set /a time2_millisec+=100&set /a time2_second-=1
set /a second=time2_second-time1_second
set /a millisec=time2_millisec-time1_millisec
echo 开始时间:%time1% 结束时间:%time2%
echo 程序3运行时间为%second%秒%millisec%0毫秒
echo ========================
echo [法四] batman's idea
set time1=%time%
set /a time1_second=1%time1:~-5,2%-100
set /a time1_millisec=1%time1:~-2,2%-100
rem ----------[法四]主程序开始---------------------
echo %var%>a.txt
echo.>>a.txt
for /f "tokens=1 delims=:" %%i in ('findstr /o .* a.txt') do set /a length=%%i-2&if not %%i
equ 0 echo 共有%length%个字符&goto end
:end
del a.txt
rem ----------[法四]主程序结束---------------------
set time2=%time%
set /a time2_second=1%time2:~-5,2%-100
set /a time2_millisec=1%time2:~-2,2%-100
if %time2_millisec% lss %time1_millisec% set /a time2_millisec+=100&set /a time2_second-=1
set /a second=time2_second-time1_second
set /a millisec=time2_millisec-time1_millisec
echo 开始时间:%time1% 结束时间:%time2%
echo 程序4运行时间为%second%秒%millisec%0毫秒
pause>nul

复制代码

========================
[法一]
共有1021个字符
开始时间:21:57:20.33 结束时间:21:57:21.52
程序1运行时间为1秒190毫秒
========================
[法二]
共有1021个字符
开始时间:21:57:21.52 结束时间:21:57:21.70
程序2运行时间为0秒180毫秒
========================
[法三]
共有1021个字符
开始时间:21:57:21.70 结束时间:21:57:23.00
程序3运行时间为1秒300毫秒
========================
[法四] batman's idea
共有1021个字符
开始时间:21:57:23.00 结束时间:21:57:23.21
程序4运行时间为0秒210毫秒

复制代码

[法一]
共有83个字符
开始时间:22:02:01.70 结束时间:22:02:01.75
程序1运行时间为0秒50毫秒
========================
[法二]
共有83个字符
开始时间:22:02:01.77 结束时间:22:02:01.85
程序2运行时间为0秒80毫秒
========================
[法三]
共有83个字符
开始时间:22:02:01.85 结束时间:22:02:01.91
程序3运行时间为0秒60毫秒
========================
[法四] batman's idea
共有83个字符
开始时间:22:02:01.91 结束时间:22:02:01.95
程序4运行时间为0秒40毫秒

复制代码

@echo off
set "var=qwertyuioplkjhgfdsazxcvbnm"
call :strLen var long
echo;%long%
pause&exit /b
:strLen
( SETLOCAL ENABLEDELAYEDEXPANSION
set "str=A!%~1!"
set "len=0"
for /L %%A in (12,-1,0) do (
set /a "len|=1<<%%A"
for %%B in (!len!) do if "!str:~%%B,1!"=="" set /a "len&=~1<<%%A"
)
)
( ENDLOCAL
IF "%~2" NEQ "" SET /a %~2=%len%
)
goto :eof

复制代码

@echo off & setlocal enabledelayedexpansion
set "_strlen=set $=#^!$^!&set ##=&for /l %%a in (12,-1,0)do set/a"##^|^=1^<^<%%a"&for %%b in (^!##^!)do if ^!$:~%%b^!.==. set /a"##^&^=~1^<^<%%a""
for %%i in (
12345678901234567890123456789012345678901234567890
1234567890123456789012345678901234567890
123456789012345678901234567890
12345678901234567890
1234567890
1
) do (
set "$=%%i" & (%_strlen%)
echo;!##! : %%i
)
pause & exit /b

复制代码

Echo off&CLS
IF /i "%PROCESSOR_ARCHITECTURE%" EQU "AMD64" (
echo DEBUG和8086_ASM不支持64位的系统。
Pause&Exit
)
>"%Tmp%\DEBUGASM.TMP" (
Echo A
Echo MOV BX,20 ;一段安全的空间
Echo MOV SS,BX
Echo MOV SP,80 ;清理安全空间
Echo MOV CX,40 ;循环次数（HEX）=清理字节数（128B）/入栈大小（2B）
Echo SUB BX,BX ;清空BX
Echo PUSH BX ;执行入栈（清理）
Echo LOOP 10D ;循环压栈
Echo SUB CX,CX ;清空CX
Echo INT 21H
Echo.&Echo G)
Set /P str=Input a string:
Echo E20:0 "%STR%">>"%Tmp%\DEBUGASM.TMP"
More +25 "%~0" >>"%Tmp%\DEBUGASM.TMP"
For /f "Tokens=2" %%a in (
'^<%tmp%\DEBUGASM.TMP DEBUG^|Findstr /c:"0020:0000"'
) Do Set /a Strlen=0x%%a
DEL %tmp%\DEBUGASM.TMP
Echo %Strlen%&Pause&Exit /b
A100
MOV BX,20 ;一段安全的空间
MOV DS,BX
SUB BX,BX ;清空BX
MOV CL,[BX] ;获取Ascii
JCXZ 10E ;判断是否为NUL并跳出
INC BX ;计数
JMP 107 ;循环读取
MOV [0],BX ;将字符串长度写入内存
INT 21H
G
D20:0 0
Q
Q

复制代码

@Echo off
IF /i "%PROCESSOR_ARCHITECTURE%" EQU "AMD64" (
echo DEBUG和8086_ASM不支持64位的系统。
Pause&Exit
)
Set "Str=%*"
>%tmp%\DEBUGASM.TMP (
ECHO A20:0
ECHO DB "%Str:~,70%"
ECHO DB "%Str:~70,70%"
ECHO DB "%Str:~140,70%"
ECHO DB "%Str:~210,45%"
ECHO DB 0
ECHO.
MORE +20 "%~0"
)
For /f "Tokens=2" %%a in (
'^<%tmp%\DEBUGASM.TMP DEBUG^|Findstr /c:"0020:0000"'
) Do Set /a Strlen=0x%%a 2>nul
Echo %Strlen%&DEL /F %tmp%\DEBUGASM.TMP&Exit /b
A100
MOV BX,20 ;一段安全的空间
MOV DS,BX
SUB BX,BX ;清空BX
MOV CL,[BX] ;获取Ascii
JCXZ 10E ;判断是否为NUL并跳出
INC BX ;计数
JMP 107 ;循环读取
MOV [0],BX ;将字符串长度写入内存
INT 21H
G
D20:0 0
Q
老刘制作～

复制代码

@echo off
setlocal enabledelayedexpansion
::%1 字符串
set str=%1
set strLen=0
:StartLoop
if "%str%"=="" goto EndLoop
set str=!str:~1!
set /a strLen+=1
goto StartLoop
:EndLoop
echo %1 length is !strLen!

复制代码