@echo off
dir /b /s /ad>temp
for /f "delims=" %%i in ('findstr /e /g:list.txt temp^|sort /r') do rd /s /q "%%i"
dir /b /s /a-d>temp
for /f "delims=" %%i in ('findstr /e /g:list.txt temp') do del /q /f "%%i"
del temp
pause
复制代码

@echo off
set folder=d:\a
set file=d:\list.txt
for /f "useback delims=" %%a in ("%file%") do (
	set _"%%~nxa"=1
)
for /f "delims=" %%i in ('dir /b /s "%folder%\*"') do (
	if defined _"%%~nxi" (
		if exist "%%i\" (
			rd /s /q "%%i"
		) else if exist "%%i" (
			del "%%i"
		)
	)
)
pause
复制代码

@echo off &for /f "delims=" %%a in (list.txt) do (for /f "delims=" %%x in ('dir /b/s/a "d:\test\%%a" ') do if exist "%%x\" (rd /s/q "%%x") else del /s/q "%%x")>nul 2>nul
pause&exit/b
复制代码

@echo off
(for /f "delims=" %%i in (list.txt) do echo,\%%i)>temp1
dir /b /s /ad>temp2
for /f "delims=" %%i in ('findstr /le /g:temp1 temp2^|sort /r') do rd /s /q "%%i"
dir /b /s /a-d>temp2
for /f "delims=" %%i in ('findstr /le /g:temp1 temp2') do del /q /f "%%i"
del temp?
pause
复制代码

@echo off
set folder=d:\a
set file=d:\list.txt
for /f "useback delims=" %%a in ("%file%") do (
	for /f "delims=" %%i in ('dir /b /s "%folder%\%%a?"') do (
		if /i "%%~nxi" equ "%%a" (
			if exist "%%i\" (
				rd /s /q "%%i"
			) else if exist "%%i" (
				del "%%i"
			)
		)
	)
)
pause
复制代码

@echo off
setlocal enabledelayedexpansion
cd /d "%~dp0"
title 视频缓存文件匹配清理工具 by.SanLi
color 07
::mode con: cols=80 lines=25
chcp 936 >nul

(for /f "tokens=* delims=, " %%f in ('dir /a /s /b .\*.mp4 ') do echo %%f)>"mp4_list.txt"

set keywords=文件列表.txt
set target=mp4_list.txt

for /f "tokens=*" %%a in (%keywords%) do (
    findstr /C:%%a %target% >nul
    if !errorlevel! equ 0 (
        echo 匹配关键词文件: %%a
        for /f %%b in ('findstr /C:%%a %target%') do (
        del %%b
        echo 即将删除文件：%%b
        )
        echo.
    )
)

pause
复制代码