@echo off
:repeat
set /p input=请输入: 
if "%input:~2,1%" equ "" goto repeat
if "%input:~10,1%" neq "" goto repeat
for /f "delims=abcdefghijklmnopqrstuvwxyz" %%a in ("%input%") do (
  if "%%a" neq "" goto repeat
)
pause
复制代码

@echo off
:repeat
set/p input=请输入: 
if "%input:~2,1%" equ "" goto repeat
if "%input:~10,1%" neq "" goto repeat
echo.%input%|findstr/i "^[a-z]*$">nul2>nul||goto repeat
pause
复制代码

@echo off
rem 限制输入3位至10位字母
set LenMin=3
set LenMax=10
set AllLetter=a b c d e f g h i j k l m n o p q r s t u v w x y z

:GetInput
set input=
set /p "input=请输入3至10位字母："
if "%input%" neq "" (
  if "%input:~2,1%" equ "" (
    echo 不足%LenMin%位
    goto :GetInput
  ) else if "%input:~10,1%" neq "" (
    echo 多于%LenMax%位
    goto :GetInput
  )
) else (
  echo 输入不能为空
  goto :GetInput
)
setlocal enabledelayedexpansion
for %%a in (%AllLetter%) do (
  set input=!input:%%a=!
  if "!input!" equ "" (
    goto :RightInput
  )
)
if "!input!" neq "" (
  echo 只能输入纯字母[a-zA-Z]
  endlocal
  goto :GetInput
)

:RightInput
echo 恭喜输入正确
pause
复制代码

@echo off&setlocal enabledelayedexpansion
:repeat
set /p input=请输入: 
echo !input!>%temp%\#tmp#
findstr /xi "[a-z][a-z][a-z] [a-z][a-z][a-z][a-z] [a-z][a-z][a-z][a-z][a-z] [a-z][a-z][a-z][a-z][a-z][a-z] [a-z][a-z][a-z][a-z][a-z][a-z][a-z] [a-z][a-z][a-z][a-z][a-z][a-z][a-z][a-z] [a-z][a-z][a-z][a-z][a-z][a-z][a-z][a-z][a-z] [a-z][a-z][a-z][a-z][a-z][a-z][a-z][a-z][a-z][a-z]" %temp%\#tmp# >nul || goto repeat
pause
复制代码

@echo off
:repeat
set /p input=请输入: 
(call set/p="%%input%%"<nul&echo.)>%temp%\#tmp#
findstr /xi "[a-z][a-z][a-z] [a-z][a-z][a-z][a-z] [a-z][a-z][a-z][a-z][a-z] [a-z][a-z][a-z][a-z][a-z][a-z] [a-z][a-z][a-z][a-z][a-z][a-z][a-z] [a-z][a-z][a-z][a-z][a-z][a-z][a-z][a-z] [a-z][a-z][a-z][a-z][a-z][a-z][a-z][a-z][a-z] [a-z][a-z][a-z][a-z][a-z][a-z][a-z][a-z][a-z][a-z]" %temp%\#tmp# >nul || goto repeat
pause
复制代码

@set /p s=Plz input:
@mshta javascript:alert(/^^[a-z]{3,10}$/i.test("%s%"));close()
复制代码

@echo off
set /p input=请输入：
echo.%input%>1.temp
for /r %%a in (*.temp) do set /a a=%%~za-2
if %a% lss 3 echo 输入字符少于3个&goto :end 
if %a% gtr 10 echo 输入字符多于10个&goto :end
echo.%input%|findstr "[^a-z]">nul&&echo 输入字符中有非字母字符&&goto end
echo 输入字符符合要求
:end
del /q 1.temp&pause>nul
复制代码

@echo off&set "f=findstr .....|findstr /v ............."
:loop
echo.&set a=a&set var=&set /p var= 请输入3至10位英文字母 &cls
echo."%var%"|%f%|findstr "^\"[a-zA-Z]*\"$">nul&&set "a="
if defined a (echo  输入错误) else echo  %var% 正确
goto loop
复制代码

请输入3至10位字母：134
已经达到最大的 setlocal 递归层
只能输入纯字母[a-zA-Z]
请输入3至10位字母：
复制代码

请输入3至10位字母：134
已经达到最大的 setlocal 递归层。
只能输入纯字母[a-zA-Z]
请输入3至10位字母：135
已经达到最大的 setlocal 递归层。
只能输入纯字母[a-zA-Z]
请输入3至10位字母：136
已经达到最大的 setlocal 递归层。
只能输入纯字母[a-zA-Z]
请输入3至10位字母：
复制代码

@echo off
set /p str=请输入3到10个字母：
set var=%str%
set n=0
:begin
set a=%str:~0,1%
set /a n+=1
set str=%str:~1%
if not "%str%"=="" goto begin
if %n% lss 3 echo 字符数不符&&goto eof
if %n% gtr 10 echo 字符数不符&&goto eof
echo %var%|findstr "[^a-z]">nul&&echo 输入的字符不完全是字母&&goto eof
echo 输入正确！
:eof
pause
复制代码

@echo off&setlocal enabledelayedexpansion
:begin
set n=0
:rep
set/a n+=1
set /p str=输入3-10个字母：
for /l %%a in (0,1,10) do (
        set one=!str:~%%a,1!
        if not defined one if %%a geq 3 (goto :ok) else (echo 不足3个&goto :rep)
        if !one! lss a echo 有非法字符&goto :rep
        if !one! gtr z echo 有中文字符&goto :rep
)
echo 超过10个&goto :rep
:ok
echo 你输入了%n%次终于搞对一次了：!str!
echo.
echo 再来!
goto :begin
复制代码