批处理之家 - Powered by Discuz! Board

标题: [特效代码] 【已解决】请问批处理有窗口关闭时触发事件的机制吗？类似js的Onbeforeunload [打印本页]

作者: xzwcn 时间: 2020-11-24 22:14 标题: 【已解决】请问批处理有窗口关闭时触发事件的机制吗？类似js的Onbeforeunload

本帖最后由 xzwcn 于 2020-11-28 16:12 编辑

请问批处理有窗口关闭时触发事件的机制吗？类似js的Onbeforeunload。

set sid=xxx
::在电脑使用时使用QQ输入法
adb -s %sid% shell ime set com.tencent.qqpinyin/.QQPYInputMethodService
adb -s %sid% shell ime enable com.tencent.qqpinyin/.QQPYInputMethodService
scrcpy -s %sid% --turn-screen-off
::关闭窗口时切换为讯飞输入法【如何实现点击窗口关闭时触发执行以下代码】？
::adb -s %sid% shell ime enable com.iflytek.inputmethod/.FlyIME
::adb -s %sid% shell ime set com.iflytek.inputmethod/.FlyIME
复制代码

相关：
关于scrcpy对中文输入法支持不友好的解决办法 · Issue #1055 · Genymobile/scrcpy
https://github.com/Genymobile/scrcpy/issues/1055

作者: 老刘1号 时间: 2020-11-24 22:44

本帖最后由老刘1号于 2020-11-24 22:45 编辑

原生bat没有，兼容bat的take command可以在进程结束的时候触发事件，可以看take command板块置顶的触发器的帖子

作者: went 时间: 2020-11-25 19:40

可以用两个窗口+start /wait 来模拟

@echo off 
if "%~1"=="Close" (
	echo 窗口开启执行代码...
	pause&exit
) else (
	start /wait "" %~0 "Close"
	echo 窗口关闭执行代码...
	explorer %cd%
	exit
)
复制代码

作者: went 时间: 2020-11-25 19:44

@echo off 
set "sid=XXX"
if "%~1"=="Close" (
	echo 窗口开启执行代码...
	adb -s %sid% shell ime set com.tencent.qqpinyin/.QQPYInputMethodService
	adb -s %sid% shell ime enable com.tencent.qqpinyin/.QQPYInputMethodService
	echo scrcpy -s %sid% --turn-screen-off
	pause&exit
) else (
	start /wait "" %~0 "Close"
	echo 窗口关闭执行代码...
	adb -s %sid% shell ime enable com.iflytek.inputmethod/.FlyIME
	adb -s %sid% shell ime set com.iflytek.inputmethod/.FlyIME
	exit
)
复制代码

作者: dfg34c 时间: 2021-3-31 16:58

回复 3# went

请问怎么隐藏监听关闭事件的那个窗口

作者: went 时间: 2021-3-31 18:34

回复 5# dfg34c

没法隐藏

作者: went 时间: 2021-4-1 10:15

回复 5# dfg34c

不能隐藏，但是可以最小化，需要三个窗口

@echo off 
if "%~1"=="Open" (
	echo 窗口开启执行代码...
	pause&exit
) 
if "%~1"=="Close" (
	echo 等待窗口关闭...
	start /wait "" %~0 "Open"
	echo 窗口关闭执行代码...
	explorer "C:\"
	exit
) 
if "%~1"=="" (
	start /min "" %~0 "Close"
	exit
)
复制代码

欢迎光临批处理之家 (http://bathome.net./)