@echo off
for %%a in (c d e f g h i j k l m n o p q r s t u v w x y z) do (
    for /f %%h in ('fsutil fsinfo drivetype %%a:^|findstr "Removable.* 可移动"') do (
        set DriveU=%%h
    )
)
echo,%DriveU%
pause
复制代码

@echo off
for /f "tokens=2 delims==" %%a in ('wmic LogicalDisk where "DriveType='2'" get DeviceID /value') do (
    set DriveU=%%a
)
echo,%DriveU%
pause
复制代码

@echo off
for /f "delims=:" %%i in ('findstr /n "^:DynamicScript$" "%~f0"') do (
    more +%%i "%~f0" > "%temp%\GetU.vbs"
)
for /f %%a in ('cscript /nologo "%temp%\GetU.vbs"') do (
    set "DriveU=%%a"
)
echo,%DriveU%
pause
goto :eof

:DynamicScript
Set Fso = CreateObject("Scripting.FileSystemObject")
Set B = Fso.Drives

For Each A in B
    If A.DriveType = 1 Then
        aDisk = aDisk & A.DriveLetter & ": "
    End If
Next
aDisk = Replace(aDisk, "A: ","")
WScript.Echo aDisk
复制代码

@title 查看可移动盘个数及盘符(当我插的是两个U盘的时候)
@echo 1楼的代码无显示（去掉“Removable ”后显示一个：显示：m:）改为3楼的代码无显示
@echo off
for %%a in (c d e f g h i j k l m n o p q r s t u v w x y z) do (
  for /f %%h in ('fsutil fsinfo drivetype %%a:^|findstr "Removable 可移动"') do (
    set DriveU=%%h
  )
)
echo.%DriveU%
echo.&pause
@echo  6楼的代码
@echo off
for %%a in (c d e f g h i j k l m n o p q r s t u v w x y z) do (
for /f %%h in ('fsutil fsinfo drivetype %%a:^|findstr "可移动"') do (
echo.%%h
)
)
:: 方案一：fsutil 仅获得盘符
:: 显示：l:
:: 显示：m:
echo.&pause
@echo off
for %%a in (c d e f g h i j k l m n o p q r s t u v w x y z) do ( fsutil fsinfo drivetype %%a:|findstr "可移动" )
:: 显示：l: - 可移动驱动器
:: 显示：m: - 可移动驱动器
echo.&pause
复制代码

@echo off&title 查看可移动盘个数及盘符&for %%i in (c d e f g h i j k l m n o p q r s t u v w x y z) do fsutil fsinfo drivetype %%i:| find "可移动"
复制代码

@echo off&title 可同时打开多个移动盘&for %%i in (c d e f g h i j k l m n o p q r s t u v w x y z) do fsutil fsinfo drivetype %%i: | find "可移动">nul && start %%i:
复制代码

 
@echo off
for %%i in (Z Y X W V U T S R Q P O N M L K J I H G F E D C) do (
    if exist %%i:\nul (
        for /f "tokens=3" %%j in ('dir /-c %%i:\') do set freesize=%%j
        set last=%%i
        if not "!freesize!"=="0" goto last_drive
    )
)
goto :eof
:last_drive
explorer  %last%:\
复制代码

 
@echo off
title 设置U盘背景(dosz整理，只能用于第一个移动盘)
:start
cls
echo 请插入U盘...
ping -n 4 127.1>nul
for %%i in (c:,d:,e:,f:,g:,h:,i:,j:,k:,l:) do fsutil fsinfo drivetype %%i | find "可移动">nul && echo %%i>>dosz.txt
if not exist dosz.txt goto dd
for /f "tokens=*" %%a in (dosz.txt) do set upanfu=%%a
:shezhi
cls
echo.
set tupian=
set /p tupian=输入要设置为背景的图片路径并回车 (建议直接将图片拖拽到本窗口):
if exist %tupian% goto d
echo.
echo 图片不存在...或输入有误....
echo.
echo 建议直接将图片拖拽到本窗口...
echo.
echo 任意键返回....
pause>nul
goto shezhi
:d
if exist %upanfu%\1.jpg attrib -s -h -r -a %upanfu%\1.jpg
copy %tupian% %upanfu%\1.jpg>nul
if exist %upanfu%\desktop.ini attrib -s -h -r -a %upanfu%\desktop.ini
echo [ExtShellFolderViews]>%upanfu%\desktop.ini
echo [{BE098140-A513-11D0-A3A4-00C04FD706EC}]>>%upanfu%\desktop.ini
echo IconArea_Image=1.jpg>>%upanfu%\desktop.ini
attrib +h %upanfu%\desktop.ini
attrib +h %upanfu%\1.jpg
del dosz.txt /q
echo.
explorer  %upanfu%\
echo.
pause>nul
exit
:dd
echo.
echo 检测不到U盘..任意键返回....
pause>nul
goto start
复制代码

@ECHO OFF
for %%i in (c d e f g h i j k l m n o p q r s t u v w x y z) do (if exist %%i: (
if not exist "%%i:\System Volume Information" (echo %%i  is USB)))
PAUSE
复制代码

@echo off
::foxjl@bbs.bathome.net
setlocal enabledelayedexpansion
for /f "delims=\" %%i in ('fsutil fsinfo drives^|find /v ""') do (
	set var=%%i
	for /f "delims=" %%h in ('fsutil fsinfo drivetype !var:~-2!') do (
		echo %%h | find "移动">nul && echo %%i
		)
	)
pause
复制代码

@echo off
setlocal enabledelayedexpansion
wmic DiskDrive where "InterfaceType='USB'" 2>&1 |findstr "没有可用实例" >nul
if not errorlevel 1 (
	echo 没有找到U盘，请确认先插入U盘！
) else (
	for /f "skip=1" %%a in ('wmic DiskDrive where "InterfaceType='USB'" get DeviceID ^|findstr "."') do (
		set diskName=%%a
		set diskID=!diskName:~-1,1!
	)
	set diskName=Disk #!diskID!
	for /f "tokens=7 delims== " %%a in ('wmic path win32_LogicalDiskToPartition ^|findstr /c:"!diskName!"') do (set U=%%a)
	set U=!U:~1,2!
	echo 已找到U盘，盘符为 !U!
	rem 找到后可做后续操作。
) 
pause
复制代码