标题: [转贴] 批处理文章：预处理、变量延迟、call [打印本页]
作者: irresolute 时间: 2009-2-15 17:45 标题: 批处理文章：预处理、变量延迟、call
原始出处：http://bbs.verybat.org/viewthread.php?tid=9292
原始标题：讨论帖：预处理究竟是如何进行的
————————namejm补注————————————————
一、预处理究竟要做什么？
根据我的经验，预处理要做的是变量值的替换和特殊符号的处理。究竟先执行哪个操作呢，我认为要先进行变量值的替换。理由有三：
1、 从逻辑上看
set var=2&echo %var%
类似于这样的语句，如果说先进行特殊符号处理的话，势必要先处理符号“&”，而“&”是用来连接两条命令的，这样一来该行就理所应当的被理解为两句，那么我们还要变量延迟干嘛。这里应该是先对变量var赋值，然后处理特殊符号“&”。
2、从运行结果看
@echo off
set var=^^^>
echo %var%
pause
这句“set var=^^^>”首先也会被预处理，预处理之后var的值为“^>”。本例的输出结果是“>”，因此可以证明系统先将变量的值替换为“^>”然后再处理特殊符号“^”。
3、从变量替换上看
@echo off
set ^&var=hero
echo %&var%
pause
结果：显示“hero”这也说明变量的替换先于特殊符号的处理。
二、启动了变量延迟之后预处理又是如何进行呢？
我的看法是这样的：如果语句中存在英文叹号“!”则会被预处理两次，其它情况仍然是预处理一次。由于脱字字符比较特殊，，因此在此借助该符号写几个例子说明一下。
（一）
@echo off
echo !^^^^^>
setlocal enabledelayedexpansion
echo !^^^^^>
pause
两个echo语句的结果不同。下面做一下分析：对于第一个echo语句，变量延迟没有开启，进行预处理的时候该句就被预处理为“echo !^^>”，这也就是输出的结果。由此可见预
处理只进行了一次。
对于第二个echo语句，此时变量延迟开启，由于有“!”存在，首先进行一次预处理得到“echo !^^>”，再进行一次得到“echo ^>”，结果也是如此。之所以没有输出叹号，是因为开启了变量延迟，叹号就变为了特殊符号。
（二）
@echo off
setlocal enabledelayedexpansion
set var=hero
echo !var!
pause
像这里的“echo !var!”不是没有被预处理，而是被预处理了两次。看下面的这段代码就可以理解了。
@echo off
setlocal enabledelayedexpansion
set var=hero
echo !var!^^^^^>
pause
运行的结果为：“hero^>”。我们来分析一下，进行第一次预处理时，由于“!var!”，因此先不替换变量值而进行特殊符号的处理，处理完后就成了“echo !var!^^>”；之后再进行一次预处理，此时就要替换“!var!”了，处理完后就成了“echo hero^>”。
（三）
我们再来看看当变量延迟开启时语句中不存在英文叹号的情况。
@echo off
echo ^^^^^>
setlocal enabledelayedexpansion
echo ^^^^^>
pause
@echo off
set var=hero
echo %var%^^^^^>
setlocal enabledelayedexpansion
echo %var%^^^^^>
pause
怎么样，也就是说如果没有“!”就不会进行第二次处理。
（四）
对于!!型，特殊符号的处理是在变量替换之前进行的。
例、
@echo off
setlocal enabledelayedexpansion
set ^&var=hero
echo !&var!
pause
这段代码运行结果是错误的。
例、
@echo off
setlocal enabledelayedexpansion
set var=^&
echo !var!
pause
这段代码运行结果是正确的。
（五）
既然都要处理符号，那么%%型和!!型的符号处理会不会是同一个过程？
（一）中的例子已经可以说明问题，不过我还有例子可以证明。
例、
@echo off
echo "^^^^^^^^"!!
setlocal enabledelayedexpansion
echo "^^^^^^^^"!!
pause
对于%%型，在符号处理时，不处理双引号间的脱字字符；而对于!!型则相反。
作者: irresolute 时间: 2009-2-15 17:46 标题: 转篇文章（2）
三、call引出的一些问题
（一）
call与脱字字符
例、
@echo off
set /p var=<hero.txt
echo "%var%"
call echo "%var%"
pause
其中hero.txt中的内容为8个脱字字符：^^^^^^^^
结果是：
"^^^^^^^^"
"^^^^^^^^^^^^^^^^"
请按任意键继续. . .
结果是否有些出乎意料？我们知道，系统在预处理时不会处理双引号间的脱字字符，那就意味着是call命令将其后的脱字字符数量加了倍。看来call命令和脱字字符还真有点“暧昧”。
例、
@echo off
set /p var=<hero.txt
echo %var%
call echo %var%
pause
本例中变量var的值为8个“^”，运行“call echo %var%”时，首先进行变量替换把%var%替换为^^^^^^^^，再经一次符号的处理变为^^^^，此时由于call命令使得脱字字符数目增加一倍变为8个，然后再进行call本身的预处理，这样结果就为4个“^”。
这样就能解释下面的代码为什么会显示4个“^”。
@echo off
call call call call echo ^^^^^^^^
pause
（二）
call与其它特殊字符
这里所说的“其它特殊字符”主要指&、>、|等。这里请允许我自定义两个名词：
主预处理过程：系统本身预处理过程的总称，其中包括了%%型和!!型。
次预处理过程：由于call命令引起的预处理过程的总称。
“其它特殊字符”是在主预处理过程中被系统识别的，而在次预处理
过程中对这些符号的识别是有问题的。
例、
@echo off
call echo hero!^&pause
pause
本例中，经过主预处理过程，&被识别为普通字符，而在次预处理过程中符号&的识别将产生问题。正如《命令行参考》中提到的--不要在 call 命令中使用管道和重定向符号。（这倒不是说call语句中不能使用那些符号，而是这些符号不能作为参数传递给call命令。）
这也从某种程度上说明某行语句的句子结构（一条还是多条）和功能（是从定向输出还是其它）是在主预处理过程中确定的。
以上所有内容，只是我个人的看法，由于没有官方文档的支持，因
此仅供参考。
那么我们学了以上种种内容又有什么实际用途呢？我想，懂得了以上
道理就可以写出更加个性化的代码，同时也可以作为一种伪装术在实
际中应用。
@echo off
set ^&=setlocal enabledelayedexpansion
set ^^^^^hero=^^^^^&p
set ^au=^^^au
set ^^^^^^^^^=障眼法
%&%
set ^^^^^se=^^^se!
echo %^^^^%!%^^hero%!au%^se%
怎么样，这段代码能看明白吗？
作者: sjzong 时间: 2009-4-13 22:54
高手！研究透彻！应该好好学习！
作者: zqz0012005 时间: 2009-4-13 23:23
注明出处就那么难吗？
我们论坛应该规定转载文章必须尽量指明出处！（似乎已经规定了？）
作者: namejm 时间: 2009-4-13 23:45
其实zqz0012005不用苛求楼主注明详细的出处，在网络上，转载是很频繁的事情，其中不乏转载之后二次转载、三次转载……N次转载的情形，多重转载之后，最原始的出处信息很可能已经丢失掉了，在这样的情况下，要让别人给出原始出处是十分困难的事情。
为了防止这样的情形出现，论坛一直在强调转载文章需要注明出处，一方面，是出于尊重原创的基本道德；另一方面，也是希望在转载的过程中，保持原始出处，在那些具有时效性、或者更新频繁的信息发生变化的时候，能从原始出处找到最新信息。如果所有的人都做到这一点的时候，原始出处信息在转载的时候也就不会发生丢失的情况了。可惜的是，由于各种原因，很多原始出处信息被丢弃了，在这种情况下，论坛采取了折中的方案，要求转帖的时候，如果确实找不到原始出处，应该在适当的位置标注转载字样。
楼主的标题已经说得很清楚了，这是一篇转载的文章，并没有把这篇文章的创作权据为己有，不应该受到苛责。
如果zqz0012005兄或其他人知道这篇文章的原始出处，还请告知楼主贴上，或者以回帖方式发表在这篇文章下，我将补上链接。
作者: zqz0012005 时间: 2009-4-13 23:55
这篇文章并没有被多次转载。google一下（注意加上引号）：
"预处理究竟要做什么"
作者: namejm 时间: 2009-4-14 00:21
呵呵，zqz0012005兄就有点强人所难了，因为如果要网上搜索的话，一般都是通过楼主标题中的关键部分去搜的，哪里会想到要用你的那个"预处理究竟要做什么"做关键词呢？
在资讯高度发达的今天，很难保证什么文章不被转载，即使是非常冷僻的文章都难以例外，我不知道楼主是从什么地方看到的这个帖子，并且也不知道楼主不写出处的确切原因，只有问了楼主才知道。
就算是zqz0012005兄，也还非得让我网上google一把才出结果，如果碰上懒人了，可能原始出处就要等到猴年马月才会出来了，呵呵，给个原始出处的链接zqz0012005兄都要转几道弯，不是顾忌什么吧？其实只要不是论坛总版规里提及的违规内容，给出URL论坛都不会反对的，更不会以“同行是冤家”的心态去处理与本论坛具备类似性质的站点之间的关系，因为我们论坛提倡的是开源、互助，不会以邻为壑，更不会刻意封杀。
原始出处已经补充到顶楼。
作者: wc726842270 时间: 2010-10-27 13:55
正好对CALL的这种用法不了解呢，学习了
不过正好今天早上查到了关于一篇关于CALL不错的文章（个人想法），在此与大家分享
转自http://wenku.baidu.com/view/6747a1c789eb172ded63b76b.html
大家都知道call命令是用来调用其他程序的。
想必有一定经验的朋友都知道要输出%a%需要这样写“echo %%a%%”，这样
百分号会脱掉一个。
先以一个简单的echo作为引子：
例一、
@echo off
set a=b
echo %a%
echo %%a%%
echo %%%a%%%
echo %%%%a%%%%
echo %%%%%a%%%%%
pause
运行结果是：
b
%a%
%b%
%%a%%
%%b%%
解说：不知道大家看没看出来问题。批处理中类似于这样的变量替换究竟是
如何进行的呢？我们姑且称之为“替换步骤”
“替换步骤”大体分为两步：
第一步：
当百分号“%”是偶数时（只按一边的百分号数目计算），变量将
不被替换，其它的也不变。当百分号是奇数时（也只按一边的百分号数目计
），最里层的“%a%”将被替换成变量的值，此时百分号数目将少了一个（
只按一边计）。
第二步：
第一步完成后，百分号就都是偶数了。好了，现在把百分号数目的
一半脱掉，剩下的就是结果了。
拿本例的“echo %%%%%a%%%%%”为例说明一下。第一步，由于百分号有
5个是奇数，因此最里层的%a%被其值代替，现在变为“%%%%b%%%%”；第二
步，将百分号脱去一半，就变为“%%b%%”。怎么样，理解了吗？
再看看有call的时候。
例二、
@echo off
set a=b
set b=c
set c=d
call echo %%%%%%%%a%%%%%%%%
call echo %%%%%%%%%%%%%a%%%%%%%%%%%%%
pause
运行结果是：
%%a%%
%%%b%%%
解说：由于有call的存在，“替换步骤”就会多进行一次。以“call echo
%%%%%%%%%%%%%a%%%%%%%%%%%%%”为例。
“替换步骤”第一次：
第一步：
百分号有13个是奇数，因此最里层的“%a%”被其值b替换，此时为
“%%%%%%%%%%%%b%%%%%%%%%%%%”，现在百分号数目为12个了。
第二步：
将百分号数脱去一半，现在为“%%%%%%b%%%%%%”。
“替换步骤”第二次：
第一步：
百分号有6个是偶数，因此不替换。现在仍然是“%%%%%%b%%%%%%”。
第二步：
将百分号数脱去一半，现在为“%%%b%%%”。
结果就是“%%%b%%%”。
（如果有n个call那么就要进行n+1次“替换步骤”。）
call命令在“变量延迟”中也遵循“替换步骤”。
举个例子：我现在要将字符串str1的“superhero”部分替换为chess，在此我们用间接的方法实现。代码如下：
@echo off
set str1=mynameissuperhero
set str2=supxrhxro
set a=x
call call set str3=%%%%str1:%%str2:%a%=e%%=chess%%%%
echo %str3%
pause
因为用了两个call，因此要进行3次“替换步骤”。
“替换步骤”第一次：
1、将“%a%”替换成“x”，结果为“%%%%str1:%%str2:x=e%%=chess%%%%”。
2、将百分号脱去一半，为“%%str1:%str2:x=e%=chess%%”。
“替换步骤”第二次：
1、将“%str2:x=e%”替换掉，结果为“%%str1:superhero=chess%%”。
2、将百分号脱去一半，为“%str1:superhero=chess%”。
“替换步骤”第三次：
1、将“%str1:superhero=chess%”替换掉，结果为“mynameischess”。
2、将百分号脱去一半（没的脱了），因此结果为“mynameischess”。
作者: abcdshenji 时间: 2011-6-6 13:49
- @echo off
-
- setlocal enabledelayedexpansion
-
- set var=hero
-
- echo !var!^^^^^>
-
- pause
- 运行的结果为：“hero^>”。我们来分析一下，进行第一次预处理时，由于“!var!”，因此先不替换变量值而进行特殊符号的处理，处理完后就成了“echo !var!^^>”；之后再进行一次预处理，此时就要替换“!var!”了，处理完后就成了“echo hero^>”。
这个解释跟前面的观点矛盾了吧：- 根据我的经验，预处理要做的是变量值的替换和特殊符号的处理。究竟先执行哪个操作呢，我认为要先进行变量值的替换。
是不是说的有点乱哦？
按照作者前面的观点，我也可以理解成：第一次预处理时结果是：echo hero^^>，第二次与处理时结果是：echo hero^>，最后的结果就是：echo hero^>，不是照样说得通吗？
如果作者的前面观点是正确的话，我想可以这样总结（个人）：- 预处理：每条语句执行前都会进行从变量替换（如果有的话）到转义特殊符号（如果有的话）的动作过程。
- 有下面2种情况：
- （1）没有开启setlocal enabledelayedexpansion：只进行一次预处理，且用双引号包裹的内容原封不动。
- （2）有开启setlocal enabledelayedexpansion：①语句中含有!:进行两次预处理，且不管是否用双引号包裹。②语句中不含!：与情况（1）相同。
作者: applba 时间: 2011-6-6 14:38
9# abcdshenji
很老的文章了，出自英雄的教程。
楼上的不必纠结，所谓预处理是个很笼统的概念，误导性很强。
我个人认为，对功能性符号的解析（即解释其特殊功能）是分阶段的。
第一个阶段是全局性的，只解释几个特定的符号，比如%,^等，这个发生在命令运行之前。
第二个阶段的解析是用命令自行触发的，这个阶段要处理的内容很多，又可以分为多个层次。
有对通用特殊符号的解析，比如| & &&，> >> <等。
有对专用特殊符号的解析，比如set /a的数学运算符。
开启变量延迟后会解析!，call命令还会再次解析%和^。
作者: abcdshenji 时间: 2011-6-6 15:08
10# applba
感觉这都只是猜测证实的过程。。谁也说不准。。M$DOS就像黑盒子。。功力深浅全凭时间和经验。。让我这样的新人学起来相当吃力。。
作者: applba 时间: 2011-6-6 16:54
本帖最后由 applba 于 2011-6-6 16:56 编辑
关于“预处理”不能简单的归结为一次两次，其实有很多次的，每一次处理的内容都不完全相同，甚至完全不同。
预处理过程包含对特殊字符的解释、参数的识别等，其中特殊字符的解释又包含了变量的替换（微软件扩展）。
第一阶段预处理发生在cmd.exe读取时，是无条件进行的，此时命令还没有被识别出来。
第二阶段处理发生在命令被执行时，是由具体的命令进行，这个阶段的处理有很强的针对性。
这两个阶段的预处理内容可是比较复杂的，每一个阶段又可以划分为很多层次。
还有第一阶段处理的某些内容第二阶段会重复处理，或者第一阶段没有处理的第二阶段会接着处理。
好吧，也许我所说的只有我自己能理解。
其实我也是个新人。
作者: applba 时间: 2011-6-6 16:57
这个东西不必过于钻死胡同，适度了解一下就可以了。
作者: abcdshenji 时间: 2011-6-6 19:33
嗯。。你比我强多了。。向你学习！
作者: Hello123World 时间: 2011-9-30 20:12
本帖最后由 Hello123World 于 2011-9-30 20:16 编辑
回复 1# irresolute
前面的逻辑严谨，论证层层递进，很有说服力，但是
一次预处理得到“echo !^^>”，再进行一次得到“echo ^>”
作者: Hello123World 时间: 2011-9-30 20:17
唯一解释就是，!转义第一个^，第二个^转义>
作者: Hello123World 时间: 2011-9-30 20:38
- @echo off
-
- set ^&=setlocal enabledelayedexpansion
-
- set ^^^^^hero=^^^^^&p
-
- set ^au=^^^au
-
- set ^^^^^^^^^=障眼法
-
- %&%
-
- set ^^^^^se=^^^se!
-
- echo %^^^^%!%^^hero%!au%^se%
这个倒不是什么障眼法，就是不断的用转义字符在绕，绕的人眼花缭乱，也就可以了
| 欢迎光临 批处理之家 (http://bathome.net./) |
Powered by Discuz! 7.2 |