@echo off&setlocal enabledelayedexpansion
set aav=abcdefghijklmnopqrstuvwxyz不够的话文字也可以ａｂｃｄｅｆｇｈｉｊｋｌｍｎｏｐｑｒｓｔｕｖｗｘｙｚＡＢＣＤＥＦＧＨＩＪＫＬＭＮＯＰＱＲＳＴＵＶＷＸＹＺ
set 最大长度=80
for /l %%a in (0,1,%最大长度%) do (
	set len!aav:~%%a,1!=%%a
	set vva=!aav:~%%a,1!!vva!
)
::前面初始定义一次，后面可以任意使用，只要两个set 就可以取得字符串长度。
::但前提是，你要知道需计算的字符串中，最长字符串的长度。
::效率可想而知了！

set str1=12345678
set str2=abcdefghijklmn

set var1=!str1!!vva!
set var2=!str2!!vva!
set/a var1=len!var1:~%最大长度%,1!,var2=len!var2:~%最大长度%,1!
echo !str1! 长度为：!var1!
echo !str2! 长度为：!var2!
pause
复制代码

@echo off
set "str=Hello, bat! %%<^_^>%%""
setlocal enabledelayedexpansion
set str2=!str:y=-!
set str2=!str2:n=-!
set str2=!str2:a=-!
echo;!str2!n>str.tmp
goto:next 用for解析命令输出会降低效率，干脆用临时文件
for /f %%a in ('
    xcopy /-y %SystemRoot%\notepad.exe %SystemRoot%\explorer.exe ^<str.tmp ^| find /i /c "%SystemRoot%\explorer.exe"
') do set strlen=%%a-1
:next
xcopy /-y %SystemRoot%\notepad.exe %SystemRoot%\explorer.exe <str.tmp | find /i /c "%SystemRoot%\explorer.exe" > strlen.tmp
set /p strlen=<strlen.tmp
set /a strlen-=1
echo;!str!&echo/&echo 上面的字符串长度为：!strlen!
del str.tmp strlen.tmp
pause
复制代码

@echo off
set "var=12345678"
set "str=%var%fedcba9876543210"
set /a max=0x%str:~15,1%
echo %var%  有 %max% 位
pause
复制代码

@echo off
set "str=例如：Hello, bat! %%<^_^>%%""
setlocal enabledelayedexpansion
set str2=!str:y=-!
set str2=!str2:n=-!
set str2=!str2:a=-!
for /f %%a in ('
    set str2^|xcopy /-y %SystemRoot%\notepad.exe %SystemRoot%\explorer.exe ^| find /i /c "%SystemRoot%\explorer.exe"
') do set /a strlen=%%a-9
echo;!str!&echo/&echo 上面的字符串长度为：!strlen!
pause
复制代码

@echo off&setlocal enabledelayedexpansion
set aav=abcdefghijklmnopqrstuvwxyz不够的话文字也可以ａｂｃｄｅｆｇｈｉｊｋｌｍｎｏｐｑｒｓｔｕｖｗｘｙｚＡＢＣＤＥＦＧＨＩＪＫＬＭＮＯＰＱＲＳＴＵＶＷＸＹＺ
set 最大长度=80
for /l %%a in (0,1,%最大长度%) do set /a len!aav:~%%a,1!=最大长度-%%a
::前面初始定义一次，后面可以任意使用，只要两个set 就可以取得字符串长度。
::但前提是，你要知道需计算的字符串中，最长字符串的长度。
::效率可想而知了！

set str1=12345678
set str2=abcdefghijklmn

set var1=!str1!!aav!
set var2=!str2!!aav!
set/a var1=len!var1:~%最大长度%,1!,var2=len!var2:~%最大长度%,1!
echo !str1! 长度为：!var1!
echo !str2! 长度为：!var2!
pause
复制代码

@echo off
setlocal enabledelayedexpansion
set str=cn-dos.net
set st2=Str%str%11111111111111111111111111111111111111111111111111111111111111111111111111111111
set "st2=%st2:~0,83%"
set n=!st2:Str%str%=-0!
set /a n=80 %n:1=-1%
echo,%n%
pause
::个数可以是0 范围是0~80 的普通字符串。
复制代码

@echo off
setlocal enabledelayedexpansion
set Var=123456789
set a=512 256 128 64 32 16 8 4 2 1
if defined Var (
    set n=1
    for %%i in (%a%) do (
        if not "!Var:~%%i!"=="" (
            set Var=!Var:~%%i!
            set /a n+=%%i
        )
    )
    echo,!n!
) else (
    echo,Var is not defined
)
pause
复制代码

@echo off
:[Loop] //测试代码 备注》调用子过程的形参须是变量名
set "str=" &set/p str="输入一个字符串获取其长度："
if not defined str exit/b
(call :strLen str sL)
echo,长度=%sL%
goto[Loop]

:: 分享计算字符串长度的经典代码如下》
::      string [in]  - variable name containing the string being measured for length
::      len [out] - variable to be used to return the string length
:: Many thanks to 'sowgtsoi', but also 'jeb' and 'amel27' dostips forum users helped making this short and efficient
:: Created 20081122，changed 20101116，source https://www.dostips.com
:strLen string len -- returns the length of a string
(   setlocal enabledelayedexpansion
    set "str=a!%~1!" &rem keep the a up front to ensure we get the length and not the upper bound，it also avoids trouble in case of empty string
    set "len=0"
    for /l %%a in (12,-1,0) do (
        set /a "len|=1<<%%a"
        for %%b in (!len!) do if "!str:~%%b,1!"=="" set /a "len&=~1<<%%a"
    )
)
( endlocal & rem return values
    if "%~2" neq "" set /a %~2=%len%
)
exit /b
复制代码