批处理之家 - Powered by Discuz! Board

标题: [文件操作] [已解决]批处理怎样根据两文件的版本高低或大小来决定要不要复制并覆盖原文件？ [打印本页]

作者: solan 时间: 2015-5-20 21:54 标题: [已解决]批处理怎样根据两文件的版本高低或大小来决定要不要复制并覆盖原文件？

本帖最后由 solan 于 2015-5-21 18:49 编辑

我的原意是这样的，如果不存在%AllUsersProfile%\A目录，就把%cd%\A整个文件夹和文件复制到%AllUsersProfile%，
如果存在，那么这个时候如果%AllUsersProfile%\A中没有1.exe文件，就彻底删除文件夹A，再把%cd%\A整个文件夹和文件复制到%AllUsersProfile%，
如果%AllUsersProfile%\A中存在1.exe文件，那么把它跟%cd%\A中的1.exe进行版本高低的比较：如果前者的版本低或同版本，就执行上面的复制；如果前者的版本高就不复制。
但是，我不会提取文件版本，只好比大小了，批处理如下：

if not exist "%AllUsersProfile%\A" (goto 11) else (if not exist "%AllUsersProfile%\A\1.exe" goto 22)
for %%1 in (%AllUsersProfile%\A\1.exe) do set wind=%%~z1
for %%1 in (%cd%\A\1.exe) do set snow=%%~z1
if "%wind% equ %snow%" goto 22
if "%wind% lss %snow%" goto 22
:11
xcopy /s/e/q/r/y "%cd%\A" "%AllUsersProfile%\A\"
:22
rmdir /s/q "%AllUsersProfile%\A" 
xcopy /s/e/q/r/y "%cd%\A" "%AllUsersProfile%\A\" 
pause
复制代码

但是这个代码不行，如果不存在%AllUsersProfile%\A目录倒能正常执行，一旦存在A\不管谁大小批处理立马闪退。后来我这样写，还是不行：

md "%AllUsersProfile%\A\"
if not exist "%AllUsersProfile%\A\1.exe" (goto 22) else (
for %%1 in (%AllUsersProfile%\A\1.exe) do set wind=%%~z1
for %%1 in (%cd%\A\1.exe) do set snow=%%~z1
if "%wind% equ %snow%" goto 22
if "%wind% lss %snow%" goto 22
if "%wind% gtr %snow%" goto end
:22
rmdir /s/q "%AllUsersProfile%\A" >nul 2>nul
xcopy /s/e/q/r/y "%cd%\A" "%AllUsersProfile%\A\" >nul 2>nul
:end
cls)
pause
复制代码

在此恳请哪位老大帮忙改下代码，最好是通过两文件的版本高低比较来写代码，xp和win7通用，先谢过了！！

作者: terse 时间: 2015-5-21 01:11

试试 replace

作者: apang 时间: 2015-5-21 11:08

@echo off
set "dstFile=%AllUsersProfile%\A\1.exe"
set "srcFile=%~dp0A\1.exe"

>$ echo fso = new ActiveXObject("Scripting.FileSystemObject")
>>$ echo v1 = fso.GetFileVersion("%dstFile:\=/%")
>>$ echo v1 = v1.replace(/\d+/g,function(s0){return s0-0+100000000})
>>$ echo v2 = fso.GetFileVersion("%srcFile:\=/%")
>>$ echo v2 = v2.replace(/\d+/g,function(s0){return s0-0+100000000})
>>$ echo WScript.Echo(v1 + " " + v2)

if exist "%AllUsersProfile%\A\" (
        if exist "%dstFile%" (
                for /f "tokens=1,2" %%1 in ('cscript -nologo -e:jscript $') do (
                        if "%%1" LEQ "%%2" call :copy
                )
        ) else (
                rd /s /q "%AllUsersProfile%\A\"
                call :copy
        )
) else call :copy
del $
pause & exit/b

:copy
xcopy /s /e /q /r /y "%~dp0A\*" "%AllUsersProfile%\A\"
复制代码

作者: terse 时间: 2015-5-21 13:07

@echo off
if exist "%AllUsersProfile%\A\" (
   if not exist "%AllUsersProfile%\A\1.exe" (
      rd /s /q "%AllUsersProfile%\A\"
      xcopy /e/q/r/y  "%cd%\A\" "%AllUsersProfile%\A\" 
   ) else  replace /u "%cd%\A\1.exe" "%AllUsersProfile%\A\"
) else xcopy /e/q/r/y "%cd%\A" "%AllUsersProfile%\A\" 
pause
复制代码

作者: apang 时间: 2015-5-21 15:02

回复 5# solan

为什么要把第7行和第9行改成replnx_flexce？

作者: solan 时间: 2015-5-21 15:24

哦，替换错了，我在试试，谢谢

作者: solan 时间: 2015-5-21 15:56

本帖最后由 solan 于 2015-5-21 16:20 编辑

大哥，你太有才了，提取版本的写法是很难的哦，你能写出来太厉害了，辛苦你再完善一下

作者: apang 时间: 2015-5-21 18:17

"清除不干净" 是个什么意思？xcopy复制文件时只能覆盖，不能清除

作者: solan 时间: 2015-5-21 18:48

可以结贴了，谢谢各位！！！

欢迎光临批处理之家 (http://bathome.net./)