批处理之家 - Powered by Discuz! Board

标题: [文本处理] [已解决]批处理如何删除文件夹名中第一个连续数字之后的部分？ [打印本页]

作者: gddsssko 时间: 2024-3-4 21:04 标题: [已解决]批处理如何删除文件夹名中第一个连续数字之后的部分？

本帖最后由 gddsssko 于 2024-6-9 08:44 编辑

只保留第一个连续数字之前的内容，在这之后的全部内容（数字，汉字，符号等）删除
   原文件名：内容"第一个连续数字"内容
   处理后：内容"第一个连续数字"
例如：
原文件夹名
   Zhang-San12345你好世界123@#￥
   你好12345#￥#123ABC123
   AA$A256--345$356
   大大11A大大AAA11
处理后文件夹名
   Zhang-San12345
   你好12345
   AA$A256
   大大11

作者: wanghan519 时间: 2024-3-5 08:12

本帖最后由 wanghan519 于 2024-3-5 10:43 编辑

需要存入bat，放到目录同一级运行

#&cls&powershell "type '%~0'|out-string|iex"&pause&exit
dir -Directory | Rename-Item -NewName {$_.Name -replace '(-\d+)-.*$','$1'}
复制代码

作者: gddsssko 时间: 2024-3-5 08:22

回复 2# wanghan519

我试了下，好像没有反应

作者: ShowCode 时间: 2024-3-5 08:31

回复 1# gddsssko

@echo off
for /f "delims=" %%i in ('dir /b /ad ^| findstr ".*-.*-"') do (
    set "OldName=%%i"
    setlocal enabledelayedexpansion
    for /f "tokens=1,2,* delims=-" %%a in ("!OldName!") do (
        echo "!OldName!" -^> "%%a---%%b"
        ren "!OldName!" "%%a---%%b"
    )
    endlocal
)
pause
复制代码

作者: gddsssko 时间: 2024-3-5 08:52

回复 4# ShowCode

大佬，我试了后只改了部分名字，我修改了下举例，第一个和第四个例子都没反应

作者: ShowCode 时间: 2024-3-5 09:14

回复 5# gddsssko

4楼代码是按照你最初的例子写的。
现在需求变了，代码也需要变。

作者: 77七 时间: 2024-3-5 09:28

1个数字的情况呢？算连续数字吗？

作者: gddsssko 时间: 2024-3-5 09:32

回复 7# 77七

算

作者: gddsssko 时间: 2024-3-5 09:34

回复 6# ShowCode

是我之前对于需求描述不准确，让大佬会错意了

作者: 77七 时间: 2024-3-5 09:56

本帖最后由 77七于 2024-3-5 10:16 编辑

@echo off
cd /d "%~dp0"
for /f "delims=" %%d in ('dir /b /ad') do (
	for /f "tokens=1* delims=0123456789" %%a in ("#%%d") do (
		set name=%%d
		setlocal enabledelayedexpansion
		ren "!name!" "!name:%%b=!"
		endlocal
	)
)
pause
复制代码

作者: gddsssko 时间: 2024-3-5 20:02

回复 10# 77七

感谢大佬

作者: hfxiang 时间: 2024-3-6 10:30

回复 1# gddsssko

此类问题俺一般将其归属到文本处理问题，习惯上借助gawk（ http://bcn.bathome.net/tool/4.1.0/gawk.exe ）来解决：

@echo off
rem 建议保存为ANSI编码格式
for /f "delims=" %%a in ('dir /b /s /a-d') do (
	for /f "delims=" %%b in ('echo;%%~na^|gawk -v"FPAT=^[^0-9]*[0-9]+" "{print $1}"') do (
		ren "%%a" "%%b%%~xa"
	)
)
复制代码

作者: qixiaobin0715 时间: 2024-6-9 14:17

本帖最后由 qixiaobin0715 于 2024-6-9 14:23 编辑

回复 10# 77七
重新看了看你的代码，为防止文件夹名出现类似这种情况（abc123c），在你的代码基础上这样修改，可能更严谨些：

@echo off
cd /d "%~dp0"
for /f "delims=" %%d in ('dir /b /ad') do (
	for /f "tokens=1* delims=0123456789" %%a in ("#%%d") do (
		setlocal enabledelayedexpansion
		set n1=%%a
		set n1=!n1:~1!
		set n2=#%%d
		set n2=!n2:*%%a=!
		set n2=!n2:%%b=!
		ren "%%d" "!n1!!n2!"
		endlocal
	)
)
pause
复制代码

作者: 77七 时间: 2024-6-9 14:43

本帖最后由 77七于 2024-6-9 14:56 编辑

回复 13# qixiaobin0715

谢谢大佬指点！
我思路不严谨，没有考虑到数字后部分与数字前部分出现相同可能。修改为以下代码，手动添加 |字符，防止重复。

@echo off
cd /d "%~dp0"
for /f "delims=" %%d in ('dir /b /ad') do (
        for /f "tokens=1* delims=0123456789" %%a in ("#%%d|") do (
                set name=%%d
                setlocal enabledelayedexpansion
                set "_name=!name!|"
                ren "!name!" "!_name:%%b=!"
                endlocal
        )
)
pause
复制代码

再添加一个判断，防止误伤没有数字的文件夹

@echo off
cd /d "%~dp0"
for /f "delims=" %%d in ('dir /b /ad') do (
	for /f "tokens=1* delims=0123456789" %%a in ("#%%d|") do (
		set name=%%d
		if "%%b" neq "" (
			setlocal enabledelayedexpansion
			set "_name=!name!|"
			ren "!name!" "!_name:%%b=!"
			endlocal
		)
	)
)
pause
复制代码

作者: aloha20200628 时间: 2024-6-9 16:26

给一个不用延迟变量也不用for分割器的版本...

@echo off &for /f "delims=" %%d in ('dir /b/ad') do (
	set "s=%%d" &set "d=%%d" &set "_s="
	(call :gets#) & (call :get#s)
)
pause&exit/b
:gets#
	set "c=%s:~,1%"
	if "%c%" geq "0" if "%c%" leq "9" exit/b
	set "_s=%_s%%c%" &set "s=%s:~1%" &goto :gets#
	exit/b
:get#s
	set "c=%s:~,1%"
	if "%c%" geq "0" if "%c%" leq "9" (call set "_s=%%_s%%%%c%%" &call set "s=%%s:~1%%" &goto :get#s) 
	ren "%d%" "%_s%" 2>nul
	exit/b
复制代码

欢迎光临批处理之家 (http://bathome.net./)