4981 5487 2724 2419 4837 2218 37 19 2880 5521
9613 7292 7433 554 8287 1147 9516 5678 9760 3028
9220 5936 3580 6455 8116 9776 6246 1652 6390 6615
7855 7707 1850 4564 2454 4571 7330 8718 4499 5083
7683 3076 637 3644 9714 6080 9554 8250 5353 6692
4036 9590 4539 8156 7648 6738 8834 7033 4043 9729
7512 1299 1611 1054 9291 9948 7213 5882 6891 6149
1159 7604 1290 7426 8342 4907 7802 2285 6828 4547
940 4594 5470 3831 7949 3308 8553 5841 4532 6151
2048 4362 7137 6227 1843 2833 119 6124 6716 4435
6342 132 4637 4359 7482 632 8 35 9999 1023
复制代码

8 19 35 37 119 132 
554 632 637 940 1023 1054 
1147 1159 1290 1299 1611 1652 
1843 1850 2048 2218 2285 2419 
2454 2724 2833 2880 3028 3076 
3308 3580 3644 3831 4036 4043 
4359 4362 4435 4499 4532 4539 
4547 4564 4571 4594 4637 4837 
4907 4981 5083 5353 5470 5487 
5521 5678 5841 5882 5936 6080 
6124 6149 6151 6227 6246 6342 
6390 6455 6615 6692 6716 6738 
6828 6891 7033 7137 7213 7292 
7330 7426 7433 7482 7512 7604 
7648 7683 7707 7802 7855 7949 
8116 8156 8250 8287 8342 8553 
8718 8834 9220 9291 9516 9554 
9590 9613 9714 9729 9760 9776 
9948 9999 
复制代码

@echo off
for /f "tokens=1-10" %%a in (a.txt) do (
set/a _%%a=0,_%%b=0,_%%c=0,_%%d=0,_%%e=0,_%%f=0,_%%g=0,_%%h=0,_%%i=0,_%%j=0
)
for /l %%i in (1,1,9999) do (
if defined _%%i call :output %%i
)
exit
:output
<nul set/p=%1 >>b.txt
set/a n+=1
if %n% equ 6 echo.>>b.txt&set/a n=0
goto :eof
复制代码

@echo off&setlocal enabledelayedexpansion
>b.txt cd.
for /f "usebackq delims=" %%i in (`more a.txt`) do (set "numbers_old=!numbers_old! %%i")
for %%i in (%numbers_old%) do (
  set number=0000%%i
  set number=!number:~-4!
  set _!number!=%%i
)
for /f "tokens=2 delims==" %%i in ('set _') do (
  for %%j in (%%i) do set "numbers_new=!numbers_new! %%j"
)
for %%i in (%numbers_new%) do (
  set /p=%%i <nul >>b.txt
  set /a n+=1
  if !n! equ 6 echo.>>b.txt&set /a n=0
)
start b.txt
exit
复制代码

@echo off
setlocal EnableDelayedExpansion
>1.txt cd.&>b.txt cd.
for /f "usebackq delims=" %%i in (`more a.txt`) do (
  for %%j in (%%i)do (
    set "number=   %%j"
    echo !number:~-4!>>1.txt
  )
)
for /f "usebackq" %%i in (`sort 1.txt`) do (
  set /p=%%i <nul >>b.txt
  set /a n+=1
  if !n! equ 6 echo.>>b.txt&set /a n=0
)
start b.txt
del 1.txt
exit
复制代码

@echo off
setlocal EnableDelayedExpansion
cd.>b.txt
for /f "delims=" %%a in ('type a.txt') do for %%i in (%%a) do set number=____%%i&set !number:~-5!=1
for /f "delims=_=" %%i in ('set _^|sort') do (
  set var=!var! %%i
  set /a n+=1
  set /a "i=1/(n/6)" 2>nul && (>>b.txt echo !var!&set var=&set n=)
)
(echo !var!)>>b.txt%不足6个数的部分%
start b.txt
复制代码

@echo off
setlocal EnableDelayedExpansion
cd.>b.txt
(for /f "delims=" %%a in ('type a.txt') do for %%i in (%%a) do echo %%i)>~a.txt
(for /l %%a in (1 1 9999) do echo %%a)>~t.txt
for /f %%a in ('findstr /rxg:~a.txt t.txt') do (
  set var=!var! %%a
  set /a n+=1
  if !n!==6 (>>b.txt echo !var!&set var=&set n=)
)
(echo !var!)>>b.txt%不足6个数的部分%
del ~a.txt ~t.txt
start b.txt
复制代码

@echo off&setlocal enabledelayedexpansion
(for /f "usebackq tokens=*" %%i in ("n.txt") do (
    for %%j in (%%i) do (
        set "str=   %%j"
        echo !str:~-4!
)))>tem
for /f "tokens=*" %%i in ('sort tem') do (
  set/a n+=1,n%%=6
  if !n! equ 0 (echo !var:~1! %%i&set "var=")else set var=!var! %%i
)
if not "!var!"=="" echo !var:~1!
pause
复制代码

@echo off&setlocal enabledelayedexpansion
(for /f "usebackq tokens=*" %%i in ("n.txt") do (
    for %%j in (%%i) do echo %%j
))>tem
for /l %%i in (1 1 4) do (
if "!t!"=="" (set t=[0-9])else set t=[0-9]!t!
for /f %%i in ('findstr "\<!t!\>" tem^|sort') do (
    set/a n+=1,n%%=6
    if !n! equ 0 (echo !var:~1! %%i&set "var=")else set var=!var! %%i
)
)
if not "!var!"=="" echo !var:~1!
pause
复制代码

@echo off
if "%~1"=="" (
  setlocal enabledelayedexpansion&set /a n=0
  for /f "tokens=* delims=0" %%a in ('%~s0 h^|sort') do (
     set /a n+=1,n=n%%6
     set /p=%%a <nul
	 if !n! equ 0 echo.
   )
  pause&exit
)
setlocal enabledelayedexpansion
for /f "usebackq tokens=*" %%i in ("a.txt") do (
   for %%j in (%%i) do set m=0000000000%%j&echo !m:~-10!
)
endlocal
goto :EOF
复制代码

@echo off&setlocal enabledelayedexpansion
(for /f "usebackq tokens=*" %%i in ("a.txt") do (
    for %%j in (%%i) do echo %%j
))>tem
sort tem>tem2
cd.>tem
for /l %%a in (1 1 4) do (
   set num=.!num!
   findstr /x !num! tem2>>tem
)
for /f "delims=" %%a in (tem) do (
     set /a n+=1,n=n%%6
     set /p=%%a <nul
	 if !n! equ 0 echo.
)
echo.&pause
复制代码

@echo off
setlocal enabledelayedexpansion
::把原始数据转换成每行只有一个数字的形式
(for /f "usebackq tokens=*" %%i in ("a.txt") do (
  for %%j in (%%i) do (
    echo %%j
  )
))>tem
::分别对一位、二位、三位、四位数字进行sort排序
::这样的做的原因是sort排序时是按照字符ASCII逐位比较的
for /l %%i in (1 1 4) do (
  if "!t!"=="" (
    ::定义这样的变量是为了在后面的findstr正则表达式中匹配任意一位0到9之间的数字
    set t=[0-9]
  ) else (
    ::在后面的findstr正则表达式中分别匹配二位、三位、四位数字
    set t=[0-9]!t!
  )
  ::控制参与sort排序的数字位数
  ::在findstr正则表达式中<string>表示精确匹配
  ::结合外层for循环实现分别对一位、二位、三位、四位数字进行sort排序
  for /f %%i in ('findstr "\<!t!\>" tem^|sort') do (
    set /a n+=1
    ::对6取余是实现六列一行的关键
    set /a n%%=6
    if !n! equ 0 (
      echo !var:~1! %%i
      set "var="
    ) else (
      set var=!var! %%i
    )
  )
)
if not "!var!"=="" (
  echo !var:~1!
)
复制代码

@echo off
setlocal enabledelayedexpansion
::把原始数据转换成每行只有一个数字的形式
(for /f "usebackq tokens=*" %%i in ("a.txt") do (
  for %%j in (%%i) do (
    ::在每个数字的最左侧补上三个空格
    set "str=   %%j"
    ::截取补空格以后的字符串的最右侧四位
    ::最终的结果就是把所有数字全部补成四个字符（不足四位的在左侧补空格）
    ::这样的做的原因是sort排序时是按照字符ASCII逐位比较的
    echo !str:~-4!
  )
))>"%temp%\GridNum.txt"
::利用tokens=*忽略行首空格的特性来删除前面补的空格
for /f "tokens=*" %%i in ('sort "%temp%\GridNum.txt"') do (
  set /a n+=1
  ::对6取余是实现六列一行的关键
  set /a n%%=6
  if !n! equ 0 (
    echo !var:~1! %%i
    set "var="
  ) else (
    set var=!var! %%i
  )
)
if not "!var!"=="" (
  echo !var:~1!
)
复制代码

@echo off&setlocal enabledelayedexpansion
for /f "delims=" %%a in (a.txt) do (
    for %%b in (%%a) do set "a=####%%b"&set "_!a:~-4!=a"
)
for /f "tokens=1 delims=#_=" %%a in ('set _') do (
     set /a n+=1,m=n%%6
     set /p=%%a        <nul>>b.txt
     if !m! equ 0 echo.>>b.txt
)
start b.txt
复制代码

for /f "delims=" %%a in ('findstr .* a.txt') do echo %%a
复制代码

findstr .* a.txt>b.txt
for /f "delims=" %%a in (b.txt) do echo %%a
复制代码

@echo off&setlocal enabledelayedexpansion
for /f "delims=" %%i in ('more a.txt') do (
for %%j in (%%i) do (
set "num=0000%%j"&set "num=!num:~-4!"
if defined _!num! (set/a m+=1&set _!num!!m!=%%j
) else set _!num!=%%j
))
for /f "tokens=2 delims==" %%i in ('set _') do (
<nul set/p=%%i >>b.txt
set/a n+=1
if !n! equ 6 echo.>>b.txt&set/a n=0
)
start "" "b.txt"
复制代码

@echo off
Setlocal EnableDelayedExpansion
Set fs=1.txt
Set dt=2.txt
Set tf=db-tmp.txt
Set lenb=1
Set "o=>>%tf%"

call :sizehex %fs%
call :consoledb %fs%

::scan file1
%o% echo s 100 %size% 20
%o% echo q
start /w debug ^<%tf% ^>db-out.txt

::edit file1
call :consoledb %fs%
for /f "eol=- tokens=2 delims=:" %%a in (db-out.txt) do (
if defined old (
	set /a len=0x%%a-old-1
	set /a old=0x%%a
	if !len! GTR !lenb! Set /a lenb=len
) else (
	set /a old=0x%%a
)
%o% echo e %%a
%o% echo 0A
)
%o% echo w
%o% echo q
start /w debug ^<%tf%

::output
call :fined >%dt%


call :sizehex %dt%
call :consoledb %dt%

::scan file2
%o% echo s 100 %size% 0D
%o% echo q
start /w debug ^<%tf% ^>db-out.txt

::edit file2
call :consoledb %dt%
for /f "eol=- tokens=2 delims=:" %%a in (db-out.txt) do (
	set /a count+=1,line=count%%6
	if !line! NEQ 0 (
		%o% echo e %%a
		%o% echo 20 20
	)
)
%o% echo w
%o% echo q
start /w debug ^<%tf%




pause
del db-???.txt
goto :eof

:fined
set reg=%reg%[0-9]
if %lenb% EQU 0 goto :eof
set /a lenb-=1
more %fs%|findstr /b /e %reg%|sort
call :fined
goto :eof

:consoledb
>%tf% cd.
%o% echo n%1
%o% echo l
goto :eof

:sizehex
set /a size=%~z1/16*10
goto :eof
复制代码

@echo off&setlocal enabledelayedexpansion
for /l %%a in (1 1 10000) do (
    for /f "delims=" %%b in (a.txt) do (
        for %%c in (%%b) do (
            if %%a equ %%c set /p= %%a<nul&set /a n+=1&if !n! equ 6 echo\&set n=0
)))
pause
复制代码