Board logo

标题: [其他] 文件图标提取工具：extractIcon.exe [打印本页]
作者: pusofalse    时间: 2009-1-2 23:02     标题: 文件图标提取工具：extractIcon.exe

  1. @echo Off

  2. :: extractIcon.exe <[文件] [图标序号] [输出文件名]>

  3. :: 返回值：

  4. ::          %errorlevel% =  0 : 成功提取

  5. ::          %errorlevel% = -1 : 参数错误

  6. ::          %errorlevel% = -2 : 找不到文件

  7. ::          %errorlevel% = -3 : 其他错误，序号不存在于文件中，或不能载入图标。

  8. extractIcon.exe shell32.dll -131 test.ico

  9. set "GetQQPath=reg query HKLM\Software\Tencent\QQ /v Install"

  10. For /f "skip=4 tokens=2*" %%a in ('%GetQQPath%') do (

  11.        extractIcon.exe "%%bQQ.exe" -1 "%cd%\QQ.Ico"

  12. )
复制代码
extractIcon.exe source:
  1. #NoTrayIcon

  2. #AutoIt3Wrapper_Change2CUI=y

  3. Global $aEN[1]

  4. Local $help = @scriptName & " <File> <Index> <Output file>" & @crLf

  5. If $CmdLine[0] <> 3 then

  6.         consoleWrite($help)

  7.         exit(-1)

  8. EndIf

  9. 

  10. $File = $CmdLine[1]

  11. If not fileExists($File) then

  12.         $file = @systemDir & "\" & $cmdLine[1]

  13.         If not fileExists($File) then

  14.                 consoleWriteErr($cmdLine[1] & " not found." & @crLf)

  15.                 exit(-2)

  16.         EndIf

  17. EndIf

  18. $Index = number($cmdLine[2])

  19. _ExtractIconToFile($File, $Index, $CmdLine[3])

  20. If @error = 0 then exit(0)

  21. exit(-3)

  22. 

  23. Func _ExtractIconToFile($sInFile, $iIcon, $sOutIco, $iPath = 0)

  24.         Local Const $LOAD_LIBRARY_AS_DATAFILE = 0x00000002

  25.         Local Const $RT_ICON = 3

  26.         Local Const $RT_GROUP_ICON = 14

  27.         Local $hInst, $iGN = "", $sData, $sHdr, $aHdr, $iCnt, $Offset, $FO, $FW, $iCrt = 18

  28.         If $iPath = 1 Then $iCrt = 26

  29.         If Not FileExists($sInFile) Then Return SetError(1, 0, 0)

  30.         If Not IsInt($iIcon) Then Return SetError(2, 0, 0)

  31.         $hInst = _LoadLibraryEx($sInFile, $LOAD_LIBRARY_AS_DATAFILE)

  32.         If Not $hInst Then Return SetError(3, 0, 0)

  33.         _ResourceEnumNames($hInst, $RT_GROUP_ICON)

  34.         For $i = 1 To $aEN[0]

  35.                 If $i = StringReplace($iIcon, "-", "") Then

  36.                         $iGN = $aEN[$i]

  37.                         ExitLoop

  38.                 EndIf

  39.         Next

  40.         Dim $aEN[1]

  41.         If $iGN = "" Then

  42.                 _FreeLibrary($hInst)

  43.                 Return SetError(4, 0, 0)

  44.         EndIf

  45.         $sData = _GetIconResource($hInst, $iGN, $RT_GROUP_ICON)

  46.     If @error Then 

  47.             _FreeLibrary($hInst)

  48.                 Return SetError(5, 0, 0)

  49.         EndIf

  50.         $sHdr = BinaryMid($sData, 1, 6)

  51.         $aHdr = StringRegExp(StringTrimLeft(BinaryMid($sData, 7), 2), "(.{28})", 3)

  52.         $iCnt = UBound($aHdr)

  53.         $Offset = ($iCnt * 16) + 6

  54.         For $i = 0 To $iCnt -1

  55.                 Local $sDByte = Dec(_RB(StringMid($aHdr[$i], 17, 8)))

  56.                 $sHdr &= StringTrimRight($aHdr[$i], 4) & _RB(Hex($Offset))

  57.                 $Offset += $sDByte                

  58.         Next

  59.         For $i = 0 To $iCnt -1

  60.                 $sData = _GetIconResource($hInst, "#" & Dec(_RB(StringRight($aHdr[$i], 4))), $RT_ICON)

  61.                 If @error Then 

  62.                     _FreeLibrary($hInst)

  63.                         Return SetError(6, 0, 0)

  64.                 EndIf

  65.                 $sHdr &= StringTrimLeft($sData, 2)

  66.         Next        

  67.         _FreeLibrary($hInst)

  68.         $FO = FileOpen($sOutIco, $iCrt)

  69.         If $FO = -1 Then Return SetError(7, 0, 0)

  70.         $FW = FileWrite($FO, $sHdr)

  71.         If $FW = 0 Then 

  72.             FileClose($FO)

  73.                 Return SetError(8, 0, 0)

  74.         EndIf

  75.         FileClose($FO)

  76.         Return SetError(0, 0, 1)

  77. EndFunc   ;==>_ExtractIconToFile

  78. 

  79. ; ========================================================================================================

  80. ; Internal Helper Functions from this point on

  81. ; ========================================================================================================

  82. Func _GetIconResource($hModule, $sResName, $iResType)

  83.         Local $hFind, $aSize, $hLoad, $hLock, $tRes, $sRet

  84.         $hFind = DllCall("kernel32.dll", "int", "FindResourceA", "int", $hModule, "str", $sResName, "long", $iResType)

  85.         If @error Or Not $hFind[0] Then Return SetError(1, 0, 0)

  86.         $aSize = DllCall("kernel32.dll", "dword", "SizeofResource", "int", $hModule, "int", $hFind[0])

  87.         If @error Or Not $aSize[0] Then Return SetError(2, 0, 0)

  88.         $hLoad = DllCall("kernel32.dll", "int", "LoadResource", "int", $hModule, "int", $hFind[0])

  89.         If @error Or Not $hLoad[0] Then Return SetError(3, 0, 0)

  90.         $hLock = DllCall("kernel32.dll", "int", "LockResource", "int", $hLoad[0])

  91.         If @error Or Not $hLock[0] Then

  92.                 _FreeResource($hLoad[0])

  93.                 Return SetError(4, 0, 0)

  94.         EndIf

  95.         $tRes = DllStructCreate("byte[" & $aSize[0] & "]", $hLock[0])

  96.         If Not IsDllStruct($tRes) Then

  97.                 _FreeResource($hLoad[0])

  98.                 Return SetError(5, 0, 0)

  99.         EndIf

  100.         $sRet = DllStructGetData($tRes, 1)

  101.         If $sRet = "" Then

  102.                 _FreeResource($hLoad[0])

  103.                 Return SetError(6, 0, 0)

  104.         EndIf

  105.         _FreeResource($hLoad[0])

  106.         Return $sRet

  107. EndFunc        

  108. 

  109. ; Just a Reverse string byte function (smashly style..lol)

  110. Func _RB($sByte)

  111.         Local $aX = StringRegExp($sByte, "(.{2})", 3), $sX = ''

  112.         For $i = UBound($aX) - 1 To 0 Step -1

  113.                 $sX &= $aX[$i]

  114.         Next

  115.         Return $sX

  116. EndFunc   ;==>_RB

  117. 

  118. Func _LoadLibraryEx($sFile, $iFlag)

  119.         Local $aRet = DllCall("Kernel32.dll", "hwnd", "LoadLibraryExA", "str", $sFile, "hwnd", 0, "int", $iFlag)

  120.         Return $aRet[0]

  121. EndFunc   ;==>_LoadLibraryEx

  122. 

  123. Func _FreeLibrary($hModule)

  124.         DllCall("Kernel32.dll", "hwnd", "FreeLibrary", "hwnd", $hModule)

  125. EndFunc   ;==>_FreeLibrary        

  126. 

  127. Func _FreeResource($hglbResource)

  128.         DllCall("kernel32.dll", "int", "FreeResource", "int", $hglbResource)

  129. EndFunc   ;==>_FreeResource

  130. 

  131. Func _ResourceEnumNames($hModule, $iType)

  132.         Local $aRet, $xCB

  133.         If Not $hModule Then Return SetError(1, 0, 0)

  134.         $xCB = DllCallbackRegister('___EnumResNameProc', 'int', 'int_ptr;int_ptr;int_ptr;int_ptr')

  135.         $aRet = DllCall('kernel32.dll', 'int', 'EnumResourceNamesW', 'ptr', $hModule, 'int', $iType, 'ptr', DllCallbackGetPtr($xCB), 'ptr', 0)

  136.         DllCallbackFree($xCB)

  137.         If $aRet[0] <> 1 Then Return SetError(2, 0, 0)

  138.         Return SetError(0, 0, 1)

  139. EndFunc   ;==>_ResourceEnumNames

  140. 

  141. Func ___EnumResNameProc($hModule, $pType, $pName, $lParam)

  142.         Local $aSize = DllCall('kernel32.dll', 'int', 'GlobalSize', 'ptr', $pName), $tBuf

  143.         If $aSize[0] Then

  144.                 $tBuf = DllStructCreate('wchar[' & $aSize[0] & ']', $pName)

  145.                 ReDim $aEN[UBound($aEN) + 1]

  146.                 $aEN[0] += 1

  147.                 $aEN[UBound($aEN) - 1] = DllStructGetData($tBuf, 1)

  148.         Else

  149.                 ReDim $aEN[UBound($aEN) + 1]

  150.                 $aEN[0] += 1

  151.                 $aEN[UBound($aEN) - 1] = "#" & $pName

  152.         EndIf

  153.         Return 1

  154. EndFunc   ;==>___EnumResNameProc
复制代码
[attach]745[/attach]

http://bcn.bathome.net/s/tool/index.html?key=extractIcon



欢迎光临 批处理之家 (http://bathome.net./) Powered by Discuz! 7.2