批处理之家 - Powered by Discuz! Board

标题: 支付宝20求批处理取本机ip地址最后位做为变量修改文件内容 [打印本页]

作者: kissn 时间: 2019-8-27 22:18 标题: 支付宝20求批处理取本机ip地址最后位做为变量修改文件内容

这个是取本机ip地址最后位做为变量并查找指定目录下ftp.txt内的 /upload，在后面加上/得到的变量数值使该行结果为cd /upload/变量值/

@echo off
for /f tokens^=1^,2^ delims^=^"^" %%a in ('wmic nicconfig get IPAddress /value ^| findstr /i "IPAddress=[^]"') do (set "ip=%%b")
for /f "tokens=4 delims=." %%a in ("%ip%") do set ip=%%~a
echo,%ip%>E:\ip.txt
 
set IPFile=E:\IP.txt
 
set IniFile=E:\ftp.txt
 
set /p ServerIP=<"%IPFile%"
 
(for /f "delims=" %%a in ('type "%IniFile%"') do (
    echo %%a|findstr /i "^serverip=" >nul && (
        echo serverip=%ServerIP%
    ) || (
        echo %%a
    )
))>tmp_Config
move /y tmp_Config "%IniFile%" >nul


pause
复制代码

以下是ftp.txt 内文件内容：

open 192.168.1.169 9999
2
2
lcd D:\pt
cd /upload
mput *.txt
prompt on
bye
quit
open 192.168.1.169 8888
1
1
prompt off
lcd D:\pt
cd /pt
mget *.txt
close
复制代码

作者: flashercs 时间: 2019-8-27 22:38

本帖最后由 flashercs 于 2019-8-27 22:44 编辑

@echo off
for /f tokens^=1^,2^ delims^=^"^" %%a in ('wmic nicconfig get IPAddress /value ^| findstr /i "IPAddress=[^]"') do (set "ip=%%b")
for /f "tokens=4 delims=." %%a in ("%ip%") do set ip=%%~a
echo,%ip%>E:\ip.txt
 
set IPFile=E:\IP.txt
 
set IniFile=E:\ftp.txt
 
set /p ServerIP=<"%IPFile%"

(for /f "delims=" %%a in ('type "%IniFile%"') do (
    echo %%a|findstr /ric:"^cd /upload" >nul && (
        echo cd /upload/%ServerIP%/
    ) || (
        echo %%a
    )
))>tmp_Config

move /y tmp_Config "%IniFile%" >nul


pause
复制代码

作者: kissn 时间: 2019-8-27 22:59

回复 2# flashercs

老哥没毛病。留下支付宝

作者: flashercs 时间: 2019-8-27 23:28

回复 3# kissn

扫我头像

作者: kissn 时间: 2019-8-27 23:29

回复 4# flashercs

已付

作者: Batcher 时间: 2019-8-28 08:04

回复 1# kissn

for /f "tokens=4 delims=." %%a in ("%ip%") do set ip=%%~a
echo,%ip%>E:\ip.txt
 
set IPFile=E:\IP.txt
 
set IniFile=E:\ftp.txt
 
set /p ServerIP=<"%IPFile%"
复制代码

是不是可以简化成：

for /f "tokens=4 delims=." %%a in ("%ip%") do set ServerIP=%%~a
set IniFile=E:\ftp.txt
复制代码

欢迎光临批处理之家 (http://bathome.net./)