@echo off&setlocal enabledelayedexpansion
set /p a=1数：
set /p b=2数：
set a2=0
for /f "delims=. tokens=1,2" %%i in ("%a%") do set a1=%%i&set a2=%%j
if "%a2%"=="" goto next1
if %a2% leq 9 goto next2
if %a2% gtr 9 goto next3

:next1
set a2=0
set /a a3=a1*100
goto next4
:next2
set /a a3=a1*100+a2*10
goto next4

:next3
set /a a3=a1*100+a2
goto next4

:next4

for /f "delims=. tokens=1,2" %%i in ("%b%") do set b1=%%i&set b2=%%j
if "%b2%"=="" goto next6
if %b2% leq 9 goto next7
if %b2% gtr 9 goto next8
pause

:next6
set b2=0
set /a b3=b1*100
goto next9
:next7
set /a b3=b1*100+b2*10
goto next9

:next8
set /a b3=b1*100+b2
goto next9

:next9
set sign=2
set /a c=a3+b3
set "s=!c:~-%sign%!"
echo !c:%s%=!.%s%
pause>nul
复制代码

@echo off&setlocal enabledelayedexpansion
set /p str=输入的两数为：
set /a num_1=0,num_2=0,num=1,v=0
for %%a in (%str%) do (
    set /a n+=1
    for /f "tokens=1,2 delims=." %%b in ("%%a") do (
        set "_!n!=%%b"
        if "%%c" equ "" (
           set ".!n!=00"&set /a m+=1
           if !m! equ 2 set "flag=a"
           ) else (
           set "a=%%c00"&set "a=!a:~,2!"
           set ".!n!=!a!"
        ) 
     )
)
for %%a in (+#h -#c) do (
    for /f "tokens=1,2 delims=#" %%b in ("%%a") do (
        if "%_1:~,1%" equ "-" set "k1=-"
        if "%_2:~,1%" equ "-" set "k2=-"
        set /a %%c1=_1%%b_2,%%c2=!k1!1%.1%%%100%%b!k2!1%.2%%%100
        if !%%c1! lss 0 (
           if !%%c2! leq -100 set /a %%c2+=100,%%c1-=1
           ) else (
           if !%%c1! equ 0 (
              if !%%c2! lss 0 set "%%c1=-0"&set "a=!%%c2!"&set "%%c2=!a:-=!"
              ) else (
              if !%%c2! lss 0 set /a %%c2+=100,%%c1-=1
           )
         )
         if !%%c2! geq 100 set /a %%c2-=100,%%c1+=1 
    )
)
for %%a in (h2 c2) do (
    set "a=!%%a!"&set "a=!a:-=!"&set %%a=!a!
    if !a! lss 10 set "%%a=0!a!"
)
echo 其和为：%h1%.%h2%&echo 其差为：%c1%.%c2%&set /a n=0
if defined flag set ".1="&set ".2="
for %%a in (1 2) do (
    if "!_%%a!" equ "0" (
       set "_%%a="&set /a .%%a=1!.%%a!%%100
       ) else (
       if "!_%%a!" equ "-0" (
          set "_%%a=-"
          ) else (
          set "a=!_%%a!"&set "a=!a:-=!"
          set /a n+=1&call :lp
       )
    )
    if "!.%%a!" neq "" set "a=!.%%a!"&call :loop&set ".%%a=!a!"
)
set /a num1=3-num_1+num_2,m=4-v
if defined flag set /a m=0
if %num1% leq 0 set /a num1=2
for /l %%a in (1,1,%num1%) do set /a num*=10
set /a s=%_1%%.1%*num/%_2%%.2%,j=%_1%%.1%*%_2%%.2%
if %j% lss 0 set "j=%j:-=%"&set "jk=-"
if %s% lss 0 set "s=%s:-=%"&set "sk=-" 
if %m% neq 0 if "!j:~%m%!" equ "" set "j=0000%j%"&set "j=!j:~-%m%!"
if %s% lss %num% set "s=%num:~1%%s%"&set "s=!s:~-%num1%!"
if %m% neq 0 set "j=!j:~,-%m%!.!j:~-%m%,2!"
set "s=!s:~,-%num1%!.!s:~-%num1%,2!
for %%a in (s j) do (
    set "a=!%%a!"
    if "!a:.=!" equ "!a!" (
       set "%%a=!%%a!.00"
       ) else (
       if "!a:~-2,1!" equ "." set "%%a=!%%a!0"
    )  
    if "!a:~,1!" equ "." set "%%a=0!%%a!"
)
echo 其积为：%jk%%j%&echo 其商为：%sk%%s%
pause>nul&goto :eof
:lp
set /a num_%n%+=1&set "a=%a:~1%"
if defined a goto lp
goto :eof
:loop
if "%a:~-1%" equ "0" set "a=%a:~,-1%"&set /a v+=1&goto loop
复制代码

@echo off&setlocal enabledelayedexpansion
:begin
set /p m=输入(q退出):
if "!m!"=="q" goto :eof
set /p n=输入:
for /f "tokens=1,2 delims=." %%i in ("%m%") do set m1=%%j00&if not "%%j"=="" (set mm=%%i!m1:~0,2!) else set mm=%%i00
for /f "tokens=1,2 delims=." %%i in ("%n%") do set n1=%%j00&if not "%%j"=="" (set nn=%%i!n1:~0,2!) else set nn=%%i00

if "!mm:~0,1!"=="-" (set mm=!mm:~1!&set /a num=2!mm!-1!mm!,mm=1!mm!-num&set mm=-!mm!) else set /a num=2!mm!-1!mm!,mm=1!mm!-num
if "!nn:~0,1!"=="-" (set nn=!nn:~1!&set /a num=2!nn!-1!nn!,nn=1!nn!-num&set nn=-!nn!) else set /a num=2!nn!-1!nn!,nn=1!nn!-num

set /a add=mm+nn
call :check !add! num1
echo 两值之和是: !num1!

set /a sub=mm-nn
call :check !sub! num2 
echo 两值之差是: !num2!


set /a mul=mm*nn
if !mul! lss 100 (set num3=0.00) else (
set mul=!mul:~0,-2!
call :check !mul! num3
)
echo 其积为:!num3!

set /a div=100*mm/nn
call :check !div! num4
echo 其商为:%num4%

goto begin

:check
set var=%1&set "_="
if !var! lss 0 (set /a var=-1*var&set _=-)
if !var! lss 10 (set var=00!var!) else if !var! lss 100 set var=0!var!
if "!var:~-2!"=="00" (set var=!var:~0,-2!) else if "!var:~-1!"=="0" (set var=!var:~0,-2!.!var:~-2,1!) else set var=!var:~0,-2!.!var:~-2!
set %2=!_!!var!&goto :eof
复制代码

@echo off
setlocal enabledelayedexpansion
set /p q=请输入两个小数：
for %%i in (%q%) do (
set /a a+=1
set a!a!=%%i
)
set /a a=%a1%+%a2%
set /a b=%a1%-%a2%
set /a c=%a1%*%a2%
set /a d=%a1%/%a2%
echo 两个小数的和为%a%
echo 两个小数的差为%b%
echo 两个小数相乘为%c%
echo 两个小数相除为%d%
pause
复制代码

@echo off
rem 已封装
setlocal enabledelayedexpansion
set ctr=0
set "bc=%~1"
set "c=%~2"
set f=false
if "!bc:~0,1!"=="-" if "!c:~0,1!"=="-" (
 set bc=!bc:-=!
 set c=!c:-=!
 set bc=!bc: =!
 set c=!c: =!
 set f=false
) else (
 rem nothing
)
if "!bc:~0,1!"=="-" if "!c:~0,1!" neq "-" (
 set bc=!bc:-=!
 set bc=!bc: =!
 set f=true
) else (
 rem nothing
)
if "!bc:~0,1!" neq "-" if "!c:~0,1!"=="-" (
 set c=!c:-=!
 set c=!c: =!
 set f=true
) else (
 rem nothing
)
set tbc=!bc!
set tc=!c!
set tbc=!tbc:.=!
set tc=!tc:.=!
set tbc=!tbc: =!
set tc=!tc: =!
if !"tbc!" neq "!bc!" if  "!tc!" neq "!c!" (
 for /f "delims=. tokens=1-3 eol=a" %%a in ('echo !bc!') do (
  call :len %%b
  set lenbcx=!zz!
 )
 for /f "delims=. tokens=1-3 eol=a" %%a in ('echo !c!') do (
  call :len %%b
  set lencx=!zz!
 )
) else (
 goto :r
)
if !lenbcx! gtr !lencx! (
 set /a cz=lenbcx-lencx
 for /l %%a in (1,1,!cz!) do (set c=!c!0)
 set c=!c:.=!
 set c=!c: =!
 set bc=!bc:.=!
 set bc=!bc: =!
) else (
 if !lenbcx!==!lencx! set bc=!bc:.=! & set c=!c:.=! & set bc=!bc: =! & set c=!c: =! & goto :r
 set /a cz=lencx-lenbcx
 for /l %%a in (1,1,!cz!) do (set bc=!bc!0)
 set c=!c:.=!
 set c=!c: =!
 set bc=!bc:.=!
 set bc=!bc: =!
)
:r
for /l %%a in (1,1,9) do (if "!bc:~0,1!"=="0" set bc=!bc:~1!)
for /l %%a in (1,1,9) do (if "!c:~0,1!"=="0" set c=!c:~1!)
set /a "s=bc/c"
set /a "m=bc %% c"
if !m!==0 goto :f
set s=!s!.
:main
if !m!==0 goto :f
for /l %%a in (1,1,8) do (
 if !m! lss !c! (
  set /a m=m*10
  if %%a geq 2 set s=!s!0 & set /a ctr+=1
 ) else (
 rem nothing
 )
)
set /a "ss=m/c"
set /a "m=m %% !c!"
set s=!s!!ss!
set s=!s: =!
set /a ctr+=1
if !ctr! gtr 10 goto :f
goto :main
:f
if !f!==false (
 echo !s!
) else (
 echo -!s!
)
goto :eof
:len
set "t=%1"
set zz=0
for /l %%a in (0,1,11) do (
 if "!t:~%%a,1!"=="" goto :eof
 set /a zz+=1
)
goto:eof
复制代码

@echo off&setlocal enabledelayedexpansion
title 批处理小数运算。
set /p input=输入算式(如 2.96+0.907) ：
for /f "tokens=1,2 delims=+-*/" %%a in ("%input%") do (
	set x=%%a & set y=%%b
	call set symbol=%%input:%%a=%%
	call set symbol=%%symbol:%%b=%%
)
set /p precision=自定义精度(默认为3)：
if not defined precision set precision=3
set /a xsd=1
for /l %%a in (1 1 %precision%) do set /a xsd*=10
echo;
rem echo;思路：先将数字放大%xsd%倍，得到结果再缩小%xsd%倍。
set/p=%x%  %symbol% %y% 的值为:<nul 
call :largen x %precision%
call :largen y %precision%
if "%symbol%"=="*" set expression=x*y & set /a z=!expression!/%xsd%
if "%symbol%"=="/" set expression=x/y & set /a z=!expression!*%xsd%
if "%symbol%"=="+" set expression=x+y & set /a z=!expression!
if "%symbol%"=="-" set expression=x-y & set /a z=!expression!
call :output z 
echo;
pause&exit /b

:largen              
setlocal
set bignum=!%~1!
set /a _precision=%~2 + 1
for /l %%n in (1,1,%_precision%) do set zero=!zero!0
set multiple=1%zero%
for /f "tokens=1,2 delims=. " %%a in ("%bignum%") do (
	set bignum_b=%%a&set bignum_e=%%b%zero%
)
set bignum_e=1!bignum_e:~0,%_precision%!
set /a smallnum=bignum_b*multiple+bignum_e
set /a smallnum+=5
set /a smallnum-=multiple
set smallnum=%smallnum:~0,-1%
endlocal & set %~1=%smallnum%
goto :eof
  
:lessen 
setlocal
set smallnum=!%~1!
set _precision=%~2
for /l %%n in (1,1,%_precision%) do set zero=!zero!0
set multiple=1%zero%
set /a bignum_b=smallnum/multiple
set /a bignum_e=smallnum%%multiple
set bignum_e=%zero%%bignum_e%
set bignum_e=!bignum_e:~-%_precision%!
set bignum=%bignum_b%.%bignum_e%
endlocal & set %~1=%bignum%
goto :eof

:output
call :lessen %~1 %precision%
set/p=	!z!<nul
goto :eof
复制代码

set/p "input=输入表达示：
for /f "delims=" %%a in ('powershell "%input%"') do echo %%a
pause
复制代码