Board logo

标题: [网络连接] [新人求助]一键设定IP如何写批处理代码？ [打印本页]
作者: chming    时间: 2009-7-18 09:41     标题: [新人求助]一键设定IP如何写批处理代码？

我在网上找到这样的一段代码：
  1.  

  2. @echo off

  3. cls

  4. 

  5. :ipw

  6. cls

  7. echo. IP:

  8. set /p IP=   请输入 IP:

  9. echo. 掩码：

  10. set /p MASK=    请输入 掩码：

  11. echo.  网关：

  12. set /p GATEWAY=  请输入 网关：

  13. echo.

  14. echo        开始设置IP、掩码、网关地址

  15. netsh interface ip set address "本地连接" static %IP% %Mask% %GATEWAY% 1

  16. echo.    设置完成，任意键其他操作。

  17. pause>nul

  18. goto ipw
复制代码


这个是手动设置，我要的用的两个不同的IP段，但用1台电脑来设置设备，这样手动就很麻烦和费时间了

我想要的功能是能够一键设定指定IP，下面我做了功能选项，希望高手帮我编写功能代码，谢谢

  1.  

  2. @echo off

  3. cls

  4. :start

  5. cls

  6. echo.

  7. echo.     ╔┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉╗

  8. echo.     ┋  ─────────────────────────  ┋

  9. echo.     ┋    【A】IP:192.168.1.10      【B】IP:10.192.16.10    ┋

  10. echo.     ┋  ─────────────────────────  ┋

  11. echo.     ┋  ─────────────────────────  ┋

  12. echo.     ┋    【C】查看IP设置           【Z】退出程序           ┋

  13. echo.     ┋  ─────────────────────────  ┋

  14. echo.     ╚┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉╝

  15. set choice=

  16. set /p choice=              请输入选项（Enter确认）:

  17. IF NOT "%Choice%"=="" SET Choice=%Choice:~0,1%

  18. if /i "%choice%"=="A" goto ipw1

  19. if /i "%choice%"=="B" goto ipw2

  20. if /i "%choice%"=="C" goto ck

  21. if /i "%choice%"=="Z" goto end
复制代码


ipw1实现一键设置成IP：192.168.1.10，掩码：255.255.255.0，网关：192.168.1.1
ipw2实现一键设置成IP：10.192.16.10，掩码：255.255.255.0，网关：10.192.16.10

谢谢帮忙
作者: chming    时间: 2009-7-18 09:43

顺便再问下，要想设置能自动获取IP，代码又如何写？再次感谢
作者: switchling    时间: 2009-7-18 12:16

@echo off
cls
:start
cls
echo.
echo.     ╔┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉╗
echo.     ┋  ─────────────────────────  ┋
echo.     ┋    【A】IP:192.168.1.10      【B】IP:10.192.16.10    ┋
echo.     ┋  ─────────────────────────  ┋
echo.     ┋  ─────────────────────────  ┋
echo.     ┋                【D】设置自动获取IP                          ┋
echo.     ┋  ─────────────────────────  ┋
echo.     ┋    【C】查看IP设置           【Z】退出程序           ┋
echo.     ┋  ─────────────────────────  ┋
echo.     ╚┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉╝
set choice=
set /p choice=              请输入选项（Enter确认）:
IF NOT "%Choice%"=="" SET Choice=%Choice:~0,1%
if /i "%choice%"=="A" goto ipw1
if /i "%choice%"=="B" goto ipw2
if /i "%choice%"=="C" goto ck
if /i "%choice%"=="Z" goto end
if /i "%choice%"=="D" goto dhcp

:ipw1
netsh interface ip set address "本地连接" static 192.168.1.10 255.255.255.0 192.168.1.1 1
echo.
echo.    设置完成，任意键其他操作。
pause >nul
goto start

:ipw2
netsh interface ip set address "本地连接" static 10.192.16.10 255.255.255.0 10.192.16.10 1
echo.
echo.    设置完成，任意键其他操作。
pause >nul
goto start

:ck
@ipconfig /all
pause >nul
goto start

:dhcp
netsh interface ip set address "本地连接"  dhcp >nul
echo.
echo.    设置完成，任意键其他操作。
pause >nul
goto start

:end
exit



你看这个成吗？
作者: chming    时间: 2009-7-19 09:45

自己顶起，寻求帮助，希望能见到大侠，呵呵
作者: keen    时间: 2009-7-19 17:44     标题: 回复 4楼 的帖子

你觉得三楼的代码不行吗？你有没有试用一下3楼的代码？



欢迎光临 批处理之家 (http://bathome.net./) Powered by Discuz! 7.2