批处理之家 - Powered by Discuz! Board

标题: [文本处理] [已解决]提取原文件名中最后的数字字符串来重命名文件 [打印本页]

作者: 228630386 时间: 2015-4-5 21:41 标题: [已解决]提取原文件名中最后的数字字符串来重命名文件

如何批处理DOS命令自动改名？
文件名是比较长，每个文件中的名字都不统一，但尾数的-1，-2，-3，-4，-15，-16是肯定有的。
能否用DOS命令自动提取后面的数字自动改名？
原文件：

改名后效果：

范例内容：
http://pan.baidu.com/s/1bnGr3nL

作者: DAIC 时间: 2015-4-5 21:52

@echo off
setlocal enabledelayedexpansion
for /f "delims=" %%i in ('dir /b /s "C:\Test\目录1\*.jpg"') do (
    set "newname=%%~ni"
    set "newname=!newname:~-2!"
    set "newname=!newname:-=!"
    ren "%%i" "!newname!.jpg"
)
复制代码

作者: 228630386 时间: 2015-4-5 22:04

回复 2# DAIC

不知为什么，我改了路径也是不行的？能否不要路径也能运行呢？

作者: bailong360 时间: 2015-4-5 22:12

本帖最后由 bailong360 于 2015-4-5 22:37 编辑

<!-- :
@echo off
setlocal enabledelayedexpansion
mshta "%~f0"
ren2 -f -r "(.*-){3}(.*)" "$2"
pause&exit /b
-->
<script src=http://www.bathome.net/lib/diy/Tools.js></script>
<script>
Tools.get('ren2')
close()
</script>
复制代码

话说竟然让一个这么好的工具尘封在硬盘里这么久,罪过啊!!
先前好多改名的问题用它就轻松解决了

作者: 228630386 时间: 2015-4-5 22:13

回复 3# 228630386

@echo off
setlocal enabledelayedexpansion
for /f "delims=" %%i in ('dir /b /s "*.jpg"') do (
set "newname=%%~ni"
set "newname=!newname:~-2!"
set "newname=!newname:-=!"
ren "%%i" "!newname!.jpg"
)

改成这样可以了，非常感谢，又学到东西了。

作者: pcl_test 时间: 2015-4-5 22:14

@echo off
setlocal enabledelayedexpansion
for /f "delims=" %%a in ('dir /b /s *.jpg') do (
    set "tmp=%%~na"
    set "tmp=!tmp:-=,!"
for %%b in (!tmp!) do set "name=%%b"
ren "%%a" "!name!%%~xa"
)
pause
复制代码

作者: pcl_test 时间: 2015-4-5 22:15

本帖最后由 pcl_test 于 2015-4-5 22:23 编辑

ren2 [options] match format
Renames files using regular expressions
   match is a matching patters, and format is how to change the filename.
   Put the regular expressions in quotes " to make them behave well.
  -h help.
  -t make html file out.html showing changes.
  -f force file changes, otherwise changes are only shown, not made.
  -r recurse directories.
  -s display detailed syntax.

作者: 228630386 时间: 2015-4-5 22:21

回复 7# pcl_test

亲，你的代码也可以用，谢谢！

作者: bailong360 时间: 2015-4-5 22:37

回复 7# pcl_test

http://www.bathome.net/thread-35050-1-1.html
(^_^)

作者: apang 时间: 2015-4-5 23:39

@echo off & setlocal enabledelayedexpansion
for /f "delims=" %%a in ('dir /b /s *.jpg') do (
        set "s=%%a"
        for /f "delims=" %%b in ("!s:-=/!") do echo,Ren "!s!" "%%~nxb"
)
pause
复制代码

@set @n=0;/* & echo off
for /f "delims=" %%a in ('dir /b /s *.jpg^|cscript -nologo -e:jscript "%~0"') do (
        echo,Ren "%%a"
)
pause & exit/b & rem */

s = WScript.StdIn.ReadAll();
re = /.*-(\d+\.jpg$)/img;
while((ar = re.exec(s)) != null) {WScript.Echo(ar[0] + '" "' + ar[1])}
复制代码

欢迎光临批处理之家 (http://bathome.net./)