@echo off&color a&setlocal enabledelayedexpansion
for %%a in ("D:\jhrw\现用音乐\music\*.bat") do set /a n+=1
set /a m=%random%%%%n%
if %m% equ 0 set m=%n%
for %%a in ("D:\jhrw\现用音乐\music\*.bat") do (
set /a counter+=1
if !counter! equ %m% start %%a
)
复制代码

@echo off
rem 1.批处理保存为utf-8编码格式；
rem 2.播放软件：MPV (https://mpv.io/)；音量设定：nircmd (http://bcn.bathome.net/tool/nirsoft,2.86/nircmd.exe)；均需添加到电脑环境变量。
chcp 65001 >nul
set "folder=D:\mp3"
set /a k=m=0,e=(d=次数=7)*(n=数量=1)
if not exist "%folder%\list.txt" (
	cd.>"%folder%\list.txt"
)

:1
setlocal
for /f "useback delims=" %%a in ("%folder%\list.txt") do (
	set _"%%a"=1
	set /a k+=1
)
if %k% geq %e% (
	cd.>"%folder%\list.txt"
	endlocal
	goto :1
)
for /f "delims=" %%i in ('dir /b /a-d "%folder%\*.mp3" "%folder%\*.flac"') do (
	if not defined _"%%i" (
		call set #%%random%%=%%i
		set /a m+=1
	)
)
if %m% lss %n% (
	cd.>"%folder%\list.txt"
	endlocal
	goto :1
)
for /f "tokens=1* delims==" %%a in ('set #') do (
	echo 播放 [%%b]
	nircmd mutesysvolume 0
	nircmd setsysvolume 30000
	rem 自行设置播放器
	mpv --window-minimized "%folder%\%%b"
	nircmd setsysvolume 0
	nircmd mutesysvolume 1
	>>"%folder%\list.txt" echo %%b
	set /a n-=1,1/n 2>nul || exit
)
复制代码

@echo off&mode con cols=20 lines=2&color a&setlocal enabledelayedexpansion

set loop=7
set str=%date:/=%
set now=%str:~0,8%
set config=%now%;1;1;0

for /r %%i in (*.flac *.mp3 *.wav *.ape) do set /a total+=1
echo # 歌曲列表 >list.txt
dir *.flac *.mp3 *.wav *.ape /s /b >>list.txt
set /a total+=1

if NOT DEFINED playConfig (
  setx /m playConfig "%config%" >nul
  set playConfig=%config%
)

for /f "eol=# delims=; tokens=1,2,3,4" %%i in ("%playConfig%") do (
  set d=%%i
  set c=%%k
  set /a t=%%j
  set nums=%%l
  if "%%i" neq "%now%" (
    set /a t=%%j+1
    set d=%now%
  )
)

:rand
set /a randNum=%random%%%!total!

:start
if !c! geq !total! echo 所有歌曲都已经播放过一遍啦！ & pause>nul & goto :eof
for %%i in (!nums!) do if %%i == %randNum% goto rand
set /a c+=1
if !t! leq %loop% set config=!d!;!t!;!c!;!nums!
setx /m playConfig "%config%,%randNum%" >nul
for /f "skip=%randNum% delims=" %%i in (list.txt) do start "" "%%i" & goto :eof
复制代码

@echo off

set times=7
set "ph=D:\jhrw\现用音乐\music"

if not exist "%ph%\已播放" md "%ph%\已播放"
set n=0
for %%a in ("%ph%\已播放\*") do set /a n+=1
if %n% gtr %times% move "%ph%\已播放\*" "%ph%\"

for %%a in ("%ph%\*.flac" "%ph%\*.mp3" "%ph%\*.ogg") do set /a m+=1
if not defined m (echo no file to play&pause&exit/b)
set /a r=%random%%%%m%
if %r% equ 0 set r=%m%
for %%a in ("%ph%\*.flac" "%ph%\*.mp3" "%ph%\*.ogg") do (
set /a counter+=1
for /f %%_ in ('echo %%counter%%') do (
if %%_ equ %r% (
move "%%~fa" "%ph%\已播放\" && start "%ph%\已播放\%%~nxa"
goto :end
)
)
)

:end
pause
复制代码

@echo off&color a&setlocal enabledelayedexpansion
for %%a in ("D:\jhrw\现用音乐\music\*.bat.skip") do set /a n+=1
if n geq 7 (
for %%a in ("D:\jhrw\现用音乐\music\*.bat.skip") do move "%%i" "%%~dpni"
)
set n=
for %%a in ("D:\jhrw\现用音乐\music\*.bat") do set /a n+=1
set /a m=%random%%%%n%
if %m% equ 0 set m=%n%
for %%a in ("D:\jhrw\现用音乐\music\*.bat") do (
set /a counter+=1
if !counter! equ %m% (
start %%a
ping -n 2 127.0.0.1 >nul
move "%%a" "%%a.skip"
)
)
复制代码

@echo off &setlocal enabledelayedexpansion
set "7F=D:\jhrw\现用音乐\music\list.7"
if not exist "!7F!" (cd.>"!7F!") else for /f %%k in ('find /v /c "" ^<"!7F!" ') do if %%k geq 7 (cd.>"!7F!")
for %%b in ("D:\jhrw\现用音乐\music\*.bat") do (set/a "n+=1" &set "$!n!=%%b")
:[Loop]
	set/a m=%random%%%%n%+1
	for %%k in (!m!) do (set "mF=!$%%k!")
	find /i "!mF!" "!7F!">nul && goto[Loop]
echo,!mF!>>"!7F!"
start "" "!mF!"
endlocal &exit/b
复制代码

@echo off &setlocal enabledelayedexpansion
set "i=0" &set "7F=D:\jhrw\现用音乐\music\list.7"
if not exist "!7F!" (cd.>"!7F!") else for /f %%k in ('find /v /c "" ^<"!7F!" ') do (set "i=%%k" &if %%k geq 7 (cd.>"!7F!"))
for %%b in ("D:\jhrw\现用音乐\music\*.bat") do (set/a "n+=1" &set "$!n!=%%b")
:[Loop]
	set/a m=%random%%%%n%+1
	for %%k in (!m!) do (set "mF=!$%%k!")
	find /i "!mF!" "!7F!">nul && goto[Loop]
set/a "i+=1" &echo,!i!: !mF!>>"!7F!"
start "" "!mF!"
endlocal &exit/b
复制代码

@echo off &setlocal enabledelayedexpansion
set "i=0" &set "7F=D:\jhrw\现用音乐\music\list.7"
if not exist "!7F!" (cd.>"!7F!") else for /f %%k in ('find /v /c "" ^<"!7F!" ') do (set "i=%%k" &if %%k geq 7 (cd.>"!7F!"&set "i=0"))
for %%b in ("D:\jhrw\现用音乐\music\*.bat") do (set/a "n+=1" &set "$!n!=%%b")
:[Loop]
	set/a m=%random%%%%n%+1
	for %%k in (!m!) do (set "mF=!$%%k!")
	find /i "!mF!" "!7F!">nul && goto[Loop]
set/a "i+=1" &echo,!i!: !mF!>>"!7F!"
start "" "!mF!"
endlocal &exit/b
复制代码

@echo off &setlocal enabledelayedexpansion
set "i=0" &set "7F=D:\jhrw\现用音乐\music\list.7"
if not exist "!7F!" (cd.>"!7F!") else for /f %%k in ('find /v /c "" ^<"!7F!" ') do (set "i=%%k" &if %%k geq 7 (cd.>"!7F!"&set "i=0"))
for %%b in ("D:\jhrw\现用音乐\music\*.bat") do (set/a "n+=1" &set "$!n!=%%b")
:[Loop]
  set/a m=%random%%%%n%+1
  for %%k in (!m!) do (set "mF=!$%%k!")
  find /i " !mF! " "!7F!">nul && goto[Loop]
set/a "i+=1" &echo,!i!: !mF! %date:~0,10%>>"!7F!"
start "" "!mF!"
endlocal &exit/b
复制代码