批处理之家 - Powered by Discuz! Board

标题: [文件操作] 求补充完整一个整理桌面文件的批处理程序 [打印本页]

作者: pangqijun 时间: 2015-1-23 21:23 标题: 求补充完整一个整理桌面文件的批处理程序

单位的电脑每天都有人放很多文件夹和文件，桌面很乱，我想写一个批处理程序，把这些文件和文件夹都放到别的地方，现在我能移动桌面上文件到d:\桌面临时文件\"%a%"。
问题来了
1.如果人家在桌面放的是一个文件夹，我就搞不定了。求助

2.我想创建一个d:\桌面临时文件的快捷方式到桌面，方便人家去查找。求助！~！~
搞了几天，都没整出来，只能发帖求助了。谢谢，求补充！~！~！~

@echo off
cd C:\Documents and Settings\Administrator\桌面
if not exist d:\桌面临时文件 md d:\桌面临时文件
set a=%date:~0,10%
if not exist d:\桌面临时文件\"%a%" md d:\桌面临时文件\"%a%"
move /y "C:\Documents and Settings\Administrator\桌面\*.doc" d:\桌面临时文件\"%a%"
move /y "C:\Documents and Settings\Administrator\桌面\*.xls" d:\桌面临时文件\"%a%"
move /y "C:\Documents and Settings\Administrator\桌面\*.txt" d:\桌面临时文件\"%a%"
move /y "C:\Documents and Settings\Administrator\桌面\*.ppt" d:\桌面临时文件\"%a%"
move /y "C:\Documents and Settings\Administrator\桌面\*.zip" d:\桌面临时文件\"%a%"
move /y "C:\Documents and Settings\Administrator\桌面\*.pdf" d:\桌面临时文件\"%a%"
复制代码

作者: mms0536 时间: 2015-1-23 21:43

http://www.bathome.net/thread-33758-1-1.html

作者: Batcher 时间: 2015-1-23 22:03

move命令不支持跨分区移动文件夹

作者: pcl_test 时间: 2015-1-24 00:18

本帖最后由 pcl_test 于 2015-1-24 00:20 编辑

@echo off & color 0d
for /f "tokens=2,*" %%i in ('reg query "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders" /v "Desktop"') do (
set "desktop_dir=%%j"
)
set "back_dir=D:\桌面备份"
set "filesdate=%date:~0,4%%date:~5,2%%date:~8,2%"
if not exist "%back_dir%\DesktopBack%filesdate%\" (md "%back_dir%\DesktopBack%filesdate%\")
xcopy "%desktop_dir%" "%back_dir%\DesktopBack%filesdate%\" /s /f
del "%back_dir%\DesktopBack%filesdate%\*.lnk" /s /f /q
for /f "delims=" %%a in ('dir /a-d /b /s "%desktop_dir%\*.*"') do (
if "%%~xa" neq ".lnk" (del "%%a" /f /s /q)
)
for /f "delims=" %%b in ('dir /ad /b /s "%desktop_dir%\"^|sort /r') do (rd "%%b" /s /q)
echo [InternetShortcut] >>"%desktop_dir%\桌面备份.url"
echo URL="%back_dir%\" >>"%desktop_dir%\桌面备份.url" 
echo IconIndex=4 >>"%desktop_dir%\桌面备份.url"
echo IconFile="%SystemRoot%\system32\SHELL32.dll" >>"%desktop_dir%\桌面备份.url"
pause
复制代码

回复 1# pangqijun

作者: ygqiang 时间: 2015-1-24 01:45

本帖最后由 ygqiang 于 2015-1-24 02:56 编辑

回复 pangqijun
pcl_test 发表于 2015-1-24 00:18

多谢，xp系统、win7 64系统下测试都好用

@echo off & color 0d
for /f "tokens=2,*" %%i in ('reg query "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders" /v "Desktop"') do (
set "desktop_dir=%%j"
)
set "back_dir=D:\桌面备份"
1set "filesdate=%date:~0,4%%date:~5,2%%date:~8,2%"
if not exist "d:\桌面备份\" (md "d:\桌面备份\")

xcopy "%desktop_dir%" "d:\桌面备份\" /s /f /y
del "d:\桌面备份\*.lnk" /s /f /q
del "d:\桌面备份\桌面备份.url" /q 

for /f "delims=" %%a in ('dir /a-d /b /s "%desktop_dir%\*.*"') do (
if "%%~xa" neq ".lnk" (del "%%a" /f /s /q)
)
for /f "delims=" %%b in ('dir /ad /b /s "%desktop_dir%\"^|sort /r') do (rd "%%b" /s /q)

echo [InternetShortcut] >>"%desktop_dir%\桌面备份.url"
echo URL="%back_dir%\" >>"%desktop_dir%\桌面备份.url" 
echo IconIndex=4 >>"%desktop_dir%\桌面备份.url"
echo IconFile="%SystemRoot%\system32\SHELL32.dll" >>"%desktop_dir%\桌面备份.url"

exit
复制代码

欢迎光临批处理之家 (http://bathome.net./)