Board logo

标题: [游戏娱乐] 3D 环涡 torus vortex [打印本页]
作者: aa77dd@163.com    时间: 2016-9-26 15:28     标题: 3D 环涡 torus vortex

本帖最后由 aa77dd@163.com 于 2016-9-27 22:00 编辑



运行代码时, 请将窗口设置成 点阵 3 X 5 像素字体

20160927_214945 修正画法

  1. @echo off & setlocal enabledelayedexpansion & chcp 936 & title 3D Torus Vortex

  2. 

  3. set "Path=%SystemRoot%\system32" & for /f "delims==" %%a in ('set') do if /i "%%a" neq "Path" set "%%a="

  4. set "SIN=(t-t*t/1875*t/320000+t*t/1875*t/15625*t/16000*t/2560000-t*t/1875*t/15360*t/15625*t/15625*t/16000*t/44800000)"

  5. set "COS=(10000-t*t/20000+t*t/1875*t/15625*t/819200-t*t/1875*t/15360*t/15625*t/15625*t/10240000+t*t/1875*t/15360*t/15625*t/15625*t/16000*t/15625*t/229376000)"

  6. set /a "ZM=10000, p=31416, p2=62832, pn2=-62832, p#2=15708, p3#2=47124, p3#2_=p3#2-1, DEG=31416/180"

  7. 

  8. set /a "Cols=wid=330, lines=hei=130, lines_plus_1=lines+1"

  9. mode !Cols!,!lines_plus_1!

  10. 

  11. set "TAB=	" & for /F %%a in ('"prompt $h&for %%b in (1) do rem"')do Set "BS=%%a"

  12. set /a "buffwid = wid, linesWantBackAbove = hei - 1 + 1, cntBS = 2 + (buffwid + 7) / 8 * linesWantBackAbove"

  13. set "BSs=" & for /L %%a in (1 1 !cntBS!) do set "BSs=!BSs!%BS%"

  14. set "aLineBS=" & for /L %%a in (1 1 !wid!) do set "aLineBS=!aLineBS!%BS%"

  15. 

  16. set "LN0=" & for /L %%C in (1 1 !Cols!) do set "LN0= !LN0!"

  17. for /L %%L in (1 1 !lines!) do set "LN%%L=!LN0!"

  18. 

  19. set /a "pixel_h=5, pixel_w=3" & rem 字体像素高宽比

  20. rem zscr 屏幕 Z 轴坐标, zeye 视点 Z 轴坐标

  21. set /a "XC = Cols/2, YC = lines/2, zscr = 128, zeye = 400, zs2e=zscr-zeye"

  22. 

  23. set /a "R1 = 68, r2 = 60, TH1 = 0, th2 = 0, cntRings=120, cntRings_1=cntRings-1, cntDotPerRing=20, cntDotPerRing_1=cntDotPerRing-1"

  24. set /a "sumDots=cntDotPerRing*cntRings"

  25. set /a "dth2base=(P2+P2/cntRings)/cntDotPerRing, offsClose=p2-(dth2base*cntDotPerRing-p2)*cntRings"

  26. set "offsClose=!offsClose!/!sumDots!"

  27. set /a "dTH1base=p2/cntRings, offsCloseBigCircle=p2-dTH1base*cntRings"

  28. set "offsCloseBigCircle=!offsCloseBigCircle!/!cntRings!"

  29. set /a "Z_cut_ZM=999*ZM" & rem 与 xoy 平面平行的切割平面, 将前部切去, 此值足够大时无切割效果

  30. 

  31. for /l %%i in (0 1 !cntRings_1!) do (

  32. 

  33.     for /l %%j in (0 1 !cntDotPerRing_1!) do (

  34. 

  35.         set /a "TH1=%%i*dTH1base+ %%i * %offsCloseBigCircle%, TH1 %%= p2, TH1 += TH1>>31&p2, t=TH1, s1=(t-p#2^t-p3#2)>>31, s3=p3#2_-t>>31, t=(-t&s1)+(t&~s1)+(p&s1)+(pn2&s3), SIN_TH1=%SIN%, t=%COS%, COS_TH1=(-t&s1)+(t&~s1)"

  36. 

  37.         set /a "t=%%i*cntDotPerRing+%%j,th2=t*dth2base+t*%offsClose%, th2 %%= p2, th2 += th2>>31&p2, t=th2, s1=(t-p#2^t-p3#2)>>31, s3=p3#2_-t>>31, t=(-t&s1)+(t&~s1)+(p&s1)+(pn2&s3), SIN_th2=%SIN%, t=%COS%, COS_th2=(-t&s1)+(t&~s1)"

  38. 

  39.         title 3D Torus Vortex  %%i/!cntRings_1! %%j/!cntDotPerRing_1!  TH1: !TH1! th2: !th2!

  40. 

  41.         set /a "z_ZM=(R1*ZM + r2*COS_th2)/ZM * SIN_TH1, z_t2eye_ZM=z_ZM -zeye*ZM, x=XC + (R1*ZM + r2*COS_th2)/ZM * COS_TH1 *zs2e* pixel_h /(z_t2eye_ZM * pixel_w), y=YC + r2 * SIN_th2 *zs2e/z_t2eye_ZM, inScr=(x-0^x-wid)&(y-0^y-hei)"

  42. 

  43.         set /a "inner=(th2-p#2^th2-p3#2)" & rem 到 y 轴距离 < 大圆半径 R

  44. 

  45.         if !z_ZM! LSS !Z_cut_ZM! (

  46. 

  47.             set /a "ind=x+1, lenL=ind-1"

  48.             for /f "tokens=1-3" %%a in ("!lenL! !ind! !y!") do (

  49.                 if !TH1! LSS !p! (

  50.                     if !inner! LSS 0 (  set "LN%%c=!LN%%c:~0,%%a!#!LN%%c:~%%b!"

  51.                     ) else (            set "LN%%c=!LN%%c:~0,%%a!o!LN%%c:~%%b!"

  52.                     )

  53.                 ) else (

  54.                     if !inner! LSS 0 (  rem set "LN%%c=!LN%%c:~0,%%a!*!LN%%c:~%%b!" & 消隐内孔后半部分

  55.                     ) else (            set "LN%%c=!LN%%c:~0,%%a!.!LN%%c:~%%b!"

  56.                     )

  57.                 )

  58.             )

  59.         )

  60. 

  61.         <nul set /p "=!aLineBS!" & (2>nul echo;%TAB%!BSs!) & <nul set /p "=%BS%"

  62.         for /L %%d in (1 1 !lines!) do <nul set /p "=%BS%!LN%%d!"

  63.     )

  64. )

  65. >nul pause

  66. exit
复制代码
523066680 的画法

  1. @echo off & setlocal enabledelayedexpansion & chcp 936 & title 3D Torus Vortex

  2. 

  3. set "Path=%SystemRoot%\system32" & for /f "delims==" %%a in ('set') do if /i "%%a" neq "Path" set "%%a="

  4. 

  5. set "SIN=(t-t*t/1875*t/320000+t*t/1875*t/15625*t/16000*t/2560000-t*t/1875*t/15360*t/15625*t/15625*t/16000*t/44800000)"

  6. set "COS=(10000-t*t/20000+t*t/1875*t/15625*t/819200-t*t/1875*t/15360*t/15625*t/15625*t/10240000+t*t/1875*t/15360*t/15625*t/15625*t/16000*t/15625*t/229376000)"

  7. set /a "ZM=10000, p=31416, p2=62832, pn2=-62832, p#2=15708, p3#2=47124, p3#2_=p3#2-1, DEG=31416/180"

  8. 

  9. set /a "Cols=wid=330, lines=hei=130, lines_plus_1=lines+1"

  10. mode !Cols!,!lines_plus_1!

  11. 

  12. set "TAB=	" & for /F %%a in ('"prompt $h&for %%b in (1) do rem"')do Set "BS=%%a"

  13. set /a "buffwid = wid, linesWantBackAbove = hei - 1 + 1, cntBS = 2 + (buffwid + 7) / 8 * linesWantBackAbove"

  14. set "BSs=" & for /L %%a in (1 1 !cntBS!) do set "BSs=!BSs!%BS%"

  15. set "aLineBS=" & for /L %%a in (1 1 !wid!) do set "aLineBS=!aLineBS!%BS%"

  16. 

  17. set "LN0=" & for /L %%C in (1 1 !Cols!) do set "LN0= !LN0!"

  18. for /L %%L in (1 1 !lines!) do set "LN%%L=!LN0!"

  19. 

  20. 

  21. set /a "pixel_h=5, pixel_w=3" & rem 字体像素高宽比

  22. REM zscr 屏幕 Z 轴坐标, zeye 视点 Z 轴坐标

  23. set /a "XC = Cols/2, YC = lines/2, zscr = 108, zeye = 400, zs2e=zscr-zeye"

  24. 

  25. set /a "R1 = 64, r2 = 44, mp = 10, np = 90, Z_cut_ZM=999*ZM"  & rem Z_cut_ZM 是 平行于 xOy 平面的切割平面, 值够大时不会切割

  26. 

  27. for /l %%m in (1 1 !mp!) do (

  28. 

  29.     for /l %%n in (1 1 !np!) do (

  30. 

  31.             set /a "TH1=p2* %%m /mp+p2*%%n/np, TH1 %%= p2, TH1 += TH1>>31&p2, t=TH1, s1=(t-p#2^t-p3#2)>>31, s3=p3#2_-t>>31, t=(-t&s1)+(t&~s1)+(p&s1)+(pn2&s3), SIN_TH1=%SIN%, t=%COS%, COS_TH1=(-t&s1)+(t&~s1)"

  32. 

  33.             set /a "th2=p2*%%n/np, th2 %%= p2, th2 += th2>>31&p2, t=th2, s1=(t-p#2^t-p3#2)>>31, s3=p3#2_-t>>31, t=(-t&s1)+(t&~s1)+(p&s1)+(pn2&s3), SIN_th2=%SIN%, t=%COS%, COS_th2=(-t&s1)+(t&~s1)"

  34. 

  35.             title 3D Torus Vortex  %%m / !mp! TH1:!TH1! th2:!th2!

  36. 

  37.             set /a "z_ZM=(R1*ZM + r2*COS_th2)/ZM * SIN_TH1, z_t2eye_ZM=z_ZM -zeye*ZM, x=XC + (R1*ZM + r2*COS_th2)/ZM * COS_TH1 *zs2e* pixel_h /(z_t2eye_ZM * pixel_w), y=YC + r2 * SIN_th2 *zs2e/z_t2eye_ZM"

  38. 

  39.             set /a "inner=(th2-p#2^th2-p3#2)" & rem 到 y 轴距离 < 大圆半径 R

  40. 

  41.             if !z_ZM! LSS !Z_cut_ZM! (

  42. 

  43.                     set /a "ind=x+1, lenL=ind-1" & rem  lenR=Cols-ind"

  44.                     for /f "tokens=1-3" %%a in ("!lenL! !ind! !y!") do (

  45.                         if !TH1! LSS !p! (

  46.                             if !inner! LSS 0 (  set "LN%%c=!LN%%c:~0,%%a!#!LN%%c:~%%b!"

  47.                             ) else (            set "LN%%c=!LN%%c:~0,%%a!o!LN%%c:~%%b!"

  48.                             )

  49.                         ) else (

  50.                             if !inner! LSS 0 (  set "LN%%c=!LN%%c:~0,%%a!*!LN%%c:~%%b!"

  51.                             ) else (            set "LN%%c=!LN%%c:~0,%%a!.!LN%%c:~%%b!"

  52.                             )

  53.                         )

  54.                     )

  55.             )

  56. 

  57.             <nul set /p "=!aLineBS!" & (2>nul echo;%TAB%!BSs!) & <nul set /p "=%BS%"

  58.             for /L %%d in (1 1 !lines!) do <nul set /p "=%BS%!LN%%d!"

  59.     )

  60. )

  61. >nul pause

  62. exit
复制代码
作者: CrLf    时间: 2016-9-26 20:29

我去，牛逼
作者: CrLf    时间: 2016-9-26 20:33

少年，批处理的明天靠你了！
作者: 艾客    时间: 2016-12-12 17:25

可以透漏下什么样的学习路径能有机会到这个境界？



欢迎光临 批处理之家 (http://bathome.net./) Powered by Discuz! 7.2