批处理之家 - Powered by Discuz! Board

标题: [文件操作] [已解决]批处理复制当前目录下任意一个TXT内容到将剪切板 [打印本页]

作者: ruoru376 时间: 2015-7-17 01:01 标题: [已解决]批处理复制当前目录下任意一个TXT内容到将剪切板

目录下有很多TXT文件，需要复制当前目录下任意一个【或者第一个】TXT内容到将剪切板，并把复制后的文件移动到文件夹“完成”。
我会复制，但是不知道怎么获取任意一个任意一个【或者第一个】TXT，希望各位大神给予帮助，谢谢！了！

作者: bailong360 时间: 2015-7-17 09:14

本帖最后由 bailong360 于 2015-7-17 10:06 编辑

@echo off
md 完成 2>nul
for /f "delims=" %%i in ('dir /a-d /b *.txt') do (
    winclip -c "%%i"
    move "%%i" ".\完成\"
    exit
)
复制代码

作者: ruoru376 时间: 2015-7-17 10:05

回复 2# bailong360
你好！测试了一下！效果不对啊！
你的代码效果是: 复制了 bat 代码。移动所有TXT了；你能不能帮我再看看谢谢了！

作者: bailong360 时间: 2015-7-17 10:06

回复 3# ruoru376
已修改

作者: flyinnet9 时间: 2015-7-17 10:39

本帖最后由 flyinnet9 于 2015-7-17 10:52 编辑

随机复制用全部代码
只复制第一个，去掉4-7行，并把第八行 “^|more +%ra%”去掉

@echo off
setlocal enabledelayedexpansion
md 完成 2>nul
for /f %%a in ('dir /a-d /b *.txt ^|find /v "" /c') do (
set row=%%a
set /a ra=%random%%%%row%
)
for /f %%b in ('dir /a-d /b *.txt ^|more +%ra%') do (
set /a line+=1
if !line!==1 set f=%%b & goto end
)
:end
winclip -c "%f%"
move "%f%" ".\完成"
复制代码

作者: ruoru376 时间: 2015-7-17 10:55

回复 5# flyinnet9
你好帮我在看看吧。不知道是什么问题：
winclip不是内部或外部命令

作者: ruoru376 时间: 2015-7-17 11:03

回复 5# flyinnet9
无法复制其他的都可以！我在研究研究一下吧！谢谢了

作者: flyinnet9 时间: 2015-7-17 11:04

本帖最后由 flyinnet9 于 2015-7-17 11:08 编辑

去网上下一个winclip，如果不需要到剪贴板，把这行去掉

请使用蓝色“复制代码”，估计是你复制代码时多了或少了什么东西，我这边测试没问题，除了winclip

或者去掉第一行，结果发上来看看

作者: tigerpower 时间: 2015-7-17 11:08

@chcp 936
@md 完成 2>nul
@for %%i in (*.txt) do (clip<"%%i" && @move "%%i" 完成 && @pause && exit)
复制代码

作者: ruoru376 时间: 2015-7-17 11:13

本帖最后由 ruoru376 于 2015-7-17 11:14 编辑

回复 8# flyinnet9
非常感谢！系统上面有的：winclip -c "%f%"换成下面的代码就可以了！

copy /y "%~pd0\clip.exe" "C:\Windows\System32"
clip < "%~pd0\%f%"

作者: ruoru376 时间: 2015-7-17 11:18

回复 9# tigerpower
代码很简洁，测试，效果不错！谢谢！

作者: pcl_test 时间: 2015-7-17 15:24

@echo off&setlocal enabledelayedexpansion
for %%a in (*.txt) do (set /a n+=1&set "#!n!=%%~nxa")
set /a f=%random%%%!n!+1
type "!#%f%!"|mshta "javascript:clipboardData.setData('text',new ActiveXObject('Scripting.FileSystemObject').GetStandardStream(0).ReadAll());close()"
echo;已复制[!#%f%!]的内容到剪贴板&ping -n 2 0 >nul& exit
复制代码

欢迎光临批处理之家 (http://bathome.net./)