批处理之家 - Powered by Discuz! Board

标题: [文本处理] 【已解决】批处理如何以指定字符分割未知长度的字符串 [打印本页]

作者: zhushjbathhome 时间: 2009-4-20 19:43 标题: 【已解决】批处理如何以指定字符分割未知长度的字符串

本帖最后由 pcl_test 于 2016-9-29 00:20 编辑

我已经知道使用for能分割并提取字符串里面的元素：
例子：
@echo off
set str=c d e f g h i j k l m n o p q r s t u v w x y z
echo 当前硬盘的分区有：
for %%i in (%str%) do if exist %%i: echo %%i:
pause
这里使用了for语句默认使用空格作为分割符号。

如果分割符不是空格的话，就无法使用上面的for来分割了：
set str=c\d\e\f\g\h\i\j\k\l\m\n\o\p\q\r\s\t\u\v\w\x\y\z
这时候可以使用for /F 分割字符串，但是不同的是，必须使用"tokens=1-24"指定分割完的部分，如果不指定，默认会返回第一个分割完的部分。

问题是：如果不知道字符串里面有多少个分割部分，怎么把分割部分逐一显示出来呢？

[ 本帖最后由 zhushjbathhome 于 2009-4-22 20:28 编辑 ]

作者: 随风 时间: 2009-4-20 20:19

for 默认的分割符除了空格还有逗号
你的问题至少有2个解决办法
第一、若确定被分割的部分没有空格和逗号，则可以先把\替换为空格，再for即可。
第二、递归
:

@echo off
set str=c\d\e\f\g\h\i\j\k\l\m\n\o\p\q\r\s\t\u\v\w\x\y\z
call :loop "%str%"
pause
:loop
for /f "tokens=1* delims=\" %%a in ("%~1") do (
   echo %%a
   if not "%%b"=="" call :loop "%%b"
)
goto :EOF
复制代码

作者: batman 时间: 2009-4-21 09:35

如果有分隔的字符串在31列内，还可采用以下方法：

@echo off
for /l %%a in (1,1,31) do call,set "str=%%str%%-%%a"
:lp
set /a n+=1
for /f "tokens=%n% delims=-" %%a in ("%str%") do if "%%a" neq "" echo %%a&goto lp
pause>nul
复制代码

作者: zhushjbathhome 时间: 2009-4-21 19:34

长知识了，3Q！

@echo off
set "str=c\d\e\f\g\h\i\j\k\l\m\n\o\p\q\r\s\t\u\v\w\x\y\z"
:lp
set /a n+=1
for /f "tokens=%n% delims=\" %%a in ("%str%") do (
if "%%a" neq "" (
echo %%a>>log.txt
goto lp
)
)
复制代码

感觉4楼的方法比较简单。

欢迎光临批处理之家 (http://bathome.net./)